Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

[Fusky]

Bonjour,

J'essaie sans resultat de prendre des infos dans un tableau en discriminant par date, sachant que les dates ne sont pas dans l'ordre (et ne le doivent pas) et au'il y a parfois plusieurs reponses.

Ci-joint mon exemple


Si vous pouvez y jeter un oeil, ca m'aiderai surement.

Merci

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Bonjour,

Quelques formats dans le fichier joint

 

[Fusky]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Bonjour,


Je reviens vous embettez encore un peu avec mes tableaux !
Tout d'abord merci pour le premier, j'ai pu l'integrer parfaitement bien.

Maintenant j'ai besoin de faire une recap un peu differente.
Je joint un exemple.

Il s'agit de faire la somme de plusiers element portant le meme nom, mais a des dates differentes ...

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Bonjour,

Un essai

Pour extraire les noms sans doublon : formule matricielle, à valider par ctrl, maj et entrée

Ligne de dates :
1ère cellule blanc sur blanc
2ème cellule format "mmmm"
3ème cellule format "aaaa"
Pas très heureux, mais ça permet d'avoir la même formule dans tout le tableau de résultats

Tableau de résultats, format # ##0;; pour éviter d'avoir plein de 0

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Re,

Une autre version
extraction du nom des voitures par ordre alphabétique

 

[Fusky]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

J'ai adapte ta premiere proposition a mon fichier, mais je n'arrive pas a avoir la somme des pts, je n'ai que la premiere proposition.

Je colle ici la formule, la syntaxe est presque la meme que la tienne (en un peu simplifiee pour les dates, je prefere faire une feuille par mois pour les donnees brutes) et elle me paraeit correcte, mais si jamais tu vois qqch ...

=SUMPRODUCT(('Apr 07'!$H$3:$H$1000=Recap!F$54)*('Apr 07'!$C$3:$C$1000=Recap!$C55),'Apr 07'!$P$3:$P$1000)

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Re,

Qu'est-ce qu'il y a en Recap!F$54 et en Recap!$C55 ?

 

[Fusky]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Erreur stupide de la part de celui qui a rentre les donnees dans le tableau : pour le type j'ai par exemple la valeur EMPTY, mais qui est parfois orthographiee avec un espace ou + apres ... ca fausse tout ! J'ai trop de donnees pour renommer (CTRL+F) je risque d'en oublier.
Peut-on demander a Xl de de trouver toutes les cellules contenants "EMPTY" mais pas strictement ( qu'il considere egalement les cellules qui contiennent plus de caracteres, comme des espaces ...) et l'integrer dans la formule ?
QQch comme :

=SUMPRODUCT(('Apr 07'!$H$3:$H$1000 = EGALE STRICTEMENT OU BIEN CONTIENT ENTRE AUTRE = Recap!F$54)*('Apr 07'!$C$3:$C$1000=Recap!$C55),'Apr 07'!$P$3:$P$1000)

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Bonjour,

Avec Supprespace(), ça devrait aller
SOMMEPROD(()*()*()*(SUPPRESPACE(Plage)=Réf);Plage à sommer)
en angliche :
SUMPRODUCT(()*()*()*(TRIM(Plage)=Réf),Plage à sommer)

Dans le fichier d'hier, en I5, ça donnerait :
=SOMMEPROD((ANNEE($B$3:$B$30)=ANNEE(I$3))*(MOIS($B$3:$B$30)=MOIS(I$3))*(SUPPRESPACE($C$3:$C$30)=I$4)*($A$3:$A$30=$H5);$D$3:$D$30)

=SUMPRODUCT((YEAR($B$3:$B$30)=YEAR(I$3))*(MONTH($B$3:$B$30)=MONTH(I$3))*(TRIM($C$3:$C$30)=I$4)*($A$3:$A$30=$H5),$D$3:$D$30)

 

[Fusky]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

J'ai egalement besoin de recuperer une info relative au nunmero de voiture. J'ai peur d'utiliser la meme formule au cas ou l'odre des donnees initiales ne soient pas le meme.

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Bonjour,

Avec Index Equiv
En I5 :
=SI(J5="";"";INDEX(A$3:A$30;EQUIV(J5;B$3:B$30;0)))
En angliche :
=IF(J5="","",INDEX(A$3:A$30,MATCH(J5,B$3:B$30,0)))

Pourquoi tu dis ça :
"recuperer une info relative au numero de voiture"

 

[Fusky]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Impeccable.

A cote de ca j'ai en A1 une date mettons "01/01/07" que je formate en "Jan 07", et en B1 j'ai colle cette formule =CONCATENATE("'",A1,"'!C3:C300").
Je m'attendais a avoir 'Jan 07'!C3:C300 comme reponse, mais en fait il ne prend pas la date sous la forme qu'elle revet en A1, et me renvoie qqch comme '39857'!C3:C300 ...
Comment faire ?

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Re,

La date en texte avec le format que tu as choisi :
=TEXTE(A1;"mmm aa")

La formule que tu donnes :
="'"&TEXTE(A1;"mmm aa")&"'!C3:C300"
(TEXT en angliche)

Avec une majuscule :
="'"&NOMPROPRE(TEXTE(A1;"mmm aa"))&"'!C3:C300"
="'"&PROPER(TEXT(A1,"mmm aa"))&"'!C3:C300"

 

[Fusky]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Bonjour,

Quelques formats dans le fichier joint

Je reviens un peu en arriere, car il y a tout de meme un bug : les donnees chiffrees que je recupere ne sont pas des nombres !
J'ai beau les conditionner dans les formats que vous m'avez envoye (RechercheFuskyV3.zip), il n'y a pas moyen de faire une somme ... c'est du texte ...

Que faire ?

PS: pour rappel, voici la formule utilisee

=IF(SUM((MONTH(INDIRECT($C$3))=MONTH(MGA!$B$7))*(YEAR(INDIRECT($C$3))=YEAR(MGA!$B$7)))<ROWS($H$12:H12),"",INDEX(INDIRECT($B$10),SMALL(IF(MONTH(INDIRECT($C$3))=MONTH(MGA!$B$7),IF(YEAR(INDIRECT($C$3))=YEAR(MGA!$B$7),COLUMN(INDIRECT($C$10)))),ROWS($H$12:H12)))&"")

 

[Monique]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Bonjour,

à essayer

Tu enlèves le &"" en bout de formule
et tu mets la cellule au format suivi de ;;

IF(SUM((MONTH(INDIRECT($C$3))=MONTH(MGA!$B$7))*(YEAR(INDIRECT($C$3))=YEAR(MGA!$B$7)))<ROWS($H$12:H12),"",INDEX(INDIRECT($B$10),SMALL(IF(MONTH(INDIRECT($C$3))=MONTH(MGA!$B$7),IF(YEAR(INDIRECT($C$3))=YEAR(MGA!$B$7),COLUMN(INDIRECT($C$10)))),ROWS($H$12:H12)))

Sauf que je ne vois pas où est cette formule
Un fichier de quelle date ?
Edit - Trouvé : colonne C du fichier du 14-07 à 11h29

 

[Fusky]

Re : Piocher dans un tableau (discrimination par date, non classees,ac plusieurs reponses)

Merci, j'ai juste enleve les &"", et ca marche.

Dites moi, peut-on demander a une macro d'executer un ordre si (par ex) A1>5 ?
Il ne s'agit pas de conditionner l'execution de la macro mais de conditionner la copy d'une plage de cellule en plus du reste de la macro.