numérotation auto par impression

[SIMO]

Bonjour,

J'ai un fichier excel dans lequel je numérote le document. J'aimerais que la numérotation se fasse automatiquement à chaque impression pour être sur de n'avoir jamais 2 numéros identiques.

Merci d'avance

 

[david84]

Re : numérotation auto par impression

Bonsoir,
tu peux mettre en place un compteur dans une cellule de ta feuille et y faire référence dans ton code.
Ce compteur serait incrémenté à chaque impression et tu pourrais ainsi t'y référer.
A+

 

[eriiic]

Re : numérotation auto par impression

Bonjour,

Regarde si ça te va, à mettre dans thisworkbook :

Private Sub Workbook_BeforePrint(Cancel As Boolean)
    If ActiveSheet.Name <> "Feuil1" Then Exit Sub
    [A1] = [A1] + 1
End Sub

eric

 

[SIMO]

Re : numérotation auto par impression

bonsoir
merci eric et david
j'ai un petit problème lorsque je lance l'impression de 10 page j'ai reçois 10 page imprime mais avec le même numéro

voir fichier
merci d’avance

 

[Compte Supprimé 979]

Re : numérotation auto par impression

Bonjour le fil

Il suffit de lancer le code suivant par un bouton "Impression"

Sub Impression()  Dim Inc As Integer, NbEx As Integer
  NbEx = InputBox("Combien de pages voulez-vous ?", "Nombre de page", 1)
  With Sheets("Feuil1")
    For Inc = 1 To NbEx
    .Range("C5").Value = Inc
    .Range("C27").Value = Inc
    .PrintOut
    Next Inc
  End With
End Sub

A+

 

[SIMO]

Re : numérotation auto par impression

merciiiiiiiiiiiiiiiiiiii bcp

 

[SIMO]

Re : numérotation auto par impression

bonsoir bruno
j'ai un petit problème lorsque je annuler ou click fermer
voir photo
merci

 

[SIMO]

Re : numérotation auto par impression

merci bruno
j'ai trouve la solution

Private Sub CommandButton1_Click()
NbEx = InputBox("Combien de pages voulez-vous ?", "Nombre de page", 1)
With Sheets("Feuil1")
If IsNumeric(NbEx) Then
For Inc = 1 To NbEx
.Range("C5").Value = Inc
.Range("C27").Value = Inc
.PrintOut
Next Inc
Else
Exit Sub
End If
End With

End Sub

 

[SIMO]

Re : numérotation auto par impression

SALUT jai un autre problème, toujours le code de fiche commence par 1 c-a-d il garde pas le dernier

 

[Gelinotte]

Re : numérotation auto par impression

Bonsoir,


À tester :

If not IsNumeric(NbEx) Then exit sub

Enlever le "End if" car il n'y en a plus besoin quand la condition et l'action sont sur la même ligne.


G

 

[SIMO]

Re : numérotation auto par impression

bonjour
Merci j’ai teste mais il reste le même problème chaque relancement de l’impression il commence la numérotation de document par 1 sans incrémentation
Voila le code
Private Sub CommandButton1_Click()
NbEx = InputBox("Combien de pages voulez-vous ?", "Nombre de page", 1)
With Sheets("Feuil1")
If Not IsNumeric(NbEx) Then Exit Sub
For Inc = 1 To NbEx
.Range("C5").Value = Inc
.Range("C27").Value = Inc
.PrintOut
Next Inc
End With
End Sub
Merciiiiiiiiiiiiiiiiiiiiiiiiiiiiiiii bcp

 

[Compte Supprimé 979]

Re : numérotation auto par impression

Re,

Voici le code souhaité

Sub Impression()
  Dim Deb As Integer, Inc As Integer, NbEx As Variant
  NbEx = InputBox("Combien de pages voulez-vous ?", "Nombre de page", 1)
  ' Si clique sur annuler, on sort
  If NbEx = "" Then Exit Sub
  ' Si la valeur n'est pas nuémrique
  If Not (IsNumeric(NbEx)) Then
    MsgBox "La valeur saisie doit être un chiffre !", vbCritical, "ATTENTION ..."
    Exit Sub
  End If
  ' Transformer en valeur entière
  NbEx = CInt(NbEx)
  ' Avec la feuille
  With Sheets("Feuil1")
    ' Si jamais eu d'impression on commence à 1
    ' Sinon on incrémente pour la suite
    If .Range("C5").Value = "" Then Deb = 1 Else Deb = CInt(.Range("C5")) + 1
    ' Faire la boucle du début jusqu'au nombre d'exemplaire
    For Inc = Deb To Deb + NbEx - 1
    .Range("C5").Value = Inc
    .Range("C27").Value = Inc
    .PrintOut
    Next Inc
  End With
End Sub

A+

 

[SIMO]

Re : numérotation auto par impression

Bonjour Merci bcp il ya une astuce pour souvgarde l'incrementation automatique avent fermer le ficher ?

 

[Compte Supprimé 979]

Re : numérotation auto par impression

Re,

Etraneg question !?

Répondre "Oui" à la question : Voulez-vous sauvegarder avant de fermer

 

[SIMO]

Re : numérotation auto par impression

Rebonjour No ma question c faire un code dans botton imprimer pour force le sauvgarde a la fin d'impression, merci