Recherche valeur dans un tableau

[Alain_V]

Bonjour à tous,

J'ai déjà vu la question de mon intitulé dans le forum, mais je n'ai pas trouvé la réponse en lien avec mon petit problème.

voilà je recherche une valeur dans un tableau (pas dans une colonne) et j'aimerais quand la valeur est trouvée avoir en retour la première valeur de la colonne et de la ligne.

Comme un petit dessin est plus facile à comprendre je joint un fichier qui explique le besoin.

Merci par avance pour votre aide.

 

[Circark]

Re : Recherche valeur dans un tableau

J'ai bidouillé ton fichier avec un autre exemple utilisant INDEX et EQUIV, pour trouver une valeur en fonction de deux autres. Peut-être peux-tu l'utiliser ?

 

[PrinceCorwin]

Re : Recherche valeur dans un tableau

Bonjour,

Je pense que la fonction recherche() est fait pour cela:
En D12

=RECHERCHE(D$10;$D$4:$G$7;$B$4:$B$7)

Bonne journée

 

[Tibo]

Re : Recherche valeur dans un tableau

Bonjour,

Un essai avec des formules matricielles basées sur les fonctions INDIRECT et ADRESSE :

en D12 :

=INDIRECT(ADRESSE(SOMME(($D$4:$G$7=D$10)*LIGNE($B$4:$B$7));2))

en D13 :

=INDIRECT(ADRESSE(SOMME(($D$4:$G$7=D$10)*LIGNE($B$4:$B$7));3))

en D14 :

=INDIRECT(ADRESSE(3;SOMME(($D$4:$G$7=D$10)*COLONNE($D$3:$G$3))))

Ces trois formules sont matricielles, c'est-à-dire qu'elles doivent être validées par CTRL + MAJ + ENTREE

Nécessite qu'il n'y ait pas de doublons dans les noms de couleur.

@+

 

[JHA]

Re : Recherche valeur dans un tableau

Bonjour à tous,

ci joint un exemple qui doit correspondre à tes besoins

JHA

 

[Alain_V]

Re : Recherche valeur dans un tableau

Merci pour vos réponses.

Par facilité j'ai commencé par regarder les fichiers attachés.
La solution proposée par Circark m'oblige à connaitre une valeur supplémentaire hors je ne connais qu'une donnée du tableau, la couleur.
La réponse de JHA répond à mon besoin car en donnant la couleur je trouve bien la catégorie, la sous-catégorie ainsi que la colonne de référence. Vu mon niveau en Excel il me faut un peu de temps pour bien comprendre la solution proposée.

Je regarderai aussi les autres propositions pour comparer, mais ce sera en fin de journée.

Merci
@+

 

[Alain_V]

Re : Recherche valeur dans un tableau

Me revoilà,

J'ai essayé les formules proposées par PrinceCorwin et Tibo, mais j'ai eu un code erreur en retour.

La proposition de JHA répond en partie au besoin, mais ne fonctionne pas si la valeur n'est pas dans le tableau, ce qui ne poserait pas de problème si j'avais systématiquement un code erreur en retour, j’obtiens aussi des réponses fausses.

J'ai essayé d'expliquer cela dans le fichier joint.

Pour mon besoin il ne faudrait une réponse que si la valeur est bien dans le tableau (pas besoin d'être sensible à la case).

Merci pour votre aide.

 

[Tibo]

Re : Recherche valeur dans un tableau

re,

Je n'ai pas trop compris pourquoi la formule que je t'ai proposée retournait #NOM?

Concernant les valeurs non présentes, il suffit d'intégrer un test NB.SI, ce qui donne pour la 1ère formule :

=SI(NB.SI($D$4:$G$7;D$18)=0;"";INDIRECT(ADRESSE(SOMME(($D$4:$G$7=D$18)*LIGNE($B$4:$B$7));2)))

En matricielle.

Je te joins ton fichier avec les formules modifiées.

@+

 

[hoerwind]

Re : Recherche valeur dans un tableau

Bonjour,

Autres possibilités, assez simples :

En D12 :

=DECALER(B3;SOMMEPROD((D4:G7=$D10)*LIGNE(1:4));)

En D14 :

=DECALER(A3;;SOMMEPROD((D4:G7=D10)*COLONNE(C:F)))

 

[david84]

Re : Recherche valeur dans un tableau

Bonsoir le fil,
pour la recherche des valeurs liées au noir :
pour les catégorie et sous-catégorie :

=SI(NB.SI(D$4:G$7;D$10)=0;"";INDIRECT(ADRESSE(MIN(SI(D$4:G$7=D$10;LIGNE(B$4:B$7)));LIGNES($1:2))))

à tirer vers le bas
pour l'entête :

=SI(NB.SI(D$4:G$7;D$10)=0;"";INDIRECT(ADRESSE(3;MIN(SI(D4:G7=D10;COLONNE(D3:G3))))))

Validation matricielle (à adapter pour les autres recherches).
A+

 

[Alain_V]

Re : Recherche valeur dans un tableau

Bonjour,

Super vos formules fonctionnent

Je suis impressionné par la rapidité et la qualité des réponses.

Je vous remercie tous pour le temps que vous avez passé pour trouver une solution à mon problème.

Les solutions proposées répondent à mon besoin immédiat (professionnel), mais je vois une possibilité d'utilisation pour un besoin perso.(super)

Un petit retour sur les formules proposées:
- proposition matricielle de Tibo ==> ok
- proposition matricielle de david84 ==> j'ai un code erreur, comme mon Excel est en Anglais j'ai du faire une erreur de traduction
- proposition non matricielle d'hoerwind ==> ok aussi

Encore un grand merci à tous.

Alain

PS: j'ai pas trouvé la fonction du forum qui permettrait de dire que le problème est soldé.

 

[hoerwind]

Re : Recherche valeur dans un tableau

Re, salut les autres,

Il n'y a pas sur le forum de fonction permettant de dire que le problème est résolu.
La raison en est simple et double (lol) :
- un problème n'est jamais entièrement résolu
- une question subsidiaire ou demande d'explication de la part d'un autre forumeur

Ma proposition de formule (SOMMEPROD) est matricielle, mais ne doit pas être validée comme telle.

 

[Alain_V]

Re : Recherche valeur dans un tableau

Merci pour ces précisions.

Je pense qu'un jour j'arriverai à comprendre la différence entre formule matricielle validée ou pas. Mais effectivement la formule même non validée comme telle s'applique bien à une matrice.

 

[Alain_V]

Re : Recherche valeur dans un tableau

Bonjour à tous,

Comme un problème n'est jamais vraiment soldé, me revoici avec une question complémentaire.

J'ai essayé de mettre en application les formules que vous m'avez proposé pour un nouveau besoin, mais cela ne fonctionne pas.

Je commence par vous expliquer mon besoin, j'importe un fichier de la banque et je souhaite attribuer une catégorie ainsi qu'une sous catégorie à chaque mouvement en fonction du tiers.

Pour ce faire j'ai un onglet "compte courant" qui contient les mouvements sur mon compte, et j'ai un autre onglet "catégories" qui lui contient toutes les catégories et sous-catégories que j'ai identifié avec les tiers répartis en colonnes (actuellement 40 colonnes mais ils pourraient y en avoir plus). Remarque un tiers ne pourra être présent que sur une seule catégorie.

Le besoin final étant de mettre la catégorie et sous-catégorie des tiers de l'onglet "compte courant" en fonction de la catégorie et sous-catégorie qui ont été affectés dans l'onglet "catégories".

Je joins un fichier exemple pour présenter cela.

Merci d'avance pour votre aide.

 

[Tibo]

Re : Recherche valeur dans un tableau

Bonsoir,

Dans la formule INDIRECT, il fallait ajouter la référence à la feuille Catégories.

Ca donne ceci en F3 :

=SI(NB.SI(Catégories!$D$2:$AQ$126;C3)=0;"";INDIRECT("Catégories!"&ADRESSE(SOMME((Catégories!$D$2:$AQ$126=C3)*LIGNE(Catégories!$B$2:$B$126));2)))

Toujours matricielle, donc validation par CTRL + MAJ + ENTREE

à recopier vers le bas

@+