renvoyer les deux plus petites valeurs d un tableau

[ivan972]

Bonjour a tous, bonjour a chacun

Je sollicite le forum afin de résoudre la difficulté suivante.

je souhaite dans un tableau obtenir les deux plus petits chronos a partir d un tableau de performances (ci joint en fichier)

A partir du tableau1 (A1:C15), je souhaite inscrire en cellules G3 et H3 les deux plus petit chronos en fonction du nom du cheval (F2) ET de l hippodrome(F3).

Les chronos ne sont pas rangés dans l ordre volontairement .

Le format des chronos doit rester sous forme 00'00''00.

Vous remerciant

Ivan

 

[david84]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir,
le problème c'est que tes temps ne sont pas des nombres.
Proposition avec ou sans colonne intermédiaire avec format de cellule personnalisé.

A+

 

[R@chid]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir @ tous,
pas sûr d'avoir compris la demande, en G3 :

=SIERREUR(INDEX($C$2:$C$15;EQUIV(PETITE.VALEUR(SI($B$2:$B$15=$F$3;CNUM(SUBSTITUE(SUBSTITUE($C$2:$C$15;"""";",");"'";)));COLONNES($G:G));SI($B$2:$B$15=$F$3;CNUM(SUBSTITUE(SUBSTITUE($C$2:$C$15;"""";",");"'";)));0));"")

@ valider par Ctrl+Shift+Enter
@ tirer vers la droite


@ + +

 

[ivan972]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonjour R@chid, re david84

Merci d avoir pris le temps de répondre a ma demande.

Cependant l hypothèse est de renvoyer dans les cellules colorées les deux plus petits chronos en fonction du cheval et de l hippodrome. Dans l exemple proposé Archange n a pas de chrono a chantilly donc pas de réponse possible.

Le résultat obtenus n est pas celui demandé.

Vous remerciant

ivan

 

[job75]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir ivan972, David, R@chid,

Pas besoin de nombres, on peut comparer les textes des chronos.

Formule matricielle en G3 du fichier joint :

=SIERREUR(INDEX(Tableau1[CHRONOS];EQUIV(COLONNES($G3:G3);SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);NB.SI(Tableau1[CHRONOS];"<="&Tableau1[CHRONOS]));0));"")

A valider par Ctrl+Maj+Entrée et tirer sur H3.

A+

 

[job75]

Re : renvoyer les deux plus petites valeurs d un tableau

Re,

Attention, si le nombre de minutes peut dépasser 9 il faut l'écrire toujours avec 2 chiffres 01', 02', 03' etc...

A+

 

[job75]

Re : renvoyer les deux plus petites valeurs d un tableau

Re,

Bah, j'avais mal testé, il faut compliquer la formule :

=SIERREUR(INDEX(Tableau1[CHRONOS];EQUIV(PETITE.VALEUR(SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);NB.SI(Tableau1[CHRONOS];"<="&Tableau1[CHRONOS]));COLONNES($G3:G3));SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);NB.SI(Tableau1[CHRONOS];"<="&Tableau1[CHRONOS]));0));"")

Fichier (2).

Malgré les évènements, bonne soirée.

 

[david84]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir, Rachid, Gérard,
en tenant compte de l'hippodrome et du cheval :

=SIERREUR(PETITE.VALEUR(SI(($A2:$A15=$F2)*($B2:$B15=$F3);(GAUCHE($C2:$C15;CHERCHE("'";$C2:$C15)-1)*60+SUBSTITUE(STXT($C2:$C15;CHERCHE("'";$C2:$C15)+1;99);"""";",")*1)/86400);COLONNE(A:A));"")

A+

 

[R@chid]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir les amis,
j'ai pas pris l'hippodrome en compte car sur l'exemple fourni ça ne renvoie rien, elle ne renvoie que du vide.

@ + +

 

[job75]

Re : renvoyer les deux plus petites valeurs d un tableau

Re,

Bien sûr avec le nom défini matrice on simplifie la formule en G3 :

=SIERREUR(INDEX(Tableau1[CHRONOS];EQUIV(PETITE.VALEUR(matrice;COLONNES($G3:G3));matrice;0));"")

Toujours avec validation matricielle.

Fichier (3).

Bonne fin de soirée.

 

[job75]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonjour ivan972, David, R@chid,

En passant par des nombres (entiers) c'est en effet plus simple :

=SIERREUR(TEXTE(PETITE.VALEUR(SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);--SUBSTITUE(SUBSTITUE(Tableau1[CHRONOS];"'";);"""";));COLONNES($G3:G3));"0'00\""00");"")

Ici pour les minutes on peut écrire 1' 2' 3'...10' 11' etc...

Fichier (4).

Bonne journée.

 

[david84]

Re : renvoyer les deux plus petites valeurs d un tableau

Bonjour,

oui Gérard c'est mieux comme cela (à partir du moment bien sûr où toutes les données sont saisies comme cela).
On peut aussi passer par TEMPSVAL.
Ceci dit, et à moins que ce soient des données importées, le demandeur doit comprendre qu'il est bien plus efficace de saisir ses données pour qu'elles soient interprétées par Excel comme des temps plutôt que du texte, quitte à appliquer par la suite un format personnalisé.

A+