Formule adéquate

[morganSOCO]

Bonjour,

Je suis chargée de créer un logiciel sous excel pour mon entreprise et je ne trouve pas la formule à utiliser pour calculer ce qui suit: Dans une première colonne j'ai des valeurs d'isolement. L'arrêté du 30 mai 1996 me dit, je cite:"Si la plus élevée des valeurs d'isolement est supérieur de plus de 3 dB aux autres, c'est cette valeur qui sera prescrite pour la façade concernée. dans le cas contraire, la valeur d'isolement prescrite est égale à la plus élevée des valeurs obtenues pour chaque infrastructures, augmntée de 3dB"

Mon problème est que pour 2 valeurs la formule est simple mais pour 5, elle l'est beaucoup moins.
Merci d'avance pour votre aide.
Cordialement

 

[PrinceCorwin]

Re : Formule adéquate

Bonjour,

Essai ceci : en E8

=SI(GRANDE.VALEUR($D$18:$D$22;1)-GRANDE.VALEUR($D$18:$D$22;2)>3;MAX($D$18:$D$22);MAX($D$18:$D$22)+3)

Bonne journée

 

[morganSOCO]

Re : Formule adéquate

Parfait !!

Merci beaucoup

Bonne journée!

 

[R@chid]

Re : Formule adéquate

Bonsoir @ tous,
Salut Prince,
on peut faire simple,

=MAX(D8:D34)+(MAX(D8:D34)-GRANDE.VALEUR(D8:D34;2)<=3)*3

Voir PJ
Amicalement

 

[mapomme]

Re : Formule adéquate

Bonjour morganSOCO, PrinceCorwin et salut Rachid,

une autre formule:

=MAX(D8:D12)+3*(SOMMEPROD(--(D8:D12<>MAX(D8:D12))*(D8:D12+3>=MAX(D8:D12)))>0)

C'est une légère interprétation différente de la règle. Si par exemple, il y a deux fois (ou plus) la même valeur max, alors la formule renvoie cette valeur max et non la valeur max + 3. ex: pour les valeurs (39,39,39,27,27) la formule renvoie 39 et non 42.

 

[R@chid]

Re : Formule adéquate

Salut mapomme,
Moi de ma part j'ai juste simplifie la formule de notre ami PrinceCorwin,
Pour la tienne elle est tres belle si c'est ce qu'il veut notre ami morgan, et alors je me permets de modifier ma formule :

=MAX(D8:D34)+(MAX(D8:D34)-GRANDE.VALEUR(D8:D34;NB.SI(D8:D34;MAX(D8:D34))+1)<=3)*3

Amicalement