Problème avec fonction SI

[jacksud]

Bonjour à tous

Voici mon problème c’est d’incrémenter ma formule en fonction des données en colonne A
Ce que je veux faire c’est quand j’ai en cellule A2 ;A3 ;A4 « 1/1 » c’est faire le calcul suivant : =(C2*4+C3*10+C4*10)/24 voir cellule C1096
Puis quand j’ai en cellule A5 ;A6 ;A7 « 2/1 » c’est faire le calcul suivant : =(C5*4+C6*10+C7*10)/24 voir cellule C1097
Et ainsi de suite mais comment l’automatiser ?

merci Jack

 

[JHA]

Re : Problème avec fonction SI

Bonjour à tous,

si bien compris, en "C1097":

=(INDIRECT(("C"&2+LIGNE()-1094))*4+INDIRECT("C"&3+LIGNE()-1094)*10+INDIRECT("C"&4+LIGNE()-1094)*10)/24
A tirer vers le bas
JHA

 

[jacksud]

Re : Problème avec fonction SI

Merci pour ta réponse rapide JHA
le calcul est bon sur la cellule "C1097" en revanche quand je tire la formule vers le bas les valeurs ne sont plus bonnes. Et quand je modifi une valeur en C6 par exemple cela modifi les cellules sur la droite ce qui n'est pas bon.
voir fichier

le résultat que je veux obtenir est en ligne 1096 et 1097

 

[hoerwind]

Re : Problème avec fonction SI

Bonjour, salut JHA,

A essayer en C1096 :

=(DECALER(C$1;EQUIV($A1096;$A$2:$A$28;0);)*4+DECALER(C$1;EQUIV($A1096;$A$2:$A$28;0)+1;)*10+DECALER(C$1;EQUIV($A1096;$A$2:$A$28;0)+2;)*10)/24

formule à copier vers le bas et vers la droite.

 

[jacksud]

Re : Problème avec fonction SI

Merci pour ta réponse je ne savais qu'il ne fallait recommencer un poste
ta formule marche bien pour les 9 premiers jours, mais arrivé au 10/01/2011 elle ne fonctionne plus
Jacques

 

[hoerwind]

Re : Problème avec fonction SI

Re,

Si tu avais au moins essayé de comprendre la formule, tu aurais constaté que la plage de recherche (sous les EQUIV) se limitait aux lignes 2:28, les autres étant masquées.
Modifie les 28 par 1093 et cela fonctionnera, même si elle restent masquées !

 

[jacksud]

Re : Problème avec fonction SI

Merci beaucoup Hoerwind j'ai modifié ta super formule et cela fonctionne très bien et maintenant je sais qu'il ne faut pas recréer de poste merci encore au forum et je n'oublierai pas de le soutenir....
Jack

 

[jacksud]

Re : Problème avec fonction SI

Nos messages se sont croisés et j'avais bien vu que la formule s'arrêtait-en ligne 2 :28 sans rancune
jack

 

[R@chid]

Re : Problème avec fonction SI

Salut Jaksud,
et un grand Salut a mon prof Hoerwind,
il n'y a pas plus simple que cette petite formule en C1096 :

=SOMMEPROD(DECALER(C$2;EQUIV($A1096;$A$2:$A$1093;0)-1;;3)*{4;10;10})/24

@ recopier vers le bas et vers la droite
@ +
@ Rachid

 

[jacksud]

Re : Problème avec fonction SI

merci rachid ta formule marche tres bien c'est sympa.....

 

[jacksud]

Re : Problème avec fonction SI

Bonjour rachid,
Peux-tu m'expliquer ta super formule Jack

 

[R@chid]

Re : Problème avec fonction SI

Salut,
pour ma formule c'est tres simple :

=SOMMEPROD(DECALER(C$2;EQUIV($A1096;$A$2:$A$1093;0)-1;;3)*{4;10;10})/24

la partie : DECALER(C$2;EQUIV($A1096;$A$2:$A$1093;0)-1;;3) va nous permetre de creer une plage dynamique en decalant C$2 jusqu'a EQUIV($A1096;$A$2:$A$1093;0)-1 c'est la ou elle commence a creer la plage et on sait tres bien que la plage contient 3 valeurs alors on a donne 3 comme hauteur de plage.
ce qui va donner =SOMMEPROD(Plage_cree*{4;10;10})/24
j'espere etre bien clair dans mes explications, je peux revenir t'expliquer tout ce soir si c'est pas suffisant, j'ai pas le temps maintenant.
@ + +

 

[jacksud]

Re : Problème avec fonction SI

Merci pour ta réponse rachid

Le -1 fait partie de la fonction DECALER ou EQUIV ?

Car j’ai vu que la fonction décaler avait 5 paramètres.
DECALER($B$2 ;7 ;2 ;16 ;3)

Correspondant
1. Cellule de départ
2. Décalage vers le bas (vers le haut si valeur négative)
3. Décalage vers la droite( vers la gauche si valeur négative)
4. Hauteur de la plage (en nombre de cellules)
5. Largeur de la plage (en nombre de cellules)



Dans notre cas :
· on part de B2
· on descend de 7 cellules, on arrive donc en B9
· on se décale de 2 cellules vers la droite on arrive en D9
· on définit à partir de cette plage 16 cellules de haut et 3 de large
· C’est à dire plage D9:F24

Si j’ai bien compris la fonction ou formule décaler on ne s’en sert pas seul.

En revanche combiner SOMMPROD et EQUIV avec décaler c’est la ou cela se corse !
Si tu as plus d’information ou exemple merci Jack

 

[R@chid]

Re : Problème avec fonction SI

Salut,

=SOMMEPROD(DECALER(C$2;EQUIV($A1096;$A$2:$A$1093;0)-1;;3)*{4;10;10})/24

C$2 : cellule de depart
EQUIV($A1096;$A$2:$A$1093;0)-1 : nombre de ligne a decaler pour trouver l'origine du plge a creer
Largeur : nombre de colonnes a decaler ici c'est omi ==> ;j'ai laisse vide;
3: la hauteur du plage a cree c'est 3 lignes
la largeur est omis aussi puisqu'on va travailler sur une seule colonne.
d'ou on resulte : on a cree une plage qui se compose de 3 lignes et une seule colonne
j'espere etre bien clair sur mon explication
@ + +

 

[jacksud]

Re : Problème avec fonction SI

Merci Rachid pour ces explications
Jack