Moyenne d'une somme de fraction avec doublons

[poulie]

Bonjour à tous,

Aprés avoir cherché sans succés, je me résouds à faire une demande d'aide publique...

J'ai deux calculs à effectuer.

Pour le premier: je réalise la somme de fractions avec des dénominateurs différents puis je divise cette somme par le nombre de fractions. Je pense y être parvenu avec notamment la fonction SOMMEPROD.

Pour le second: je réalise la somme de fractions si les résultats (numérateurs) sont inférieurs aux seuils (dénominateurs).
Je n'y parviens pas d'autant plus que des fractions peuvent être identiques (doublons). J'ai essayé avec une colonne intermédiaire.

Je vous remercie de ce que vous pourrez faire.

Bonne réception

 

[Dranreb]

Re : Moyenne d'une somme de fraction avec doublons

Bonjour.

=SOMME(SI($N$4:$N$9<$O$4:$O$9;$N$4:$N$9/$O$4:$O$9;0))/SOMME(N($N$4:$N$9<$O$4:$O$9))

validé par Ctrl+Maj+Entrée

Remarque: pour la 1ère j'aurais mis:

=MOYENNE($N$4:$N$9/$O$4:$O$9)

validé aussi par Ctrl+Maj+Entrée
Cordialement.

 

[poulie]

Re : Moyenne d'une somme de fraction avec doublons

Bonsoir Dranreb,

Tout d'abord un grand merci.

Pour la seconde, j'avais tenté sans succés une formule matricielle.
Pour la première c'est en effet plus simple.

Merci encore

 

[R@chid]

Re : Moyenne d'une somme de fraction avec doublons

Bonjour Poulie,
Salut Dranreb,
Pour la 2eme, on peut faire simple :

=MOYENNE(SI(N4:N9<O4:O9;N4:N9/O4:O9))

@ valider par Ctrl+Maj+Entree
Amicalement

 

[Modeste geedee]

Re : Moyenne d'une somme de fraction avec doublons

Bonsour®
pour la première :
=SOMMEPROD($N$4:$N$9/$O$4:$O$9)/SOMMEPROD(1*($N$4:$N$9<>0))
pour la seconde :
=SOMMEPROD(($N$4:$N$9/$O$4:$O$9)*($N$4:$N$9<$O$4:$O$9))/SOMMEPROD(1*($N$4:$N$9<$O$4:$O$9))

 

[R@chid]

Re : Moyenne d'une somme de fraction avec doublons

Bonsoir @ tous,
Salut Modeste,
Peut être déjà fait par Dranreb
Amicalement

 

[poulie]

Re : Moyenne d'une somme de fraction avec doublons

Bonjour Rachid_0661, Modeste geedee, Bonjour à tous,

Rachid_0661, en effet cela paraît simple. Je me suis bien compliqué lors de mes recherches... Cela veut-il dire aussi que le temps de calcul sera moins long ?.

Merci Rachid, merci encore à vous trois.

 

[Modeste geedee]

Re : Moyenne d'une somme de fraction avec doublons

Bonsour®

Peut être déjà fait par Dranreb

il ne s'agit que d'une variation :

• n'utilisant pas la validation matricielle
• et de formulation similaire pour chaque réponse

=SOMMEPROD(Calcul*condition)/SOMMEPROD(1*(condition))

 

[R@chid]

Re : Moyenne d'une somme de fraction avec doublons

Bonjour @ tous,

il ne s'agit que d'une variation :

• n'utilisant pas la validation matricielle
• et de formulation similaire pour chaque réponse

• 
  

  Dranreb :
  =SOMME(SI($N$4:$N$9<$O$4:$O$9;$N$4:$N$9/$O$4:$O$9;0))/SOMME(N($N$4:$N$9<$O$4:$O$9))

  Amicalement

 

[Modeste geedee]

Re : Moyenne d'une somme de fraction avec doublons

Bonsour® Rachid

Dranreb :
=SOMME(SI($N$4:$N$9<$O$4:$O$9;$N$4:$N$9/$O$4:$O$9;0))/SOMME(N($N$4:$N$9<$O$4:$O$9))
validé par Ctrl+Maj+Entrée

modeste geedee :
=SOMMEPROD(($N$4:$N$9/$O$4:$O$9)*($N$4:$N$9<$O$4:$O$9))/SOMMEPROD(1*($N$4:$N$9<$O$4:$O$9))
validé par Entrée

ami calmement...