import de tous les fichiers texte dans la feuille active

[Aldolito]

Bonjour,

Je voudrais importer tout les fichiers texte d'un répertoire dans la feuille active à partir de la cellule active.
Les données sont séparés dans les fichiers par des tabulations.

Je suis débutant en VBA ... J'ai essayé à l'aide de l'enregistreur de macros mais sans résultat.

Merci d'avance.

ALDOLITO

 

[Lord Nelson]

Re : import de tous les fichiers texte dans la feuille active

Salut,

Voici une des façons de résoudre la question :

Sub Import_Textes()
Dim Chemin As String, Fichier As String, Temp As String
Dim NumLigne As Long, NumCol As Integer
Dim FF As Integer, I As Integer
'Adapter le chemin 
Chemin = "D:\HC\Excel\Macros\"
Fichier = Dir(Chemin & "*.txt")
NumLigne = ActiveCell.Row
NumCol = ActiveCell.Column
With ActiveSheet
  FF = FreeFile
  Do While Fichier <> ""
    Open Chemin & Fichier For Input As #FF
    Do While Not EOF(FF)
      Line Input #FF, Temp
      Table = Split(Temp, vbTab)
      For I = 0 To UBound(Table)
        .Cells(NumLigne, NumCol + I) = Table(I)
      Next
      NumLigne = NumLigne + 1
    Loop
    Close #FF
    Fichier = Dir
  Loop
End With
End Sub

Cette macro est à copier/coller dans un module de code.
N'oublie pas de donner, dans la variable Chemin, le nom du répertoire contenant les fichiers txt.

A+
Horatio

 

[Aldolito]

Re : import de tous les fichiers texte dans la feuille active

Nickel merci c vraiment top

ALDOLITO