Formule SI avec plusieurs solution possible

[Jeydu77410]

Bonjour à tous,

Voila, je travail actuellement si un fichier Excel mais j'ai l'idée mais pas la formule qui va avec

Voici ce que je souhaiterai :

Dans la colonne G, j'indique le nom d'une planche (une planche est une feuille contenant 5 de mes produits) exemple de nom de planches: A1 -A2 -... B1 - B2 - B3 -... C1 - ...
exemple de référence sur planche A1 : Réf 1 ou 2 ou 3 ou 4 ou 5.

Ce que j'aimerai, c'est : SI G1= "planche A1" ET H1 = Réf 1 ou 2 ou 3 ou 4 ou 5 ou SI G1 = "Planche A2" ET H1 = Réf 6 ou 7 ou 8 ou 9 ou 10 = Vrai OU SI G1 = "Planche A3" ET H1 = Réf 11 ou 12 ou 13 ou 14 ou 15 ALORS VRAI SINON FAUX

L'objectif étant de me reservir de cette formule pour faire la mise en forme conditionnelle suivante: SI VRAI alors affichage de la case en vert si FAUX affichage de la case en Rouge.

J'espère avoir été assez clair pour vous.

Merci d'avance pour votre aide!

 

[Gorfael]

Re : Formule SI avec plusieurs solution possible

Salut Jeydu77410 et le forum

Ce que j'aimerai, c'est : SI G1= "planche A1" ET H1 = Réf 1 ou 2 ou 3 ou 4 ou 5 ou SI G1 = "Planche A2" ET H1 = Réf 6 ou 7 ou 8 ou 9 ou 10 = Vrai OU SI G1 = "Planche A3" ET H1 = Réf 11 ou 12 ou 13 ou 14 ou 15 ALORS VRAI SINON FAUX

=((G1= "planche A1")*((H1 = "Réf 1")+(H1 = "Réf 2")+(H1 = "Réf 3")+(H1 = "Réf 4")+(H1 = "Réf  5"))) + ((G1= "planche A2")*((H1 = "Réf 6")+(H1 = "Réf 7")+(H1 = "Réf 8")+(H1 = "Réf 9")+(H1 = "Réf  10")))+((G1= "planche A3")*((H1 = "Réf 11")+(H1 = "Réf 12")+(H1 = "Réf 13")+(H1 = "Réf 14")+(H1 = "Réf  15")))

Explication rapide :
Pour une MFC, il faut une condition Vrai ou Fausse.
Est considéré par excel Faux le 0
est considéré Vrai... tout ce qui n'est pas faux

(G1= "planche A1")*((H1 = "Réf 1")+(H1 = "Réf 2"))
si G1<> "planche A1" => (G1= "planche A1") = Faux, mais comme il est dans une opération excel le compte 0 et comme 0×A=0, quelque soit A, la condition est fausse.
(G1= "planche A1") => 3 possibilités :
- (H1 = "Réf 1") => 1×(1+0)=1 => Vrai
- (H1 = "Réf 2") => 1×(0+1)=1 => Vrai
- (H1 = autre chose) => 1×(0+0)=0 => Faux
en français, ça donne si G1 égal "planche A1" et H1 égal soit Réf1 soit Réf2, la condition est vraie.

Au lieu de jongler avec les si imbriqués, on s'occupe du résultat d'une opération. C'est plus facile à contrôler. Il faut cependant faire attention, quand le résultat peut être différent de 0 ou 1 (ce n'est pas le cas dans cette fonction), il peut être faussé.
A+

 

[Dranreb]

Re : Formule SI avec plusieurs solution possible

Bonjour

Ce que j'aimerai, c'est : SI G1= "planche A1" ET H1 = Réf 1 ou 2 ou 3 ou 4 ou 5 ou SI G1 = "Planche A2" ET H1 = Réf 6 ou 7 ou 8 ou 9 ou 10 = Vrai OU SI G1 = "Planche A3" ET H1 = Réf 11 ou 12 ou 13 ou 14 ou 15 ALORS VRAI SINON FAUX

Bon alors :

=ET(GAUCHE(G1;9)="Planche A";GAUCHE(H1;4)="Réf ";ENT((STXT(H1;5;2)+4)/5)=DROITE(G1;1))

 

[Jeydu77410]

Re : Formule SI avec plusieurs solution possible

Merci de vos réponse!!! je test ça se soir!!

 

[Jeydu77410]

Re : Formule SI avec plusieurs solution possible

Bonjour Dranreb! pourrais-tu m'expliquer ta formule?

que signifie "Gauche(G1;9) ,...

Merci d'avance

 

[Dranreb]

Re : Formule SI avec plusieurs solution possible

Bonjour.
en français (bien moins concis) ça donne:
Les 9 premiers caractères de G1 sont "Planche A"
et les 4 premiers caractères de H1 sont "Réf" suivi d'un blanc
et la partie entière du quotient de la sous-chaîne de H1 de 2 caractères commençant pos. 5, augmentée de 4 et divisée par 5 est égale au dernier caractère de G1
Cordialement.