Liaisons cellules prioritaires

[GBR]

Bonjour,

Besoin d'aide pour l'exemple joint
Quand on modifie la cellule L19 EQ1 il faut quelle devienne prioritaire et que les modifs se repercutent sur toutes les autres equipes en cellule L19 (onglets EQ2,,,EQ3,,EQ4 etc...)
Quand on modifie la cellule L19 EQ2 il faut quelle devienne a son tour prioritaire et que les modifs se repercutent sur toutes les autres equipes en cellule L19 (onglets EQ1,,,EQ3,,EQ4 etc...)

Impossible d'utiliser les liaisons simples ='EQ1'!$L$19 ??????
y at'il une fonction d'excel ou une macro pour ce type de liaisons
Je plafonne, il me faut une aide.....
Ci joint prog d'exemple...

Amicalement

 

[ERIC S]

Re : Liaisons cellules prioritaires

Bonjour

à essayer

pour chaque feuille

Private Sub Worksheet_Change(ByVal Target As Range)
Dim feuille As Worksheet
'si encours =1 sort pour éviter le bouclage
If encours = 1 Then Exit Sub
'pour exemple zone limitée, à étendre à toute la zone de planning
If Intersect(Range("C13:T22"), Range(Target.Address)) Is Nothing Then Exit Sub
encours = 1
'boucle sur toutes les feuilles
For Each feuille In Sheets
feuille.Range(Target.Address).Value = Target.Value
Next
encours = 0
End Sub


en plus déclarer encours comme variable globale sur une feuille de module

public encours

 

[GBR]

Re : Liaisons cellules prioritaires

Me revoila,

merci Eric s
Sa marche sauf que après ma saisie sa m'envoi un message (execution interompue et same bloque excel) ??

ma variable globale est elle bonne ?
Public encours As Variant


Qui a une idée du problème ?

 

[GBR]

Re : Liaisons cellules prioritaires

erreur....

Il faut lire:

Global encours As Variant


merci

 

[ERIC S]

Re : Liaisons cellules prioritaires

re

essaie, chez moi cela marche (sauf erreur)

 

[Gorfael]

Re : Liaisons cellules prioritaires

Bonjour,

Besoin d'aide pour l'exemple joint
Quand on modifie la cellule L19 EQ1 il faut quelle devienne prioritaire et que les modifs se repercutent sur toutes les autres equipes en cellule L19 (onglets EQ2,,,EQ3,,EQ4 etc...)
Quand on modifie la cellule L19 EQ2 il faut quelle devienne a son tour prioritaire et que les modifs se repercutent sur toutes les autres equipes en cellule L19 (onglets EQ1,,,EQ3,,EQ4 etc...)

Impossible d'utiliser les liaisons simples ='EQ1'!$L$19 ??????
y at'il une fonction d'excel ou une macro pour ce type de liaisons
Je plafonne, il me faut une aide.....
Ci joint prog d'exemple...

Amicalement

Salut à toutes et tous

Ce que je comprends :
une modification sur une cellule d'un planning met à jour tous les plannings
Si c'est ça : macro à mettre dans ThisWorkBook :

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
On Error GoTo Err_Workbook_SheetChange
Dim Plage_T As String
Dim Cel_T As Range
Dim Cel_D As Range
Dim F As Worksheet

If Intersect(Target, Range([c13], _
             Cells(Range("A65536").End(xlUp).Row, Range("IV6").End(xlToLeft).Column))) _
             Is Nothing Then GoTo Sort_Workbook_SheetChange
Application.EnableEvents = False
Application.ScreenUpdating = False

Plage_T = Intersect(Target, Range([c13], _
             Cells(Range("A65536").End(xlUp).Row, _
             Range("IV6").End(xlToLeft).Column))).Address(0, 0)
For Each F In Worksheets
    If Left(F.Name, 2) = "EQ" Then
        For Each Cel_D In F.Range(Plage_T)
            For Each Cel_T In Target
                If Cel_T.Address = Cel_D.Address Then
                    Cel_D = Cel_T
                    Exit For
                End If
            Next Cel_T
        Next Cel_D
    End If
Next F


Sort_Workbook_SheetChange:
    Application.EnableEvents = True
    Application.ScreenUpdating = True
    Exit Sub
Err_Workbook_SheetChange:
    MsgBox (Err.Number & " - " & Err.Description)
    Resume Sort_Workbook_SheetChange
End Sub

EnableEvents => bloque les événement pendant l'action de la macro, évitant un bouclage de la macro sur elle-même
ScreenUpDating => accélère la macro
On Error... Permet de gérer les erreurs : Si on ne gère pas les erreurs, Quand Excel détecte une errur après blocage de la gestion événement :
il avertit avec une msgbox, et quand on clique sur OK, il exécute un end sub direct => on ne passe pas sur la remise en route des événements => pour éviter ce genre de problème, on gére les erreurs par la macro
une détection d'erreur envoie à l'adresse Err_...
on avertit par msgbox (comme Excel). Moi, j'aime bien savoir que j'ai une erreur
on continue sur Sort... qui remet en action les gestion événement et rafraîchissement écran.

Si autres précisions nécessaires, demander

A+

 

[GBR]

Re : Liaisons cellules prioritaires

OK ça marche...

Décidement avec excel on peut presque tout faire à condition de bien comprendre ce que l'on recherche.
Mon blocage était du à une mauvaise saisie..
Merci à tous pour votre aide

amicalement

 

[GBR]

Re : Liaisons cellules prioritaires

Je reviens avec une nouvelle question

Je suis obligé de rajouter à mon planning deux feuilles bilan qui ne doivent pas êtres impacté par mes modifications sur les feuilles EQ1 EQ2 ....

Il faut que les feuilles bilans restent vierge de toutes actions sur d'autres cellules des feuilles EQ1 EQ2......


Qui a une idée simple..

merci par avance pour vos propositions

 

[Gorfael]

Re : Liaisons cellules prioritaires

Je reviens avec une nouvelle question

Je suis obligé de rajouter à mon planning deux feuilles bilan qui ne doivent pas êtres impacté par mes modifications sur les feuilles EQ1 EQ2 ....

Il faut que les feuilles bilans restent vierge de toutes actions sur d'autres cellules des feuilles EQ1 EQ2......


Qui a une idée simple..

merci par avance pour vos propositions

Re...
Si t'avais pris la peinde de regarder mon code, tu aurais vu que c'était déjà le cas
A+

 

[GBR]

Re : Liaisons cellules prioritaires

OUPS !!!! milles excuses GORFAEL effectivement j'ai survolé ton code, je me penche réellement dessus de suite.

A+

 

[GBR]

Re : Liaisons cellules prioritaires

Gorfael ton code et impec, une question subsidiaire et si mes onglets n'on pas tous le même nom
voir exemple joint

Merci pour votre patience...

 

[GBR]

Re : Liaisons cellules prioritaires

Bonjour,

mes onglets n'on pas tous le même nom
voir exemple joint au post précedent. j'ai bien essayer de bricoler le code de GORFAEL mais ça bug !!!

Qui a une idée simple du problème...?

Merci par avance

 

[Gorfael]

Re : Liaisons cellules prioritaires

Bonjour,

mes onglets n'on pas tous le même nom
voir exemple joint au post précedent. j'ai bien essayer de bricoler le code de GORFAEL mais ça bug !!!

Qui a une idée simple du problème...?

Merci par avance

re...
plusieurs solutions
il faut modifier le code :

For Each F In Worksheets
    If Left(F.Name, 2) = "EQ" Then

soit

For Each F In Worksheets
    If right(F.Name, 3) = "1AM" Then

soit

For Each F In Worksheets
    If ucase(Left(F.name, 3)) <> "BIL" Then

A+

 

[GBR]

Re : Liaisons cellules prioritaires

Et voila la ou j'ai tout raté le (<> "BIL" Then) bravo pour ta réponse rapide
Ca fonctionne parfaitement

Merci
A+

 

[ERIC S]

Re : Liaisons cellules prioritaires

re

juste une question Gorfael:

n'a-t'on pas intérêt aussi à faire le test du nom de feuille en début de macro (que se passe-t'il si on modifie une feuille bilan?)

peut-être sans objet mais j'ai peu detemps et je n'ai pas tout regardé, par contre la macro dans workbook me plait beaucoup