Formule qui test contenu cellule

[BAT]

Bonjour à tous,

Je viens vers vous car je n'arrive pas à faire ma formule. Je cherche une formule qui va tester le contenu de ma cellule.

En A1, la case à tester. En B1, la formule et son résultat.

Si la cellule A1 contient la chaine de caractères "POMME" , la formule en B1 doit renvoyer le résultat "POMME" simplement.

J'ai 4 test donc je pense qu'avec des SI ça doit fonctionner. Voici les tests :
POMME ==> inscrire POMME
POIRE ==> inscrire POIRE
AIL ==> inscrire AIL
FRAISE ==> inscrire FRAISE
Si aucune de ces chaines de caractère, alors inscrit "DIVERS" en B1.

J'ai essayer avec la formule TROUVE mais sans résultat.

Please, hep

Merci à tous par avance pour votre aide.

Bat

 

[CISCO]

Re : Formule qui test contenu cellule

Bonjour

Essayes avec
=SI(OU(A1="FRAISE";A1="POMME");A1;"DIVERS")

Je n'ai fait qu'avec deux mots, Fraise et Pomme. As toi de deviner pour la suite à mettre dans le OU(.....).

@ plus

 

[ROGER2327]

Re : Formule qui test contenu cellule

Bonjour à tous

Une autre proposition :

[COLOR="DarkSlateGray"][B]=SI(ESTNA(EQUIV(A1;{"POMME";"POIRE";"FRAISE";"AIL"};0));SI(A1="";"";"DIVERS");A1)[/B][/COLOR]

ROGER2327
#4310

Lundi 9 Haha 138 (Tautologie, V)
23 Vendémiaire An CCXIX
2010-W41-4T15:05:46Z

 

[pierrejean]

Re : Formule qui test contenu cellule

Bonjour Bat

Salut CISCO
Bonjour ROGER

Uniquement pour prouver que je ne suis pas completement nul en formules

=SI(A1="POMME";"POMME";SI(A1="POIRE";"POIRE";SI(A1="AIL";"AIL";SI(A1="FRAISE";"FRAISE";"DIVERS"))))

 

[Habitude]

Re : Formule qui test contenu cellule

Admettons que
A1= Shortcake Fraise
A2= Ail séché
A3= Suprême poire
A4= Banana Split
A5= Pomme Farcie

Le résultat serait
B1= Fraise
B2= Ail
B3= Poire
B4= Divers
B5= Pomme

Si j'ai bien compris
Mettre en A1 et tirer vers le bas

=SI(NON(ESTERREUR(CHERCHE("POMME";MAJUSCULE(A1))));"Pomme";SI(NON(ESTERREUR(CHERCHE("POIRE";MAJUSCULE(A1))));"Poire";SI(NON(ESTERREUR(CHERCHE("AIL";MAJUSCULE(A1))));"Ail";SI(NON(ESTERREUR(CHERCHE("FRAISE";MAJUSCULE(A1))));"Fraise";"Divers"))))


Tu peux aussi faire une liste et chercher dans cette liste par formule matricielle.

 

[CISCO]

Re : Formule qui test contenu cellule

Bonjour à tous, bonjour Roger, bonjour pierrejean

Bonjour Bat

Uniquement pour prouver que je ne suis pas completement nul en formules

Arf, arf, arf...

Je parie même que tu peux la faire encore plus longue, juste histoire de prouver que tu connais d'autres fonctions...

@ plus

 

[BAT]

Re : Formule qui test contenu cellule

Bonjour à tous,
Un grand merci pour vos réponses.
Par contre, je n'était pas suffisament précis dans l'énoncé. Du coup seule la formule de Habitude fonctionne.
En effet, les tests que j'aurai du mettre sont plutôt:
POMME VERTE ==> inscrire POMME
POIRE WILLIAMS ==> inscrire POIRE
AIL AU LIT ==> inscrire AIL
FRAISE DES BOIS ==> inscrire FRAISE

Un très trsè grand merci pour vos réponses.

 

[BAT]

Re : Formule qui test contenu cellule

Oupss !

En fait la formule ne marche pas.
Seul Pomme fonctionne. POur les autres cas lla formule inscrit divers, même si Poire ou Ail est inscrit ...

Help again !

 

[Habitude]

Re : Formule qui test contenu cellule

Malheuresement petit bug du forum
Il met des espaces où il ne devrait pas.

Élimine ces espaces et tu verra que ca marche.
Il y en a 3

remplace
"FRA ISE" par "FRAISE"
MASJUSCUL E par MASJUSCULE
MA JUSCULE par MAJUSCULE

 

[BAT]

Re : Formule qui test contenu cellule

You ouuuuu

ça marche ! Merci habitude !!!!

 

[job75]

Re : Formule qui test contenu cellule

Bonjour le fil,

Il met des espaces où il ne devrait pas.

En mettant la formule entre les balises # pas de problème.

Par ailleurs dans ta formule, la fonction MAJUSCULE est inutile, CHERCHE ne respecte pas la casse.

Contrairement à TROUVE.

A+

 

[tototiti2008]

Re : Formule qui test contenu cellule

Bonjour à tous,

un essai

=CHOISIR(EQUIV(VRAI;ESTNUM(CHERCHE({"fraise";"ail";"poire";"pomme";"*"};A1));0);"fraise";"ail";"poire";"pomme";"divers")

 

[Habitude]

Re : Formule qui test contenu cellule

Bonjour le fil,



En mettant la formule entre les balises # pas de problème.

Par ailleurs dans ta formule, la fonction MAJUSCULE est inutile, CHERCHE ne respecte pas la casse.

Contrairement à TROUVE.

A+

D'accord avec toi sur toute la ligne


Cependant les balises j'aime pas pour les formules Excel.


Je voulais simplifier mais la formule de tototiti est bien plus meilleure.

 

[ROGER2327]

Re : Formule qui test contenu cellule

Bonjour Bat

Salut CISCO
Bonjour ROGER

Uniquement pour prouver que je ne suis pas completement nul en formules

=SI(A1="POMME";"POMME";SI(A1="POIRE";"POIRE";SI(A1="AIL";"AIL";SI(A1="FRAISE";"FRAISE";"DIVERS"))))

Bravo pierrejean

J'ai toujours su que vous nous étonneriez encore !​

Bonne soirée,

ROGER2327
#4311

Lundi 9 Haha 138 (Tautologie, V)
23 Vendémiaire An CCXIX
2010-W41-4T16:43:06Z

 

[CISCO]

Re : Formule qui test contenu cellule

Bonjour

Et avec

SI(OU(A1="FRAISE DES BOIS";A1="POMME VERTE");STXT(A1;1;CHERCHE(" ";A1));"DIVERS")

à adapter aux autres expressions.

@ plus