Problème de répartition de budget sur une période donnée

[Novata]

Bonjour à tous,

J'ai vraiment besoin de votre aide svp.
Je cherche à calculer l'impacte du budget sur l'exercice 2012. J'aimerais donc étaler le budget par mois selon:
- la période d'écheance (uniquement la période 2012, ce qui n'est en 2012 doit me rester en colonne U)
- date de déclenchement de la facture
- la périodicité de la facturation
- les taux de repartition.

Par exemple, dans mon tableau la ligne 14 devrait m'afficher les résultats suivants:

En juillet: 188.08*33.33% d'apport + (188.08*(33.33% de prodution + 33.33% de gestion))/6 (car échéance semestrielle)
En aout: (188.08*(33.33% de prodution + 33.33% de gestion))/6
En septembre: (188.08*(33.33% de prodution + 33.33% de gestion))/6
En octobre: (188.08*(33.33% de prodution + 33.33% de gestion))/6
En novembre: (188.08*(33.33% de prodution + 33.33% de gestion))/6
En décembre: (188.08*(33.33% de prodution + 33.33% de gestion))/6

En juillet le résultat s'affiche bien mais je n'arrive pas à avoir les 66.66% du budget sur les mois suivants

Pourriez-vous me proposer une solution svp?

Merci

 

[VDAVID]

Re : Problème de répartition de budget sur une période donnée

Bonjour Novata,

Pas sûr d'avoir tout compris (Ta formule est quelque peu complexe ^^' ), mais à tester en I14 et à faire glisser:

=SI(ET(MOIS($G14)=MOIS(O$1);ET(ANNEE($A14)<=2012;ANNEE($B14)>=2012));$E14*$Y$8;0)+SI(MOIS($G14)<=MOIS(O$1);($E14*$Y$9+$E14*$Y$10);0)/RECHERCHEV($F14;$W$2:$Y$5;3;0)

Je retombe de ce que j'ai compris sur le résultat espéré

Bonne journée!

 

[Novata]

Re : Problème de répartition de budget sur une période donnée

Bonjour Vdavid et merci beaucoup pour avoir pris le temps de me répondre.

Vous avez raison, la formule est complexe à interpreter, j'y suis depuis qq jours et je n'arrive pas à trouver la solution

Par rapport à votre formule je cherche l'inverse et plus encore

Je vais essayer d'être claire mais je sais que c'est pas évident à l'écrit comme ça:

-on étale le budget si et seulement si au mois un jour de l'exercice (2012) est compris entre la date début et la date fin,
-donc si pas un jour 2012 compris dans cette période pas d'étalement (je cherche à affecter le budget de 2012 à 2012),
-si minimum un jour de 2012 est compris dans cette période, alors affecter 33% d'apport du budget au mois correspondant à la date de déclenchement de la facture (33% du budget, pas de franctionnement à ce niveau là),
-les 66% du budget qui restent on les glisse sur l'exercice selon le fractionnement:
budget * (33% de production+33% de gestion)/périodicité
mais uniquement si la période d'échéance comprend 2012

Si l'on prend comme exemple la ligne 14:
la date début est le 08/07/2012
la date de fin est le 07/01/2013
la date de déclenchement est en 07/2012
Périodicité semestrielle

Donc en 07/2012 on prend les 33% d'apport
plus et seulement a partir de 07/2012 (car date début 08/07/2012) 1/6ème des 66% de production et de gestion pendant 6 mois. Sauf que l'on arrete de glisser en 12/2012 car la quote part de 01/2013 (date de fin 07/01/2013) ne m'intéresse pas parce qu'elle ne fait pas partie de l'exercice.

Cad, que si la date début est le 26/09/2011 et la date de fin le 25/09/2013 on glisse 66% dès le 01/12/2012 jusqu'au 31/12/2012 selon la périodicité + 33% à la date de déclenchement.

Rien que d'écrire ça mes pauvres neurones sont fatiguées

Help

 

[VDAVID]

Re : Problème de répartition de budget sur une période donnée

Re Novata,

Un autre essai, toujours en I4 à faire glisser:

=SI(ET(MOIS($G14)=MOIS(I$1);ET(ANNEE($A14)<=2012;ANNEE($B14)>=2012));$E14*$Y$8;0)+SI(ET(I$1>=DATE(ANNEE($A14);MOIS($A14);1);DATE(ANNEE($B14);MOIS($B14);1)>=I$1);($E14*$Y$9+$E14*$Y$10);0)/RECHERCHEV($F14;$W$2:$Y$5;3;0)

Ca me semble cohérent avec ta seconde description

Dis moi si c'est ce que tu attends
Bonne soirée!

 

[Novata]

Re : Problème de répartition de budget sur une période donnée

Vdavid, vous etes genial!!!

C'est exactement ça, un GRAND MERCIIII
Quand je vois la taille de votre formule par rapport à la mienne...

J'ai une autre question, cette fois ci toute petite, bon j'espère
Comment je pourrais faire afficher vide dans les cellulles où il y a 0.00

Merci, merci beaucoup

 

[VDAVID]

Re : Problème de répartition de budget sur une période donnée

Re Novata,

Par formule:

=SI(SI(ET(MOIS($G14)=MOIS(I$1);ET(ANNEE($A14)<=2012;ANNEE($B14)>=2012));$E14*$Y$8;0)+SI(ET(I$1>=DATE(ANNEE($A14);MOIS($A14);1);DATE(ANNEE($B14);MOIS($B14);1)>=I$1);($E14*$Y$9+$E14*$Y$10);0)/RECHERCHEV($F14;$W$2:$Y$5;3;0)=0;"";SI(ET(MOIS($G14)=MOIS(I$1);ET(ANNEE($A14)<=2012;ANNEE($B14)>=2012));$E14*$Y$8;0)+SI(ET(I$1>=DATE(ANNEE($A14);MOIS($A14);1);DATE(ANNEE($B14);MOIS($B14);1)>=I$1);($E14*$Y$9+$E14*$Y$10);0)/RECHERCHEV($F14;$W$2:$Y$5;3;0))

Mais c'est pas très joli, sinon il faut voir du côté du format des cellules !
Content de d'avoir aidé en tout cas
Bonne soirée

 

[Novata]

Re : Problème de répartition de budget sur une période donnée

C'est merveilleux, merci beaucoup Vdavid.
Ah oui, vous m'avez beaucoup aidé.

MERCI et bonne soirée