ouverture de fichier zip

[sabrina64]

bonjour
j aimerais savoir s il est possible d ecrire une macro permettant d ouvrir un fichier zip , d en extraire ses éléments.

j ai essayé de faire une macro avec l enregistreur masi san succès.....;

quelqu un a une idée?

je travaill avec excel 97

sans me donner les programmes, si vous avez de la doc..........

merci beaucou p.

 

[Spitnolan08]

Re : ouverture de fichier zip

Bonjour,

Je te joints un fichier avec des macros pour utiliser WinZip mais je ne sais pas si elles fonctionnent sous 97...
Regardes si tu y trouves ton bonheur.

Cordialement

 

[Staple1600]

Re : ouverture de fichier zip

Bonjour le forum, le fil, Spitnolan08


Dans la même veine que la macro de Spitnolan08

(enfin je suppose car je n'ai pas encore regarder son fichier)

J'y vais de ce pas.


Pré-requis avoir Winzip installé sur ton poste

Sub De_Zipper_Fichier(fichier As String)
Dim CheminWZip As String
Dim Fichier_ZIP As String
Dim Lig_CMD As String
Dim Dossier As String
Dim DeZip
     
CheminWZip = "C:\Program Files\Winzip\"

If Dir(CheminWZip & "winzip32.exe") = "" Then _
MsgBox "Winzip n'est pas installé sur cet ordinateur" _
& Chr(13) & "ou ne se situe pas dans C:\Program Files\Winzip .", _
vbCritical, "Attention ERREUR": Exit Sub

'adapter le nom du dossier ou se trouve le fichier zip
Dossier = "C:\Temp\"
     
Lig_CMD = CheminWZip & "Winzip32 -min -e" & " " & Chr(34) & fichier & Chr(34) _
& " " & Chr(34) & Dossier & Chr(34)

DeZip = Shell(Lig_CMD, 0)
   
End Sub

Lancer cette macro pour tester la décompression
Sub test_decompresseVBA()
De_Zipper_Fichier ("toto.zip")' ici mettre le nom de fichier adéquat
End Sub

A+

Staple


EDIT: vu le fichier de Spitnolan08 (du bien bel ouvrage ma foi et exhaustif avec ça ! bravo

 

[Staple1600]

Re : ouverture de fichier zip

Re

Si tu es sous Windows XP (pas besoin de Winzip)

avec la macro ci-dessous:

Sub Unzip1()
    Dim FSO As Object
    Dim oApp As Object
    Dim fname
    Dim FileNameFolder
    Dim DefPath As String
    Dim strDate As String

    fname = Application.GetOpenFilename(filefilter:="Zip Files (*.zip), *.zip", _
                                        MultiSelect:=False)
    If fname = False Then
        'do nothing
    Else
        DefPath = Application.DefaultFilePath
        If Right(DefPath, 1) <> "\" Then
            DefPath = DefPath & "\"
        End If

        strDate = Format(Now, " dd-mm-yy h-mm-ss")
        FileNameFolder = DefPath & "MyUnzipFolder " & strDate & "\"

        'Create normal folder
        MkDir FileNameFolder

        Set oApp = CreateObject("Shell.Application")
        'Copy the files in the newly created folder
        oApp.Namespace(FileNameFolder).CopyHere oApp.Namespace(fname).items

        MsgBox "You find the files here: " & FileNameFolder
        On Error Resume Next
        Set FSO = CreateObject("scripting.filesystemobject")
        FSO.deletefolder Environ("Temp") & "\Temporary Directory*", True

        Set oApp = Nothing
        Set FSO = Nothing
    End If
End Sub

source de cette macro:ici

 

[sabrina64]

Re : ouverture de fichier zip

Merci beaucoup pour votre aide je vais regarder tout cela bien attentivement.

Bonne journee