Deux prénom dans une cellule

[maval]

Bonjour

Dans une cellule je doit rentrer manuellement deux prénom, je recherche le code pour pouvoir mettre
ex: Pierre & Paul mettre le "&" entre les deux prénom

D'avance merci à qui pourra m'aider.
Cordialement
Maval

 

[Claude5]

Re : Deux prénom dans une cellule

Bonjour,

sur votre clavier, sous le 1 vous avez le signe &

Pierre & Paul

Claude

 

[maval]

Re : Deux prénom dans une cellule

Bonjour Claude

Oui je sais bien qu'il y a le signe & sous le 1.
Mais se que je recherche c'est d'avoir un code qui le rentre automatiquement quand tu as 250 nom à rentrer sa facilite les choses

Merci

@+

Max

 

[ralph45]

Re : Deux prénom dans une cellule

Bonjour maval, Claude5, le forum,

Si tous tes prénoms sont séparés par une espace, tu peux faire un Rechercher/Remplacer en sélectionnant la colonne voulue :
1° Rechercher = " "
2° Remplacer par " & "

A+

 

[ralph45]

Re : Deux prénom dans une cellule

Ou avec le code VBA brut de décoffrage :

Columns("A:A").Select
Selection.Replace What:=" ", Replacement:=" & ", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False

 

[maval]

Re : Deux prénom dans une cellule

Bonjour Ralph

Je te remercie j'ai essayer le code message d'erreur #VALEUR!

@+

Max

 

[ralph45]

Re : Deux prénom dans une cellule

Re,

Peux-tu transmettre un fichier-exemple pour adaptation éventuelle ?

A+, R@lph

 

[maval]

Re : Deux prénom dans une cellule

Re,

Regarde Fichier joint

Merci

@+
Max

 

[ralph45]

Re : Deux prénom dans une cellule

Beuh...

Sans aucune modification, chez moi, ton bouton fonctionne et remplace bien les espaces par le "et" commercial...

A+

 

[job75]

Re : Deux prénom dans une cellule

Bonsoir à tous,

Dans le code de la feuille (clic droit sur l'onglet et Visualiser le code) :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range, t As String
Set r = Intersect(Target, [A:A], Me.UsedRange)
If r Is Nothing Then Exit Sub
Application.EnableEvents = False
For Each r In r 'en cas d'entrées multiples
  t = Application.Trim(Replace(r.Text, "&", "")) 'SUPPRESPACE
  r = Replace(t, " ", " & ")
Next
Application.EnableEvents = True
End Sub

La macro contrôle l'entrée des espaces en colonne A.

A+

 

[maval]

Re : Deux prénom dans une cellule

Bonjour Job,

Je te remercie pour le code.
J'ai ajouter un morceau de code pour avoir les noms avec la première lettre en majuscule (Nom Propre) comme ceci:

Private Sub Worksheet_Change(ByVal Target As Range)

'Deux prénom avec & entre les deux
Dim r As Range, t As String
Set r = Intersect(Target, [D:D], Me.UsedRange) ' colonne D
If r Is Nothing Then Exit Sub
Application.EnableEvents = False
For Each r In r 'en cas d'entrées multiples
  t = Application.Trim(Replace(r.Text, "&", "")) 'SUPPRESPACE
  r = Replace(t, " ", " & ")
Next
Application.EnableEvents = True

 'Nom en Nom Propre
 
        If Not Intersect(Target, [D3:D1000]) Is Nothing Then
    Application.EnableEvents = False
    Target.Value = Application.Evaluate("PROPER(""" & Target.Value & """)")
    Application.EnableEvents = True
 End If


End Sub

Aucun problème, j'ai bien mais noms séparer avec "&" et en nom propre (Pierre & Paul) jusqu'ici tous va bien, et lorsque je veut les supprimer soit manuellement soit par un code VBA j'ai un message d'erreur "Incompatibilité de type "
sur cet ligne.

Target.Value = Application.Evaluate("PROPER(""" & Target.Value & """)")

je joint mon fichier pour exemple.

Bonne journée et merci

@+
Max

 

[job75]

Re : Deux prénom dans une cellule

Bonjour maval, le forum,

Eh bien vous allez chercher midi à quatorze heures !

Utilisez Application.Proper dans la boucle :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range, t As String
Set r = Intersect(Target, [D:D], Me.UsedRange) 'colonne D
If r Is Nothing Then Exit Sub
Application.EnableEvents = False
For Each r In r 'en cas d'entrées multiples
  t = Application.Trim(Replace(r.Text, "&", "")) 'SUPPRESPACE
  r = Application.Proper(Replace(t, " ", " & "))
Next
Application.EnableEvents = True
End Sub

A+

 

[maval]

Re : Deux prénom dans une cellule

Bonjour Job

Merci Nickel

Bonne journée

@+

Max