Graphique qui compte données d'une colonne

[k4RADOC]

Bonjour,

Alors je sens que ce doit être relativement simple et que tout le monde va se dire "le pauvre il est tellement pas doué" mais bon je me lance ! J'aimerai créer un graphique qui me compte les données d'une colonne. En gros j'ai des "oui" des "non" et des "NC" dans une colonne et j'aimerai un graph qui me compte tout ça.

Je sais le faire en deux temps en utilisant d'abord un compteur du type : "=NB.SI($Ma plage de données;"Oui")" me comptant mon nombre de oui de non et de nc puis en faisant un graph mais je me demandai si ce n'était pas possible de le faire directement sans passer par cette étape.
Merci bien d'avance

 

[Efgé]

Re : Graphique qui compte données d'une colonne

Bonjour k4RADOC
Tu ne peux pas directement passer de ta colonne à un graph.
Par contre tu peux passer par un Graphique Croisé Dynamique. Je ne sais pas si c'est plus simple, mais... ...c'est possible.
Cordialement

 

[k4RADOC]

Re : Graphique qui compte données d'une colonne

Ok c'est donc normal que je ne trouvais pas solution à mon problème en tout cas je te remercie Efgé

 

[Guest]

Re : Graphique qui compte données d'une colonne

Bonjour,

Par Macro:

Sub GraphiqueONNC()
    Dim oGraph As Object
    Dim Valeurs As Variant
    Dim plage As Range
    Dim s As Series
    With Sheets("Feuil1")
        'Colonne des données "O,N,NC"
        Set plage = .Range("A2:A" & .Cells(Rows.Count, 1).End(xlUp).Row)
        
        'Sortir de la macro s'il
        If plage.Rows.Count < 2 Then Exit Sub
        
        'Mise en tableau du calcul du nombre de chaque donnée
        Valeurs = Array(Application.CountIf(plage, "O"), _
                        Application.CountIf(plage, "N"), _
                        Application.CountIf(plage, "NC"))
        
        'Obtenir le graphique
        On Error Resume Next
        Set oGraph = .ChartObjects("graphiqueONNC")
        On Error GoTo 0
        
        'Si le graphique n'existe pas
        If oGraph Is Nothing Then
            'Création du graphique
            Set oGraph = .Shapes.AddChart(xlColumnClustered)
            oGraph.Name = "graphiqueONNC"
            
            'Création de la série de donnée
            Set s = oGraph.Chart.SeriesCollection.NewSeries
        Else
            'Le graphique existe: récupérer sa série de données
            Set s = oGraph.Chart.SeriesCollection(1)
        End If
        
        'Mise à jour de la série avec les données et les légendes
        With s
            .Values = Valeurs
            .XValues = Array("O", "N", "NC")
        End With
        
    End With
      
End Sub

A+
hello Efgé