recherche pour comparer dans une plage

[julbute]

Bonsoir,
voici ce que je recherche à faire, en vba.
J'ai une liste Nom , Prénom, Code dans des colonnes A,B & C dans une feuille 1.
Au démmarge du classeur excel, j'aimerai pouvoir comparer le code et le nom entrée dans une "inputbox", dans la liste.Afin de savoir qui ouvre le fichier et de renseigner automatiquement les infos le concernant dans differentes cellules de la feuille 2.
C'est plutôt la partie recherche est traitement de l'info qui me pose problème.
Merci pour votre aide
Rb

 

[Robert]

Re : recherche pour comparer dans une plage

Bonsoir Julbute, bonsoir le forum,

Peut êter comme ça :

Private Sub Workbook_Open()
Dim code As String 'déclare la variable code
Dim nom As String 'déclare la variable nom
Dim rc As Range 'eclare la variable rc (Recherche de Code)
 
Sheets("Feuil2").Activate 'active l'onglet "Feuil2" (pour qu'on ne voit pas la liste inscrite en "Feuil1")
code = InputBox("Quel est Votre Code ?") 'demande du code
nom = InputBox("Quel est Votre Nom ?") 'demande du nom
 
With Sheets("Feuil1") 'prend em compte l'onglet "Feuil1"
    Set rc = .Range("C2:C" & .Range("C65536").End(xlUp).Row).Find(code, , xlValues, xlWhole) 'définit la variable rc
    If Not rc Is Nothing Then 'condition 1 : si il existe au moins une occurrence de rc dans la colonne C
        If rc.Offset(0, -2).Value = nom Then 'condition 2 : si le nom de la colonne A correpond à la demande de nom
            'place ici tes codes et supprime le message...
            MsgBox "place ici tes codes et supprime le message..."
            Exit Sub 'sort de la procédure
        End If 'fin de la condition 2
        MsgBox "Nom non reconnu !"
        GoTo fin
    Else 'sinon (condition 1)
        MsgBox "Code non reconnu !" 'message
fin:
        ThisWorkbook.Close Savechanges:=False 'ferme le classeur
        'Application.Quit 'ferme l'application (ou ça pour être plus radical)
    End If
End With
End Sub

Mais il y a l'éternel problème si les macros ne sont pas activées...

 

[julbute]

Re : recherche pour comparer dans une plage

parfait,
merci bien Robert
j'ai fait un essai est cela fonctionne comme je voulais.
J'affinerai un peu et je posserai peut etre d'autres questions.
Merci encore.
Rb