Recherche à deux critères (sommeprod, comment utiliser?)

[josanche]

Bonjour,

J'aurais besoin de votre aide. Je pense que pour résoudre mon problème il faut utiliser la formule sommeprod mais j'arrive pas a maitriser l'utilisation de cette formule.

J'ai une Colonne à compléter. Les pourcentages se situe dans le cadrant gris H3:M9 et doivent se retrouver dans la colonne C en fonction des deux critères Age et quantité (Colonne A et B)

J'aimerais une formule qui renvoit par exemple dans la cellule C3: 25% car l'age (C3=8) est compris dans l'intervalle (6:8] où 8 est bien compris dans cet intervalle et car la quantité est de 3. Ensuite la formule doit etre tiré vers le bas.

J'ai mis des commentaires et des couleurs pour vous faciliter la tache dans le fichier excel en pièce jointe.

Voici la pièce jointe.

Bien à vous

 

[renyeu]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Bonjour,
Quelque chose de ce genre ? (voir pièce jointe)
Cdlt
Renyeu

 

[R@chid]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Bonjour,
En C3,

=SIERREUR(RECHERCHEV(MAX(A3;8);G$3:M$9;B3+1);"")

@ tirer vers le bas
@ + +

 

[JCGL]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Bonjour à tous,

Peux-tu essayer en C3 et vers le bas :

=SOMMEPROD(($F$3:$F$9<=$A3)*($G$3:$G$9>=$A3)*($I$1:$M$1=$B3)*$I$3:$M$9)

A+ à tous

 

[Modeste geedee]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Bonsour®
en C3:
=INDIRECT(ADRESSE(1+EQUIV(A3;$G$2:$G$9;1);8+EQUIV(B3;$I$1:$M$1;0)))

nb: j'ai bricolé (données distinctes) un peu la plage H3:M9 à fin de bien contrôler le fonctionnement

nb2: je ne pense pas que la solution SOMMEPROD soit la plus pertinente ...
on souhaite recouvrer le contenu d'une cellule en fonction de 2 critères(tableau à 2 entrées),
alors que sommeprod est dédié à la somme d'un produit de matrices

 

[R@chid]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Bonjour @ tous,
Peut-être comme ça c'est mieux,

=SIERREUR(RECHERCHEV(PLAFOND(A3;2);G$3:M$9;B3+1);"")

@ + +

 

[job75]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Bonjour à tous,

Une autre solution en C3 :

=DECALER(G$3;SOMMEPROD((A3>F$3:F$9)*(A3<=G$3:G$9)*LIGNE($3:$9))-3;B3)

Fichier joint.

A+

 

[job75]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Re,

Encore une autre, un peu pour le fun :

=SIERREUR(DECALER(G$2;EQUIV(A3-1/2;G$2:G$9);B3);"")

Voyez quand même le contenu de la cellule G2...

Fichier (2).

A+

 

[job75]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Re,

Mais R@chid a raison, c'est mieux avec RECHERCHEV :

=SIERREUR(RECHERCHEV(A3-1/2;F$3:M$9;B3+2);"")

Fichier (3).

A+

 

[josanche]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Merci les gars pour vos propositions.

En effet, la fonction sommeprof marche pas. Recherche V marche mieux dans ce cas -ci merciiiiiiiiii encor

bien à vous

josanch

 

[JCGL]

Re : Recherche à deux critères (sommeprod, comment utiliser?)

Bonjour à tous,

Je pense que le SOMMEPROD peut convenir, il suffit de modifier le chevron :

=SOMMEPROD(($M$3:$M$9<$A3)*($N$3:$N$9>=$A3)*($P$1:$T$1=$B3)*$P$3:$T$9)

A+ à tous