Probleme de recherche de données

[djunbi]

Bonjour le forum ,
je revient vers vous car j'ai un problème avec des rechercheV qui ne me trouve pas le bon résultat, je ne comprend pas pourquoi car j'en est déjà utilisé et qui fonctionnais parfaitement. Au début j'avais penser que c’était parce que le format des cellules n’était pas bon mais cela n'a pas fonctionner
De plus petite question peut associé des rechercheV et rechercheH ?

Voila mon problème, j'ai 3 société qui utilise des comptes comptables différent ou non, puis des codes CTG auquel sont rattaché c'est comptes comptables .Possibilité d'avoir plusieurs comptes comptables pour un CTG.

Je vous met un exemple

Pouvez vous m'aidez je galère depuis hier ?

 

[Spinzi]

Re : Probleme de recherche de données

Bonjour djunbi,

je n'ai pas les compétences requises, mais je pense qu'il faut s'orienter du coté d'un Index mêlé à un petit.valeur le tout validé en matriciel ...

 

[djunbi]

Re : Probleme de recherche de données

Bonjour Spinzi
Merci pour ta réponse rapide je vais essayer ce que tu me dit, pour Index pas de problème je connais déjà , par contre petit.valeur je ne connais pas du tout....

 

[ralph45]

Re : Probleme de recherche de données

Bonjour djunbi & Spinzi,

djunbi, si tu veux conserver tes résultats avec RECHERCHEV, il faut modifier ton onglet CTG COMPTE.
Il faut que la valeur cherchée soit toujours en "pole-position" (colonne 1) de ta matrice (voir en PJ)...

A+

 

[djunbi]

Re : Probleme de recherche de données

Bonjour, d'accord pour cela je comprend c'est tout bête et je n'y est pas pensé.
Par contre le compte 606450 doit correspondre à plusieurs CTG or la je n'arrive quand afficher 1seul. Je n'arrive pas a ce que la formule cherche plusieurs fois le numéro comptable 606450.
Faut t il que j'utilise la formule Index ou formule matricielle ?

Cordialement
djunbi

 

[R@chid]

Re : Probleme de recherche de données

Bonjour @ tous,
essayer en C2 :

=SI(COLONNES($C:C)<=NB.SI('CTG COMPTE'!$C:$C;$A2);INDEX('CTG COMPTE'!$A:$A;EQUIV($A2;'CTG COMPTE'!$C:$C;0)+COLONNES($C:C)-1);"")

@ tirer vers le bas et vers la droite
Amicalement

 

[Spinzi]

Re : Probleme de recherche de données

Bonjour le fil,

R@chid, pourrais tu m'expliquer cette formule ?
Merci bcp

 

[djunbi]

Re : Probleme de recherche de données

Bonjour ,
je viens de tester ta formule elle marche super bien j'adore . Je te remercie R@chid
Bien à vous Djunbi

 

[djunbi]

Re : Probleme de recherche de données

Re bonjour , je pense que j'ai parlé trop vite... . la premières colonnes fonctionne parfaitement , la formule va bien chercher les bonnes données. Mais après sur les autres c'est pas bon du tout..

 

[R@chid]

Re : Probleme de recherche de données

Bonjour,

Re bonjour , je pense que j'ai parlé trop vite... . la premières colonnes fonctionne parfaitement , la formule va bien chercher les bonnes données. Mais après sur les autres c'est pas bon du tout..

Oui je viens de faire attention que les données ne sont pas triées dans la colonne C de l'Onglet "CTG COMPTE", donc il faut impérativement passer par une formule matricielle si tu ne veux pas les trier...
en C2,

=SI(COLONNES($C:C)<=NB.SI('CTG COMPTE'!$C$2:$C$185;$A2);INDEX('CTG COMPTE'!$A$2:$A$185;PETITE.VALEUR(SI('CTG COMPTE'!$C$2:$C$185=$A2;LIGNE(INDIRECT("1:"&LIGNES('CTG COMPTE'!$C$2:$C$185))));COLONNES($C:C)));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas et vers la droite
@ micalement

 

[djunbi]

Re : Probleme de recherche de données

Bonjour , avant de crier victoire trop tôt comme la dernière fois j'ai vérifie et analysé . Toujours un problème apparait , la formule ne prend pas toutes les données , elle en prend plus que sur la première formules mais il en manque. J'ai remarquer que ce sont des données présente sur les colonnes autres que la 1 qui ne sont pas prise en comptes.
Je ne comprend pas . Cela peut être du au format de cellules ou non . J'ai mis un exemple en pieces jointe avec en rouge quelque données qui non pas apparut avec la formules

 

[R@chid]

Re : Probleme de recherche de données

Bonjour,
Voir PJ
la formule est matricielle comme j'ai dit sur le post #10
Amicalement

 

[djunbi]

Re : Probleme de recherche de données

Re bonjour ,
oui oui j'ai compris que c'était une formule matricielle qui s'applique avec Ctrl+Maj+Entree mais cela ne fonctionne pas elle ne me sort pas tout les bons comptes CTG il en manque en fait . Dans la dernière pièces jointes que j'ai publié les données dont les cellules sont en rouge ne sont pas prises avec la formules matricielle.
amicalement
djunbi

 

[R@chid]

Re : Probleme de recherche de données

ReBonjour,
Si j'ai bien compris en C2,

=SI(COLONNES($C:C)<=NB.SI('CTG COMPTE'!$C$2:$H$185;$A2);INDEX('CTG COMPTE'!$A$2:$A$185;PETITE.VALEUR(SI('CTG COMPTE'!$C$2:$H$185=$A2;LIGNE(INDIRECT("1:"&LIGNES('CTG COMPTE'!$A$2:$A$185))));COLONNES($C:C)));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas et vers la droite
je l'ai fait pour toute les comptes comptables de 1 @ 6,
si c'est pas le cas remplacer les H par des C dans la formule
Amicalement

 

[djunbi]

Re : Probleme de recherche de données

Oui la je suis d'accord ca fonctionne parfaitement, que je suis bête j'ai compris tu à agrandi la plage jusqu'a H moi j'avais essayer comme ça mais sans succès

=SI(COLONNES($C:C)<=NB.SI('CTG COMPTE'!$C$2:$C$185;$A2);INDEX('CTG COMPTE'!$A$2:$A$185;PETITE.VALEUR(SI('CTG COMPTE'!$C$2:$C$185=$A2;LIGNE(INDIRECT("1:"&LIGNES('CTG COMPTE'!$C$2:$C$185))));COLONNES($C:C)));COLONNES($d:d)<=NB.SI('CTG COMPTE'!$d$2:$d$185;$A2);INDEX('CTG COMPTE'!$A$2:$A$185;PETITE.VALEUR(SI('CTG COMPTE'!$d$2:$d$185=$A2;LIGNE(INDIRECT("1:"&LIGNES('CTG COMPTE'!$C$2:$C$185))));COLONNES($d:d)));"")


Jusqu' la colonne h mais non

Je te remerci pour l'aide que tu ma apporté
amicalement
Djunbi