double recherche sur heures hh:mm:ss

[ant75]

Bonjour,
J'ai fais plusieurs essais avec les fomules que je connais déjà (recherchev et sommeprod surtout), et en cherchant un peu sur le forum, mais je n'arrive pas à trouver les résultats dans les colonnes A et B (voir fichier joint).
Merci d''avance à celui, celle, ceux ou celles qui arriveront à trouver comment faire (si possible sans maccro).

 

[Raja]

Re : double recherche sur heures hh:mm:ss

Bonjour ant75,

Tu nous a envoyé un énigme à résoudre ?

Cdlt,

 

[mth]

Re : double recherche sur heures hh:mm:ss

bonjour,

ça vient peut-être de moi, mais pas compris.Serait-il possible de préciser le résultat attendu dans les colonnes A et B ?

Merci et @ +

mth

Edit: oups, bonjour, je ne t'avais pas vu Raja, aussi perplexe que toi pour l'instant ....
@ +

 

[tototiti2008]

Re : double recherche sur heures hh:mm:ss

Bonjour à tous,

Colonne A :
=SI(C2<>"";C2;SI(D2<>"";D2;SI(E2<>"";E2;SI(F2<>"";F2;SI(G2<>"";G2;H2)))))

Colonne B :
=INDEX(C2:H2;1;EQUIV(A2;C2:H2;0)+1)

Il y a surement plus simple...

 

[wilfried_42]

Re : double recherche sur heures hh:mm:ss

Bonjour

une formule matricielle à valider avec Ctrl + Shift + Entrée

=PETITE.VALEUR(SI($C2:$H2=0;99;$C2:$H2);COLONNE())

tu tires la formules à droite et vers le bas

Edit : Bonjour Raja, mth, tototiti2008

 

[ant75]

Re : double recherche sur heures hh:mm:ss

Pardon Raja et Mth j'avais pas expliqué, pensant que le fichier parlerait de lui même ^^
Donc dans les colonnes C à G il y a des heures, mais ce sont toujours des heures qui fonctionnent par 2 (C/D ou E/F ou G/H).
Ce que je cherche à faire c'est de centraliser tout ça sur 2 colonnes (A et B).
Merci d'avance.

 

[ant75]

Re : double recherche sur heures hh:mm:ss

Merci tototiti2008, c'est exactement ça
Merci aussi wilfried_42, mais il fallait que l'heure de gauche soit toujours dans la colonne A et l'heure de droite toujours dans la colonne B.

 

[Raja]

Re : double recherche sur heures hh:mm:ss

Re,

Je pense que par rapport à ce que tu demandes, la formule suivante en A2 (et puis à recopier dans les autres cellules) sera suffisante.

=C2+E2+G2

A toi.

Cdlt,

 

[wilfried_42]

Re : double recherche sur heures hh:mm:ss

re:

toujours une fomule matricielle

=INDEX($C2:$I2;PETITE.VALEUR(SI($C2:$I2=0;7;COLONNE($C2:$I2)-2);COLONNE()))

 

[Dugenou]

Re : double recherche sur heures hh:mm:ss

Salut à tous,

J'arrive un peu comme la cavalerie !

en matriciel pour la colonne A :
=INDEX($C2:$H2;1;GRANDE.VALEUR(SI($C2:$H2>0;COLONNE(C$2:H$2);0);2)-2)

pour la colonne B :
=INDEX($C2:$H2;1;GRANDE.VALEUR(SI($C2:$H2>0;COLONNE(C$2:H$2);0);2)-1)
Cette solution est très proche de la dernière de Wilfried que je salue au passage


La solution de titi est plus simple mais ne marche qu'avec un nombre réduit de colonnes

Cordialement

 

[ant75]

Re : double recherche sur heures hh:mm:ss

re:

toujours une fomule matricielle

=INDEX($C2:$I2;PETITE.VALEUR(SI($C2:$I2=0;7;COLONNE($C2:$I2)-2);COLONNE()))

EXCELLENT !!!!!!!!!!
Merci beaucoup
De plus cette formule peut être appliqué à un plus grand tableau, génial.

 

[ant75]

Re : double recherche sur heures hh:mm:ss

Merci beaucoup Dugenou aussi, tes formules fonctionnent parfaitement bien aussi.
En fait je vais me servir de ça pour essayer de dépanner quelqu'un dans le forum, si j'y arrive je vous mettrait tous dans les crédits