excel + compteur

[fred]

Bonour à tous,

je suis novice sur excel,

je voudrais réaliser un compteur qui compte combien il y a de valeur de la colonne1 inférieur à "30", combien il y a de valeur supérieur à "50" par exemple.

On peut le faire peut etre par la mise en forme conditionnelle...

Pouvez vous m'aider??

Merci

 

[Jocelyn]

Bonjour le Forum,
Bonjour Fred,

Je ne suis pas non plus un spécialiste mais je pense qu'avec une formule de type NBsi ca devrait t'aider

=NB.SI(A1:A8;"<30")

celle la conte dans la plage de cellule A1 a A8 le nombre de valeur inférieur a 30

Voila j"espere t'avoir aidé

bon travail
A+
Jocelyn

 

[PhiBou]

Bonjour Fred, le Forum

Si tes valeurs sont dans la plage A1:A100

Tu entres (pour ton exemple) dans B1 et B2:

=NB.SI(A1:A100;"<30")

=NB.SI(A1:A100;">50")

Bonne fin de journée

PhiBou

 

[fred]

merci,

je vais essayer,

mais si je veux une valeur comprise entre A et B,
comment dois-je faire??

 

[fred]

une autre question:

si dans mon SI, il y a plusieurs conditions, par exemple, SI( (A<50 et A>30) ou (A<100 et A>80) alors...

si vous pouvez m'aider ça serait génial!

 

[andré]

Salut Fred,

De mémoire, la fonction NB.SI n'admet pas la double condition.
Alors il faut contourner le problème
La formule : =NB.SI(A1:A100;<50)-NB.SI(A:A100;<30) te donnera les valeurs comprises entre 30 et 50.

Ândré.

 

[PhiBou]

Re Fred, Jocelyn, le Forum

Alors là on passe au sommeprod

=SOMMEPROD((A1:A100>30)*(A1:A100<50))
=SOMMEPROD((A1:A100>80)*(A1:A100<100))

Bonne fin de journée

PhiBou

 

[Jocelyn]

Re Fred,
Bonjour André, Phibou,

Merci a toi j'essayais d'aidé et j'avais seulement une solution bricolée grace nous avons une solution qui ressemble a quelque chose. !!!!!!!!!

Bonne fin de journée
A+
Jocelyn

 

[PhiBou]

Re,

Plusieurs conditions : SI( (A<50 et A>30) ou (A<100 et A>80)

=SOMMEPROD((A1:A100>30)*(A1:A100<50)) + SOMMEPROD((A1:A100>80)*(A1:A100<100))

PhiBou

 

[fred]

merci beaucoup, ca marche super bien.

J'ai encore une autre question:

dans mes valeurs de ma colonne C, j'aimerai compter le nombre de fois que les valeurs augmentent ou diminuent, je m'explique:

80
81
78

la il y a 1 changement
et de meme pour

89
87
90

en fait, il faut comparer les 3 chiffres consécutifs

 

[LaurentTBT]

Bonsoir à tous

Pour cette dernière question, j'ai une solution, mais en passant par une troisième colonne:
Si tes valeurs commencent en C2:
en D4, tu mets:
=(C3-C2)*(C4-C3)
S'il y a inversion de croissance, alors cette formule est négative. Si il y a augmentation de C2 à C4, ou diminution de C2 à C4, alors elle est positive.
Tu copies cette formule sur toute la colonne D, puis tu obtiens le nombre de fois où il y a inversion avec NB.SI(D2100;"<0")
Attention, il reste le cas où deux lignes successives sont identiques, dans ce cas, le résultat sera 0. A voir ce que tu veux faire dans ce cas.

Maintenant, je ne sais pas comment faire cela sans passer par une autre colonne, mais les pros des SommeProd ou autres formules matricielles pourront peut-être partir de mon idée.

Bonne soirée.

 

[Monique]

Bonjour,

Pas sûre d'avoir compris l'histoire : tu compares 3 nombres seulement ou toute une plage ?
Compter le nb d'augmentations :
=SOMMEPROD((A2:A7<A3:A8)*1)

Compter le nb de diminutions :
=SOMMEPROD((A2:A7>A3:A8)*(ESTNUM(A2:A7))*(ESTNUM(A3:A8)))

En fait, tu décales, (dans la formule), la plage de 1 cellule, le principal est que A2:A7 et que A3:A8 aient la même longueur

Compter et le nb d'augmentations et le nb de diminutions :
=SOMMEPROD(((A2:A7>A3:A8)+(A2:A7<A3:A8))*(ESTNUM(A2:A7))*(ESTNUM(A3:A8)))

 

[LaurentTBT]

Hello, Monique,

Moi, j'ai compris: compter le nombre de fois où on inverse la tendance (passer d'une augmentation à une diminution, ou le contraire)

Qu'en penses-tu?

 

[Monique]

Bonjour,

Alors là, je ne sais plus quoi penser.
J'avais comme un doute.
Si on dit tendance inversée, on ne compte pas les augmentations successives,
on ne compte que la 1ère augmentation d'une série. (ou diminution)
SommeProd ne va pas, du moins pas sous cette forme-là.

 

[Monique]

Re,

Tu as de bonnes idées, Laurent.
Valeurs de B2 à B15
Nb de passages d'une augmentation à une diminution :
=SOMMEPROD((B1:B15<B2:B16)*(B2:B16>B3:B17)*(ESTNUM(B1:B15))*(ESTNUM(B2:B16))*(ESTNUM(B3:B17)))

Nb de passages d'une diminution à une augmentation :
=SOMMEPROD((B1:B15>B2:B16)*(B2:B16<B3:B17)*(ESTNUM(B1:B15))*(ESTNUM(B2:B16))*(ESTNUM(B3:B17)))

Les 2 :
=SOMMEPROD(((B1:B15>B2:B16)*(B2:B16<B3:B17)+(B1:B15<B2:B16)*(B2:B16>B3:B17))*(ESTNUM(B1:B15))*(ESTNUM(B2:B16))*(ESTNUM(B3:B17)))

La dernière formule est en fait celle-ci, cellule par cellule, mais qui demande une colonne intermédiaire :
En C2 :
=((B1>B2)*(B2<B3)+(B1<B2)*(B2>B3))*(ESTNUM(B1))*(ESTNUM(B3))
renvoie 0 ou 1 pour FAUX ou VRAI, et on fait le total pour avoir le nb d'inversions