[RESOLU] Moyenne Si sous excel 2003

[julien712]

Bonjour

Je dois calculer une moyenne de nombre, si ceux ci corresponde à une semaine X
Sous excel 2007, c'est facile, j'utilise la fonction MOYENNE.SI
Par contre sous excel 2003, j'ai tenter de voir avec les formules matricielles MOYENNE(SI ....) mais je ne comprend pas trop son fonctionnement.

Dans l'exemple, en PJ, je souhaite que dans ma feuille "calcul", en B8, il me calcule la moyenne des chiffres correspondant à la semaine "11-08" (celulle A8) tout en regardant les chiffres de cette meme semaine figurant dans ma feuille 'synthèse".
A la main, le calcul va donc me prendre les valeurs de "Synthèse!J8:J14"

Quelqu'un a t'il une formule magique pour le faire avec la fonctionne moyenne(si ...) et m'expliquer svp

Merci de votre aide

 

[tototiti2008]

Re : Moyenne Si sous excel 2003

Bonjour Julien,

Moyenne(si s'écrit comme ça

=MOYENNE(SI(Synthèse!$B$1:$B$14=Calcul!A8;Synthèse!$J$1:$J$14))

à valider par Ctrl+Maj+Entrée

ou en "non matriciel", on peut faire:

=SOMME.SI(Synthèse!$B$1:$B$14;Calcul!A8;Synthèse!$J$1:$J$14)/NB.SI(Synthèse!$B$1:$B$14;Calcul!A8)

 

[julien712]

Re : Moyenne Si sous excel 2003

Merci pour cette réponse.
Par contre en calculant manuellement, je dois être à une moyenne de 225, hors avec les deux formules, j'arrive a 161
Bizarre...
Apparemment, il prend dans le calcul les samedis et dimanches (qu'il ne devrait pas)
Comment faire ?

Merci encore

 

[hoerwind]

Re : Moyenne Si sous excel 2003

Bonjour, salut tototiti,

Essaie ceci :

=MOYENNE(SI((Synthèse!$B$1:$B$14=Calcul!A8)*(JOURSEM(Synthèse!$F$1:$F$14;2)<6);Synthèse!$J$1:$J$14))

à valider en matricielle

 

[ROGER2327]

Re : Moyenne Si sous excel 2003

Bonjour à tous

Autre proposition :

=SI(NB(J$1:J$14);MOYENNE(SI((Synthèse!$B$1:$B$14=Calcul!$A8)*(J$1:J$14<>"");Synthèse!J$1:J$14));"")

en colonne J, à recopier vers la droite. Formule matricielle à valider par Ctrl Maj Entrée.​

ROGER2327
#5023

Mardi 10 Pédale 138 (Nativité de Saint Tancrède, jeune homme, SQ)
14 Ventôse An CCXIX
2011-W09-5T09:48:53Z

 

[tototiti2008]

Re : Moyenne Si sous excel 2003

Re,

Ah oui, oups... pour les cellules vides ça pose problème
Pour la formule matricielle, je ne sais pas trop, pour la 2ème ça devrait donner ça

=SOMME.SI(Synthèse!$B$1:$B$14;Calcul!A8;Synthèse!$J$1:$J$14)/SOMMEPROD((Synthèse!$B$1:$B$14=Calcul!A8)*(Synthèse!J1:$J$14<>""))

Edit : Bonjour Roger , Bonjour hoerwind

 

[julien712]

Re : Moyenne Si sous excel 2003

Merci beaucoup pour votre aide. Cela fonctionne.