Lister les dossiers d'un répertoire dans listbox

[Fabdu57100]

Bonjour à tous,
J'aurai besoin de votre aide pour constituer une macro.

Je souhaiterai lister les dossiers (uniquement : pas les sous-dossiers) d'un répertoire choisi (par exemple "L:\Dossier" dans un listbox dénommé "txt_folder" aprés avoir cliqué sur un bouton nommé "Btn_go".

Pourriez-vous m'aider a la constitution du code svp ? car je tourne en rond et n'arrive pas 🙁.

    Private Sub Btn_go_Click()
        Dim i As Integer
            For i = 0 To My.Computer.FileSystem.GetFiles("L:\").Count - 1
            txt_folder.Items.Add (My.Computer.FileSystem.GetFiles("L:\").Item(i))
        Next i
    End Sub

Merci d'avance,
Fab

 

[Robert]

Re : Lister les dossiers d'un répertoire dans listbox

Bonsoir Fab, bonsoir le forum,

Tiré et adapté de l'aide VBA car je galère aussi avec ce genre de problème...

Private Sub Btn_go_Click()
MyPath = "L:\"    ' Définit le chemin d'accès.
MyName = Dir(MyPath, vbDirectory)    ' Extrait la première entrée.
Do While MyName <> ""    ' Commence la boucle.
    ' Ignore le dossier courant et le dossier
    ' contenant le dossier courant.
    If MyName <> "." And MyName <> ".." Then
        ' Utilise une comparaison au niveau du bit pour
        ' vérifier que MyName est un dossier.
        If (GetAttr(MyPath & MyName) _
            And vbDirectory) = vbDirectory Then
            Me.txt_folder.AddItem MyName    ' Affiche l'entrée uniquement si elle
        End If    ' représente un dossier.
    End If
    MyName = Dir    ' Extrait l'entrée suivante.
Loop
End Sub

 

[Fabdu57100]

Re : Lister les dossiers d'un répertoire dans listbox

Super, ca fonctionne.
Merci beaucoup 🙂