Dupliquer feuille

[mcp229]

Bonsoir, Je sèche sur une méthode en VBA pour dupliquer une feuille de mon doc excel.
Ce document est en fait un devis, mais je voudrais pouvoir dupliquer une des feuilles de ce doc.
Dans cette feuille a dupliquer il y a des boutons pour activer des macros.
Le nom de la feuille à dupliquer est aléatoire.

Ayant chercher et n'ayant pas le début d'une idée je fais appelle à vos lumières.



Bien à vous.

 

[phlaurent55]

Re : Dupliquer feuille

Bonjour mcp,

avec ce code:

Sub DupliquerFeuille()
Application.ScreenUpdating = False
feuille = ActiveSheet.Index
Sheets.Add After:=Sheets(feuille)
Sheets(feuille).Cells.Copy
Sheets(feuille + 1).Select
texte = "Feuille copiée à " & Format(Time, "hh.mm.ss")
ActiveSheet.Name = texte
Range("A1").Select
Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
Range("A1").Select
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub

à+
Philippe

 

[DoubleZero]

Re : Dupliquer feuille

Bonjour, mcp229, Philippe , le Forum,

Ou, peut-être, avec celui-ci :

Option Explicit
Sub Onglet_actif_dupliquer_nommer()
    Dim nom As String, mem As Worksheet
    Set mem = ActiveSheet
    nom = InputBox("Nommer l'onglet...")
    ActiveSheet.Copy after:=Sheets(1)
    On Error GoTo fin
    ActiveSheet.Name = nom
    With ActiveSheet: .Tab.Color = 6684927: End With
    Exit Sub
fin:
    Application.DisplayAlerts = False
    ActiveSheet.Delete
    MsgBox "Veuillez saisir un autre nom !"
    Application.DisplayAlerts = True
    mem.Activate
End Sub

A bientôt

 

[mcp229]

Re : Dupliquer feuille

Merci beaucoup,

c'est exactement ce qui me fallai.

toutefois pouvez vous m'indiquer ou je peux trouver le correspondance couleurs de cette ligne de code.

With ActiveSheet: .Tab.Color = 6684927: End With

 

[DoubleZero]

Re : Dupliquer feuille

Bonjour à toutes et à tous,

Appliquer une couleur dans une cellule et lancer cette macro :

Option Explicit
Sub Quelle_couleur()
MsgBox Selection.Interior.Color
End Sub

A bientôt

 

[mcp229]

Re : Dupliquer feuille

Merci beaucoup

 

[mcp229]

Re : Dupliquer feuille

Merci pour cette macro, je voudrait toutefois la modifier un peu.
j'ai un onglet masqué, et c'est lui que je voudrais dupliquer (et bien sur qu'il reste masqué).

auriez vous une solution pour cette modification?

Option Explicit
Sub Onglet_actif_dupliquer_nommer()
Dim nom As String, mem As Worksheet
Set mem = ActiveSheet
nom = InputBox("Nommer l'onglet...")
ActiveSheet.Copy after:=Sheets(1)
On Error GoTo fin
ActiveSheet.Name = nom
With ActiveSheet: .Tab.Color = 6684927: End With
Exit Sub
fin:
Application.DisplayAlerts = False
ActiveSheet.Delete
MsgBox "Veuillez saisir un autre nom !"
Application.DisplayAlerts = True
mem.Activate
End Sub

 

[DoubleZero]

Re : Dupliquer feuille

Re-bonjour,

Merci pour cette macro, je voudrait toutefois la modifier un peu.
j'ai un onglet masqué, et c'est lui que je voudrais dupliquer (et bien sur qu'il reste masqué).

auriez vous une solution pour cette modification?...

L'onglet devant être dupliqué est-il toujours le même ?

A bientôt

 

[DoubleZero]

Re : Dupliquer feuille

Re-bonjour,

...L'onglet devant être dupliqué est-il toujours le même ?...

... et comment est-il masqué ?

Peut-on l'afficher par clic droit sur l'un des onglets visibles ?

A bientôt

 

[Si...]

Re : Dupliquer feuille

salut

à tester :

Sub Dupliquer()
    Dim Nom As String, W As Worksheet
1   Nom = InputBox("Dupliquer l'onglet Original")
    If Nom = "" Then Exit Sub
    For Each W In Sheets
      If W.Name = Nom Then
        MsgBox "changer d'intitulé !", 16, "Nom déjà utilisé..."
        GoTo 1
      End If
    Next
    With Feuil4 'caché et dont le nom est Original
      .Visible = 1
      .Copy after:=Sheets(1)
      .Visible = 2
      ActiveSheet.Name = Nom
      ActiveSheet.Visible = 1
    End With
End Sub

@00 , truc personnel : je préfère faire plutôt que défaire

 

[mcp229]

Re : Dupliquer feuille

Re-bonjour,



... et comment est-il masqué ?

Peut-on l'afficher par clic droit sur l'un des onglets visibles ?

A bientôt

L'onglet est toujours le même et il peut etre affiché avec un clic droit.

 

[mcp229]

Re : Dupliquer feuille

avec un petit bonus,

si la feuille dupliquer pouvait placée en avant dernière position (avant dernier onglet) ce serait parfait

 

[Si...]

Re : Dupliquer feuille

re

à qui t'adresses-tu si courtoisement ?

Si... c'est à moi, remplace after:=Sheets(1) par Before:=Sheets(Sheets.Count) !

 

[mcp229]

Re : Dupliquer feuille

Pour SI....


Merci beaucoup,
je vais essayer tout ca se soir, un peu de devoirs en prévision.

 

[laurent950]

Re : Dupliquer feuille

Bonsoir,

Sub duplique()

Dim F1 As Worksheet
Set F1 = Worksheets("Feuil1")

F1.Copy After:=F1

End Sub

laurent