Rechercher une valeur dans une matrice et coller les resultats dans une autre

[tprlechef]

Bonjour à tous

J’ai un planning de la semaine par employé avec une liste d’actions à faire par client.

Je souhaiterais avoir un récapitulatif en automatique des actions à faire par client, c’est-à-dire rechercher les actions par client et les copier dans le second tableau.

J’ai pensé à recherchev et des fonction SI imbriqué, mais je crois que je suis pas dans la bonne direction …. Ci-joint mon tableau.

Merci pour vos lumieres…

 

[Modeste]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Bonjour tprlechef,

Si j'ai bien compris, essaie en J3:

=SIERREUR(INDEX($D$1:$D$52;PETITE.VALEUR(SI($E$3:$E$52=J$2;LIGNE($E$3:$E$52));LIGNES($1:1)));"")

Valider avec Ctrl+Shift+Enter, puis recopier en bas et à droite

 

[vgendron]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Hello chef, Modeste,

juste parce que pour une fois j'ai réussi à faire cette formule en UNE seule cellule.. sans passer par une colonne intermédiaire.. ;-)

en J3
=SI(GRANDE.VALEUR(($E$3:$E$52=J$2)*LIGNE();LIGNE()-2)>0;INDEX($D$3:$D$52;GRANDE.VALEUR(($E$3:$E$52=J$2)*LIGNE();LIGNE()-2));"")

et idem: validation matricielle..

Ha bah non.. m... ca marche pas...:-(

 

[tprlechef]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Waouh ca marche ! Bon j'avoue que je suis inccapable de faire ca... Je vais essayer de comprendre la logique mais c'est pas gagné

Merci beaucoup en tout cas pour ton aide et ta reponse super rapide !!

Vu que tu à l'air de maitriser à la perfection excel, j'ai une autre contrainte sur la MFC, je voulais que les colonnes action/client/statut soit en couleur (pas que la colonne statut), donc je change le "s"applique à" de =$F$3:$F$52 à =$D$3:$F$52 mais ca ne marche pas...

L'idéal serait que mes actions clients recapitulées affiche la couleur de statut (vert ou rouge)...

Merci pour ton aide !

 

[Modeste]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Re,
Salut vgendron

Vu que tu à l'air de maitriser à la perfection excel

Alors ça, c'est encore loin d'être le cas: je peux t'en présenter des wagons entiers qui "maîtrisent" bien plus que moi (et rien que sur ce forum!)
Pour ta MFC, je pense que celle qui colore en rouge devrait être supprimée (en attendant de savoir dans quel cas elle est supposée s'appliquer!?). Pour celle qui colore en vert, =$F3="Fait" devrait fonctionner

Ha bah non.. m... ca marche pas...:-(

Avec 2-3 petites modifs, ça commencerait à fonctionner (ne dit-on pas que Rome ne s'est pas faite en un jour?)

 

[tprlechef]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Disons qui maitrise mieux que moi

Est-ce qu'avec ta formule en validation matricielle, je peux copier la mise en forme de la cellule?

Par exemple les actions avec le statut "Fait" donc en vert, lorsqu'elles sont copier dans le tableau recap client, je voudrais qu'elles soient en vert pour donner la vision du statut des actions dans ce tableau.

Je ne suis pas sur que c'est faisable sans passer par une macro...

Merci beaucoup pour votre aide

 

[Modeste]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Re²,

De fil en aiguille, on s'éloigne un tantinet de la question de départ! Qu'en diront les générations futures, quand elles repasseront par ici!?

Si j'ai bien compris la nouvelle demande, tu peux faire une MFC:

• sélectionne la plage de $J$3 à $O$25
• MFC > Nouvelle règle > Utiliser une formule pour ...
• coller cette formule:

  =INDEX($F$1:$F$52;PETITE.VALEUR(SI($E$3:$E$52=J$2;LIGNE($E$3:$E$52));LIGNES($1:1)))="fait"

• choisir ton format
• valider

... et tester

Note: la formule est encore matricielle (mais ne nécessite pas de Ctrl+Shift+Enter dans la MFC)
Note bis: attention au fait que des classeurs avec de nombreuses formules matricielles peuvent commencer à "ramer" (si le volume est proche de ton fichier actuel, pas de souci!)

 

[tprlechef]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

J'avoue que ca dévie mais ca sera surement utile

Encore une fois bravo, ca fonctionne

J'ai réussis à adapter la formule avec ma nouvelle mise en forme (ajout de colonne etc, c'est déjà ca )

Mon dernier point bloquant, c'est concernant les actions en retard (en rouge) elle ne se reporte pas sur mon tableau recap client.

J'ai essayer de modifier le ="Fait" dans ta formule par =ET($B4<$J$1;$E4<>"") mais ca ne marche pas

 

[Modeste]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

J'avoue que ca dévie mais ca sera surement utile

À n'en point douter!

Pour la MFC, il faudra vérifier et tester avec les différents cas de figure possible:
la plage (je suppose!?) est $L$4:$Q$26;
la formule serait:

=SOMMEPROD((L4<>"")*($F$4:$F$53=L$3)*($B$4:$B$53<$J$1)*($G$4:$G$53=""))

cette règle-ci doit "descendre" sous celle qui colore en vert

... tu nous diras ...

 

[tprlechef]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Oui la plage est la bonne !

Ca marche mais jusqu'au 03/02/2015.... bizarrement apres ca ne prend plus le strictement inferieur à la date mais ca me fait un inférieur ou égal...

J'ai bien essayé de magouiller en faisant -1 à la date mais vu que ca ne maarche plus qu'à partir du 03/02 mais le retard du 02/02 n'est pas affiché....

Ca me parait super bizarre ca non? bug d'excel?

 

[Modeste]

Re : Rechercher une valeur dans une matrice et coller les resultats dans une autre

Bonjour tprlechef, le fil, le forum et le reste du monde,

bug d'excel?

Le bug provient plus souvent de l'utilisation qu'on fait d'Excel ... que d'Excel lui-même
Dans le cas présent, c'est ma formule qui n'est pas la bonne!
Essaie celle-ci, pour la MFC rouge sur la plage L4:Q26:

=INDEX($G$1:$G$53;PETITE.VALEUR(SI(($F$4:$F$53=L$3)*($B$4:$B$53<$J$1);LIGNE($F$4:$F$53));LIGNES($1:1)))=""

... toujours à tester soigneusement!

Attention: dans ton dernier exemple, en ligne 28, une action est renseignée ... sans que le client soit mentionné!? Si ce cas de figure est possible, il faudra que tu détermines laquelle des 2 infos est prioritaire pour les différentes MFC.