Formules imbriquées

[Alban 56]

Bonjour à toutes et à tous,

Je n'arrive pas à imbriquer ces 5 conditions pour n'obtenir qu'une seule formule à inscrire dans la cellule A6:
=Si(A1="A";"Première solution";"")
=Si(A1="B";"Deuxième solution";"")
=Si(A1="C";"Troisième solution";"")
=Si(A1="D";"Quatrième solution";"")
=Si(A1="E";"Cinquième solution";"")

D'avance merci pour votre aide,
Alban

 

[ftho]

Re : Formules imbriquées

Bonjour,

=SI(A1="a";1;SI(A1="b";2;SI(A1="c";3;SI(A1="d";4;SI(A1="e";5;"")))))

 

[Brigitte]

Re : Formules imbriquées

Bonjour,

Vite fait, mais d'autres pistes plus simples existent (tableau intermédiaire avec une recherche V ou index/equiv, ou d'autres encore) :

=SI(A1="A";"première solution";SI(A1="B";"deuxième solution";SI(A1="C";"troisième solution";SI(A1="D";"quatrième solution";"cinquième solution"))))

Edit : boum... bonjour ftho. Même combat. J'ai juste pas testé E puisque c forcément ca si les 4 autres marchent pas, donc ca simplifie : un si de moins, toujours ca de gagné ;-) : c'est quoi ton avatar ?

 

[Monique]

Re : Formules imbriquées

Bonjour,

Pour jouer

=INDEX({"première solution";"deuxième solution";"troisième solution";"quatrième solution";"cinquième solution"};EQUIV(A1;{"a";"b";"c";"d";"e"};0))

=RECHERCHEV(A1;{"A"."première solution";"B"."deuxième solution";"C"."troisième solution";"D"."quatrième solution";"E"."cinquième solution"};2;0)

Edit

Suite

=RECHERCHEH(A1;{"A"."B"."C"."D"."E";"première solution"."deuxième solution"."troisième solution"."quatrième solution"."cinquième solution"};2;0)

 

[Brigitte]

Re : Formules imbriquées

Re,

Qu'avais-je dit ? je pensai tout juste à Monique en mettant : rechercheV, index/equiv et d'autres formules (matricielles).

T'es pas possible, Monique, mais tellement exceptionnelle. Alban mesurera t'il sa chance de voir une réponse de toi sur sa question ? I hope so.

Bisous, doit faire frisquet à St Brieuc, fais gaffe en sortant.

 

[Monique]

Re : Formules imbriquées

Il faut que je sorte, justement ! Comment le sais-tu, Brigitte ? ?

 

[Brigitte]

Re : Formules imbriquées

N'oublie pas Monique la webcam en sortant ;-)

Bisous

 

[Tibo]

Re : Formules imbriquées

Bonjour,

Pour le fun et pour varier les plaisirs, une autre solution avec la fonction CHOISIR :

=CHOISIR(CODE(MAJUSCULE(A1))-64;"première";"deuxième";"troisième";
"quatrième";"cinquième")&" solution"

Bon WE à tous

@+

 

[Alban 56]

Re : Formules imbriquées

ça marche !
Merci à toutes et à tous et plus particulièrement à Brigitte et Ftho,
Et bonne fin de weekend