récupérer coordonnées d'une sélection de cellules

[Adeus33]

Bonjour le forum,

Serait-il possible de récupérer les coordonnées d'une sélection de cellules par macro?

par exemple : je sélectionne les cellules A2; A8 et C10 et la macro me renvoi les coordonnées de chaque cellule sélectionnée.
A2 --> colonne 1 et ligne 2
A8 --> colonne 1 et ligne 8
etc....

j'y arrive seulement lorsque je sélectionne une seule cellule avec le code ci dessous :
ligne = activecell.row
colonne = activecell.column

Merci d'avance pour votre aide

adeus33

 

[Modeste geedee]

Re : récupérer coordonnées d'une sélection de cellules

Bonsour®

effectuer une selection
puis activer la mocro

Sub adeus()
Dim cell As Range
Dim Res As String
Res = Selection.Cells.Count & " cellule(s)" & Chr(10)
Res = Res & "Adresse" & vbTab & "ligne" & vbTab & "colonne" & Chr(10)
For Each cell In Selection
Res = Res & cell.Address & vbTab & cell.Row & vbTab & cell.Column & Chr(10)

Next
MsgBox Res
End Sub

 

[Adeus33]

Re : récupérer coordonnées d'une sélection de cellules

Bonsoir et merci Modeste geedee,

C'est parfait !!!! exactement ce que je souhaitais faire.

Encore merci et bon week end.

Adeus

 

[Modeste geedee]

Re : récupérer coordonnées d'une sélection de cellules

Bonsour®
autre propositions en cas de plages distinctes

Sub Tress()
Dim area As Range
Dim Res As String
Res = Selection.Cells.Count & " cellule(s)" & Chr(10)
Res = Res & "répartie(s) en " & Selection.Areas.Count & " zone(s) distincte(s)" & Chr(10)
Res = Res & "Adresse" & vbTab & "ligne(s)" & vbTab & "colonne(s)" & Chr(10)
For Each area In Selection.Areas
Res = Res & area.Address & vbTab & area.Rows.Count & vbTab & area.Columns.Count & vbTab & area.Cells.Count & Chr(10)

Next
MsgBox Res
End Sub