recuperer 2 colonnes sans doublons

[jean paul]

bonsoir à tous

Actuelement je recupére de la feuil1 une liste de references sans doublons en colonne B feuil2 jusque là pas de probleme ,je souhaite récupèrer en plus la désignation de ces reférences en collonne A j'ai bien essayer à partir du code existant de faire quelques modifs mais sans réussite.
Merci de votre collaboration
bonne soirée
jean paul

 

[Robert]

Re : recuperer 2 colonnes sans doublons

Bonjour Jean-paul, bonjour le forum,

Nous aussi on essaierait bien si on navet le code ou un fichier exemple... mais on l'a pas, tâte ton post il est creux...

Ha entre temps le fichier a été placé... Je me sens comme une vieux Hollywood trop mâché... laid gum en quelque sorte...

 

[Excel-lent]

Re : recuperer 2 colonnes sans doublons

Bonsoir Jean paul, Robert,

J'ai essayé d'ouvrir ton fichier, ça bug.

Je l'ai renommé en *.rar au cas où tu aurais compressé ton fichier avec Winrar, mais ça fonctionne pas mieux!

Quelqu'un arrive à l'ouvrir?

Sans ça, impossible de t'aider

A te lire

 

[jeanpierre]

Re : recuperer 2 colonnes sans doublons

Bonsoir jean paul, Robert, Excel-lent,

Le fichier s'ouvre bien mais il est vide (745 Ko pour une seule feuille blanche, y'a un problème).

Bonne soirée.

Jean-Pierre

 

[jean paul]

Re : recuperer 2 colonnes sans doublons

Désolé je ne sais pas ce qu'il se passe avec winzip
j'ai utilisé cijoint.fr je ne sais pas si ca va aller
merci de votre aide


Cijoint.fr - Service gratuit de dépôt de fichiers

 

[Robert]

Re : recuperer 2 colonnes sans doublons

Bonsoir le fil, bonsoir le forum,

J'ai pu ouvrir ton premier fichier sans problème... Mais les fonctions c'est pas mon truc je ne m'en sors pas. Je te propose la macro suivante :

Public Sub sansfonction()
Dim cr As Collection 'déclare la variable cr (Collection des Références)
Dim cd As Collection 'déclare la variable cd (Collection des Désignations)
Dim cel As Range 'déclare la variable cel (CELlule)
Dim pl As Range 'déclare la variable pl (PLage)
 
Set cr = New Collection 'définit la variable cr
Set cd = New Collection 'définit la variable cd
Set pl = Sheets("Feuil1").Range("B1:B" & Sheets("Feuil1").Range("B65536").End(xlUp).Row) 'définit la variable pl
 
'***************************
'remplissage des collections
'***************************
For Each cel In pl 'boucle sur toutes les cellules cel de la plage pl
    On Error Resume Next 'gestion des erreurs (un doublon génère une erreur à cause de la clé "CStr(cel.Value)")
    cr.Add cel.Value, CStr(cel.Value) 'ajoute la valeur de la cellule comme nouveau membre de la collection cr
    cd.Add cel.Offset(0, -1).Value, CStr(cel.Offset(0, -1).Value) 'ajoute la valeur de la cellule à gauche comme nouveau membre de la collection cd
Next cel 'prochaine cellule cel de la plage pl
 
'************************
'récupération des données
'************************
With Sheets("Feuil2")
    For x = 1 To cr.Count
        .Cells(x + 3, 2).Value = cr(x)
        .Cells(x + 3, 1) = cd(x)
    Next x
End With
End Sub

 

[BOISGONTIER]

Re : recuperer 2 colonnes sans doublons

Bonsoir,

Méthode rapide

http://boisgontierjacques.free.fr/pages_site/Dictionnaire.htm#comparaison

Sub Essai()
  Set f = Sheets(1)
  Set mondico = CreateObject("Scripting.Dictionary")
  For Each c In f.Range("b1:b" & f.[B65000].End(xlUp).Row)
     mondico.Item(c.Value) = c.Offset(0, -1).Value
  Next c
  Sheets(2).[b4].Resize(mondico.Count, 1) = Application.Transpose(mondico.keys)
  Sheets(2).[a4].Resize(mondico.Count, 1) = Application.Transpose(mondico.items)
End Sub

JB

 

[jetted]

Re : recuperer 2 colonnes sans doublons

Robert

J'aime bien to code, simple et tres educatif

Milles mercis... je vais surement l'adapter pour mes besoin

 

[Robert]

Re : recuperer 2 colonnes sans doublons

Bojour le fil, bonjour le forum,

P... moi c'est celui de JB qui m'a "espanté" comme on dit chez moi... C'est dommage qu'il ne nous donne pas quelques explications mais... pfffiou ! Quelle consision Sire ! C'est à se la prendre, se la couper et se la poser sur l'oreille pour la fumer plus tard non ?

 

[jean paul]

Re : recuperer 2 colonnes sans doublons

Quel bonheur votre collaboration,merci beaucoup
bon week end à tous

jean paul