Formule NB.SI sur plusieurs feuilles

[TheCougard]

Bonsoir,
j'aimerai appliquer la formule NB.SI sur une même plage de cellules (G8:G12) mais dans plusieurs feuilles (1 à 52).
Ex: =NB.SI('Semaine 1:Semaine 52'!G8:G12;'congés')
Même si je valide par ALT SHIFT entrée pour la matricielle, j'ai la réponse '#valeur!'
Quelqu'un aurait-il la soluce, merci ?

 

[BOISGONTIER]

Re : Formule NB.SI sur plusieurs feuilles

Bonjour,

Voir PJ

=SOMMEPROD(NB.SI(INDIRECT("'semaine "&LIGNE(36:40)&"'!G8:G12");B5))

http://boisgontierjacques.free.fr/pages_site/sommeprod3D.htm#NBsiX

JB
Formation Excel VBA JB

 

[Pga109]

Re : Formule NB.SI sur plusieurs feuilles

Merci à toi BOISGONTIER !
Je verrai ça demain, mais a priori ça ne fonctionnera pas car les noms de mes feuilles n'ont aucun lien logique entre elles (ce pourrait être, Mexico, Berlin, Prune, Plume, Café, par exemple)

je ne comprends vraiment pas pourquoi la méthode simple ne fonctionne pas.
D'autant que je viens de tester avec MS Excel 2010 et le problème n'est toujours pas résolu !

 

[Tibo]

Re : Formule NB.SI sur plusieurs feuilles

Bonjour,

Certains fils d'une des anciennes versions du Forum ne sont plus accessibles directement.

Le plus simple : décris ton problème de façon concise mais précise.

N'hésite pas à joindre un fichier exemple commenté (d'un côté, ce que tu as, d'un autre, ce que tu veux, entre les deux : le commentaire sur le pourquoi du comment).

A te (re)lire avec ce fichier

@+

 

[Pga109]

Re : Formule NB.SI sur plusieurs feuilles

Merci à toi,

Effectivement, j'ai découvert ce problème d'accès à certaines discussions d'une version antérieure du forum en lisant le sujet épinglé dédié.

Je pense que BOISGONTIER a parfaitement su ou je voulais en venir. Il en arrive à la même conclusion que ce que l'on trouve un peu partout sur la toile : il n'est pas possible d'appliquer simplement un NB.SI dont la plage s'étend à plusieurs feuilles d'un même classeur.

Mais c'est vrai que pour être complet, je vais joindre un fichier exemple.
Il s'agit de Mexico_Berlin_Plume(Essai).xls

La formule se trouve là : '[Mexico_Berlin_Plume(Essai).xls]Calculs'!$A$1
ou '[Mexico_Berlin_Plume(Essai).xls]Calculs'!$A1

[HS]Ne vous en faites pas si certaines cellules sont masquées : je m'en sers pour tenter un autre truc apparemment impossible : mêler texte et nombre dans une même cellule afin de la formater en mode "nombre".[/HS]

Merci encore

 

[Gael]

Re : Formule NB.SI sur plusieurs feuilles

Bonjour à tous,

J'avais fait une réponse dans ce fil (post N°13) avec une solution possible avec les macros complémentaires de Morefun (freeware).

Il y a une fonction NB.SI.3D qui marche très bien.

Adresse du téléchargement : Ce lien n'existe plus
nom de la macro: morefun.xll

@+

Gael

 

[Tibo]

Re : Formule NB.SI sur plusieurs feuilles

re,

Une adaptation de la fonction de Jacques Boisgontier :

=SOMMEPROD(NB.SI(INDIRECT("'"&F1:F3&"'!A1");"fleur"))

F1:F3 : plage contenant les noms de tes onglets : Mexico, Berlin, plume

Je te laisse tester

@+

Edit : Salut Gael

Il me semble que le lien vers le site de Laurent Longre ne permet pas le téléchargement de morefunc (message d'erreur).

On peut quand même trouver cette macro complémentaire ici par exemple :

Télécharger MOREFUNC (Macro complémentaire EXCEL) (gratuit)

@+

 

[Pga109]

Re : Formule NB.SI sur plusieurs feuilles

Merci à vous

Gael :
Le problème, au sujet des macros, est qu'il m'est impossible d'en utiliser pour les fichiers du bureau. De même d'ailleurs, que le nom des feuilles m'est imposé :/

Tibo :
Donc : =SOMMEPROD(NB.SI(INDIRECT("'"&F1:F3&"'!A1");"fleur")) pourrait fonctionner si je reportais systématiquement les contenus des cellules des feuilles qui m'intéressent dans la plage FI:F3 de la feuille calcul. Mais dans ce cas, je pense perdre plus de temps qu'autre chose, non ?
À moins qu'il n'existe un moyen d'incrémentation qui fasse ça automatiquement, c'est à dire qui me permette de 'tirer' une cellule verticalement de façon à obtenir une colonne de données contenues au sein d'une même cellule dans chacune des feuilles, mais je ne pense pas.


J'ai essayé autre chose : attribuer un nom à la plage =Mexicolume!$A$1 (ou =Mexicolume!$A1, je ne sais pas pourquoi même la version 2010 s'obstine à rajouter des $ inutiles). Et entrer =NB.SI(Exo;"fleur"), où Exo est cette plage, mais ça ne fonctionne pas non plus.

 

[BOISGONTIER]

Re : Formule NB.SI sur plusieurs feuilles

Voir PJ

Portable - sans maco complémentaire -

=SOMMEPROD(NB.SI(INDIRECT("'"&nomsfeuilles&"'!G8:G12");B5))

JB

 

[BOISGONTIER]

Re : Formule NB.SI sur plusieurs feuilles

Avec noms de feuilles automatiques

-définir un nom de champ Nf =LIRE.CLASSEUR(1)
-Sélectionner L2:L16
=SI(MAINTENANT()>0;TRANSPOSE(STXT(Nf;TROUVE("]";Nf)+1;99)))
-Valider avec Maj+ctrl+entrée
-définir un nom de champ NomsFeuilles
=DECALER($L$3;;;NB.SI($L$3:$L$16;"<>#N/A"))

JB

 

[Pga109]

Re : Formule NB.SI sur plusieurs feuilles

Bonjour BOISGONTIER

Et merci à toi.
J'ai mis un peu de temps à saisir le truc, mais à présent je sais faire deux nouvelles choses bien distinctes.

Bon maintenant c'est un peu comme l'histoire de l'homme qui apprend à pêcher