Nettoyer une liste en mettant l'article apres un titre, entre parenthese

[agnesd]

Chers tous,

Je cherche a nettoyer une liste en mettant l'article qui se trouve parfois en debut de titre (et donc de cellule) pour le mettre apres le titre, entre parentheses, comment faire svp ?

C'est a dire LE SAUVAGE devient avec la formule SAUVAGE (Le).

cf fichier en annexe.

Merci beaucoup et bonne soireee,

Agnes

 

[Victor21]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Bonsoir, agnesd.

Peut-être :

=STXT(B2;TROUVE(" ";B2)+1;9^9)&" ("&STXT(B2;1;TROUVE(" ";B2)-1)&")"

à recopier vers le bas.

 

[agnesd]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Merci beaucoup, malheureusement cela ne semble pas marcher.

bonne journee,

Agnes

 

[Victor21]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Bonjour, agnesd

Merci beaucoup, malheureusement cela ne semble pas marcher.

Probablement un phénomène météorologique local

 

[excfl]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Bonjour le forum,

Pour compléter l'excellente formule de Victor21 (que je salue) :

=SI(OU(GAUCHE(B2;3)="La ";GAUCHE(B2;3)="Le ";GAUCHE(B2;4)="Les ");STXT(B2;TROUVE(" ";B2)+1;9^9)&" ("&STXT(B2;1;TROUVE(" ";B2)-1)&")";B2)

 

[agnesd]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Ca doit etre ca !

En fait, j'utilise excel en anglais donc j'ai traduit la formule : voici ce que ca donne (mais peut etre que je fais une erreur quelque part) =MID(B2;FIND(" ";B2)+1;9^9)&"("&MID(B2;1;FIND(" ";B2)-1)&")"
Mais j'ai un message d'erreur.

Merci en tout cas,

Agnes

 

[ROGER2327]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Bonjour à tous.

Bonjour, agnesd

Merci beaucoup, malheureusement cela ne semble pas marcher.

Probablement un phénomène météorologique local

Farpaitement !
Cette formule est une bonne base de travail qui donne le résultat souhaité dans la plupart des cas.
C'est un peu facile de la balayer d'un revers de main !
Il y a quelques cas d'échecs (lignes 42 à 45, lignes 88 à 90), mais vous avez malgré tout une belle avancée.
Essayez ceci :

=SUBSTITUE(SI(MIN(SIERREUR(CHERCHE("le ";$B2);999);SIERREUR(CHERCHE("la ";$B2);999);SIERREUR(CHERCHE("les ";$B2);999);SIERREUR(CHERCHE("l'";$B2);999))=1;STXT(SUBSTITUE(B2;"'";"' ");TROUVE(" ";SUBSTITUE(B2;"'";"' "))+1;9^9)&" ("&STXT(B2;1;TROUVE(" ";SUBSTITUE(B2;"'";"' "))-1)&")";B2);"' ";"'")

et remerciez Victor21[SUP][1][/SUP].
​

Bonne journée.



[SUP][1][/SUP]... et excfl.

ℝOGER2327
#7749

Vendredi 20 Gueules 142 (Saint Lafleur, valet - fête Suprême Quarte)
26 Pluviôse An CCXXIII, 5,4948h - guède
2015-W07-6T13:11:15Z

 

[gosselien]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Bonjour

si ça peut aider:
Toutes

P.

 

[ROGER2327]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Suite...


Les trois propositions.


ℝOGER2327
#7750

Vendredi 20 Gueules 142 (Saint Lafleur, valet - fête Suprême Quarte)
26 Pluviôse An CCXXIII, 5,6621h - guède
2015-W07-6T13:35:21Z

 

[agnesd]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

un grand merci a tous !

Je vais regarder les differentes reponses proposees et notamment la premiere sur un ordinateur avec Excel en francais, l'erreur venait surement de la retranscription en anglais. Je ne balaie rien du tout... et j'apprecie vos efforts !

Je ne manquerai pas de vous tenir au courant.

Bon dimanche,

Agnes

 

[agnesd]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

bonjour,

Je dirai juste...

Bravo et merci a tous, c'est parfait. Et tres interessant de comparer les differentes solutions proposees.

Tres bonne journee a vous,

Agnes

 

[ROGER2327]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Suite...

Une variante.​

=SUBSTITUE(SI(MIN(
SIERREUR(CHERCHE("UN ";$B2);2);SIERREUR(CHERCHE("UNE ";$B2);2);
SIERREUR(CHERCHE("L'";$B2);2);SIERREUR(CHERCHE("LE ";$B2);2);
SIERREUR(CHERCHE("LA ";$B2);2);SIERREUR(CHERCHE("LES ";$B2);2);
SIERREUR(CHERCHE("AU ";$B2);2);SIERREUR(CHERCHE("AUX ";$B2);2);
SIERREUR(CHERCHE("DE ";$B2);2);SIERREUR(CHERCHE("DES ";$B2);2);
SIERREUR(CHERCHE("À"&CAR(160)&"l'";SUBSTITUE($B2;" L'";CAR(160)&"L'"));2);
SIERREUR(CHERCHE("DE"&CAR(160)&"l'";SUBSTITUE($B2;" L'";CAR(160)&"L'"));2);
SIERREUR(CHERCHE("À"&CAR(160)&"la";SUBSTITUE($B2;" LA";CAR(160)&"LA"));2);
SIERREUR(CHERCHE("DE"&CAR(160)&"la";SUBSTITUE($B2;" LA";CAR(160)&"LA"));2))=1;
SUBSTITUE(STXT(SUBSTITUE(SUBSTITUE(SUBSTITUE($B2;" LA";CAR(160)&"LA");" L'";CAR(160)&"L'");"'";"' ");
    TROUVE(" ";SUBSTITUE(SUBSTITUE(SUBSTITUE($B2;" LA";CAR(160)&"LA");" L'";CAR(160)&"L'");"'";"' "))+1;999)
    &" ("&STXT(SUBSTITUE(SUBSTITUE($B2;" LA";CAR(160)&"LA");" L'";CAR(160)&"L'");1;
    TROUVE(" ";SUBSTITUE(SUBSTITUE(SUBSTITUE($B2;" LA";CAR(160)&"LA");" L'";CAR(160)&"L'");"'";"' "))-1)&")";
CAR(160);" ");
B2);"' ";"'")

Il ne reste plus qu'aux spécialistes de l'expression régulière de frapper.​

ℝOGER2327
#7762

Dimanche 22 Gueules 142 (Saint Sexe, Stylite - fête Suprême Première seconde)
28 Pluviôse An CCXXIII, 5,7745h - cyclamen
2015-W08-1T13:51:31Z

 

[agnesd]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

bonjour à tous,

Je voulais juste dire que je venais de me servir à nouveau de la formule et que je vous remercie, cela me fait gagner beaucoup de temps et marche vraiment très bien.

Bonne après-midi,

Agnès

 

[gosselien]

Re : Nettoyer une liste en mettant l'article apres un titre, entre parenthese

Sympa ça, de venir donner une suite

P.