Formule avec celleules variables

[wolf2012]

Bonjour, le forum

je cherche a insérer une formule qui effectue un calcul simple mais avec des cellule qui changent en fonction choix (Choix du lot),je joint un fichier exemple
Merci de votre compréhension

 

[JHA]

Re : Formule avec celleules variables

Bonjour à tous,

A essayer,

=SOMMEPROD(($A$10:$A$14=$C$1)*(($B$10:$B$14*4)+($C$10:$C$14*3,5)+($D$10:$D$14+$E$10:$E$14)))/2

Suite remarque de R@chid, la première formule proposée est pour:
((T1*4)+(T2*3,5)+(T3+T4))/2
sinon il faut mettre le "/2" à l'intérieur du sommeprod
=SOMMEPROD(($A$10:$A$14=$C$1)*(($B$10:$B$14*4)+($C$10:$C$14*3,5)+($D$10:$D$14+$E$10:$E$14)/2))

JHA

 

[R@chid]

Re : Formule avec celleules variables

Bonjour,
Voir PJ
@ + +

 

[genialo4000]

Re : Formule avec celleules variables

Salut!

J'ai une autre solution à proposer (plus facilement ajustable je pense) :

Dans la cellule :

=(INDEX($B$10:$B$14;EQUIV($C$1;$A$10:$A$14;0);1))*4
+ (INDEX($C$10:$C$14;EQUIV($C$1;$A$10:$A$14;0);1))*3,5
+ (INDEX($D$10:$D$14;EQUIV($C$1;$A$10:$A$14;0);1))/2
+ (INDEX($E$10:$E$14;EQUIV($C$1;$A$10:$A$14;0);1))/2

La fonction EQUIV donne le numéro de ligne (dans la matrice de recherche) où se trouve le paramètre.
La fonction INDEX renvoie une valeur d'une matrice selon le numéro de ligne et de colonne en paramètre.

A +

 

[JHA]

Re : Formule avec celleules variables

Re,

Il y a aussi la fonction decaler() mais moins souple que sommeprod()

=((DECALER(DECALER($A$9;EQUIV($C$1;$A$10:$A$14;0););;1)*4)+(DECALER(DECALER($A$9;EQUIV($C$1;$A$10:$A$14;0););;2)*3,5)+(DECALER(DECALER($A$9;EQUIV($C$1;$A$10:$A$14;0););;3)+DECALER(DECALER($A$9;EQUIV($C$1;$A$10:$A$14;0););;4))/2)

JHA

 

[R@chid]

Re : Formule avec celleules variables

Bonjour @ tous,
C'est déjà fait sur mon fichier avec la fonction DECALER()...

=4*DECALER(B9;EQUIV(C1;A10:A14;0);)+3,5*DECALER(C9;EQUIV(C1;A10:A14;0);)+SOMME(DECALER(D9;EQUIV(C1;A10:A14;0);;;2))/2

@ + +

 

[wolf2012]

Re : Formule avec celleules variables

Bonjour
bravo tous le monde
toutes les solutions sont géniales, la fonction Equiv et index est la mieux appropriée
un grand merci à vous tous.
Wolf