Décomposer des lignes de texte en colonne

[josanche]

Bonjour à tous

Content d'etre à nouveau sur le forum ! J'aurais besoin de votre attention pour résoudre un petit problème.😎

Dans la pièce jointe attachée, il y a en colonne A, des éléments d'informations que je voudrais répertorier en 4 colonnes différentes: Name, party, state et vote.

Exemple: Heflin (D-AL),*Yea dont heflin est le nom, D va dans la colonne party, AL va dans la colonne state et Yea va dans la colonne Vote.

Quel macro faut-il utilisé ?

merci

 

[CISCO]

Re : Décomposer des lignes de texte en colonne

Bonjour

Tu peux peut être faire avec les formules du fichier ci-joint. Attention, je ne sais d'où vient l'espace après la virgule. Cela ne fonctionne pas avec la barre d'espace. J'ai obtenu la bonne formule avec un copier coller, et encore, il y avait un problème en ligne 15.

@ plus

 

[R@chid]

Re : Décomposer des lignes de texte en colonne

Bonjour @ tous,
Salut CISCO,
Voir PJ
Amicalement

 

[laurent950]

Re : Décomposer des lignes de texte en colonne

Bonsoir

Ligne N°15 pose un soucis avec nom composé d'ou la proposition 1 mais la proposition est plus adapter si pas de non composer avec un tiret "-" car le calcule se fait en automatique et pas de nombre fixe (proposition 1)

Sur cette même ligne il y a une virgule qui na pas d'espace aprés year se qui génére cette erreur (ear) il faut donc remettre en espace entre la virgule est year (, year)

2 proposition sur les deux onglets excel (Poposition 1 ou Poposition 2)

Cellule F3 (Poposition 1)
=GAUCHE(A3;CHERCHE("(";A3)-2)

Cellule G3 (Poposition 1)
=DROITE(GAUCHE(A3;CHERCHE("-";A3)-1);1)
ou
Cellule G3 (Poposition 2)
=DROITE(GAUCHE(A3;CHERCHE("-";A3)-1);CHERCHE("-";A3)-1-CHERCHE("(";A3))


Cellule H3(Poposition 1)
=DROITE(GAUCHE(A3;CHERCHE(")";A3)-1);2)
ou
Cellule H3(Poposition 2)
=DROITE(GAUCHE(A3;CHERCHE(")";A3)-1);CHERCHE(")";A3)-1-CHERCHE("-";A3))

Cellule G3 (Poposition 1)
=DROITE(A3;NBCAR(A3)-CHERCHE(",";A3)-1)

Laurent 950

 

[mapomme]

Re : Décomposer des lignes de texte en colonne

Bonsoir josanche et à tous,

Une autre série de formules en éliminant les espace insécables présents dans la colonne A.

 

[laurent950]

Re : Décomposer des lignes de texte en colonne

Bonsoir mapomme,

Ligne N° 15 le probléme est toujours la : C'est ce nom composé qui pose soucis "Moseley-Braun" a cause du tiret "-"

Moseley-Braun (D-IL),Yea Moseley-Braun D Br Yea

le resulat devrait être :

Moseley-Braun (D-IL),Yea Moseley-Braun D IL Yea

les fonctions c'est bien mais moin puissant que la programmation en utilisant VBA. mais votre formule est bonne aussi est bien pensé.

laurent

 

[mapomme]

Re : Décomposer des lignes de texte en colonne

Re Josanche, Rachid, laurent950,

laurent950:
Ligne N° 15 le probléme est toujours la : C'est ce nom composé qui pose soucis "Moseley-Braun" a cause du tiret "-"

Il m'avait échappé celui-là. Voir le fichier avec modif de la formule. Et aussi une simplification de la formule pour le nom (merci Rachid)

 

[R@chid]

Re : Décomposer des lignes de texte en colonne

Bonsoir @ tous,

Ligne N° 15 le probléme est toujours la : C'est ce nom composé qui pose soucis "Moseley-Braun" a cause du tiret "-"

Moi aussi j'ai pas fait attention je dois tout refaire je vais essayer de voir ça, l'essentiel chez moi c'est de trouver une seule formule qu'on tirer vers le bas et vers la droite, je m'amuse avec ce genre de formule qui se tire vers le bas et vers la droite...
Amicalement

 

[david84]

Re : Décomposer des lignes de texte en colonne

Bonsoir tout le monde,
à tester :
Name :

=GAUCHE(A3;CHERCHE(" ";A3)-1)

Party :

=STXT(A3;CHERCHE("(";A3)+1;CHERCHE("/";SUBSTITUE(A3;"-";"/";NBCAR(A3)-NBCAR(SUBSTITUE(A3;"-";""))))-CHERCHE("(";A3)-1)

State :

=STXT(A3;CHERCHE("(";A3)+1;CHERCHE("/";SUBSTITUE(A3;"-";"/";NBCAR(A3)-NBCAR(SUBSTITUE(A3;"-";""))))-CHERCHE("(";A3)-1)

Vote :

=STXT(SUBSTITUE(A3;CAR(160);"");CHERCHE(",";SUBSTITUE(A3;CAR(160);""))+1;99)

A+

 

[david84]

Re : Décomposer des lignes de texte en colonne

Re

Moi aussi j'ai pas fait attention je dois tout refaire je vais essayer de voir ça, l'essentiel chez moi c'est de trouver une seule formule qu'on tirer vers le bas et vers la droite, je m'amuse avec ce genre de formule qui se tire vers le bas et vers la droite...

A tester :

=STXT("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))+1;CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:B)))-CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))-1)

A+

 

[mapomme]

Re : Décomposer des lignes de texte en colonne

Bonsoir David84 😀 , le forum,

=STXT("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))+1;CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:B)))-CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))-1)

C'est pas faux! 😛 Il fallait aller au bout de celle ci ! Mais (et je plaisante) comment remettre l'espace entre le not et voting? Celle là peut-être?

=SUBSTITUE(STXT("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))+1;CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:B)))-CHERCHE("§";SUBSTITUE("/"& SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");" ";"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))-1);"Voting"; " Voting")

 

[david84]

Re : Décomposer des lignes de texte en colonne

Re

comment remettre l'espace entre le not et voting?

Peut-être simplement en gardant les espaces au lieu de les supprimer :

=STXT("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))+1;CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:B)))-CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))-1)

Moralité : mieux vaut voter sinon ça fout la m......😱
A+

Edit : si l'on veut vraiment ne pas avoir d'espace (si l'on veut pouvoir faire un copier-coller pour garder la valeur par exemple) :

=SUPPRESPACE(STXT("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))+1;CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:B)))-CHERCHE("§";SUBSTITUE("/"&SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($A3;CAR(160);"");",";"");"(";"/");"-";"/";NBCAR($A3)-NBCAR(SUBSTITUE($A3;"-";"")));")";"/")&"/";"/";"§";COLONNES($A:A)))-1))

 

[pierrejean]

Re : Décomposer des lignes de texte en colonne

Bonjour à tous

Apres cette avalanche de formules, un petit Vba

 

[laurent950]

Re : Décomposer des lignes de texte en colonne

Bonjour pierrejean,

Un petit VBA par la taille mais Grand par l'esprit... Franchement vous ête un Crack félicitation... J'aimerais savoir si vous avez l'astuce pour intégré des couleur ou format a (dans un tableau) et tous restitué en une seul fois.

laurent

 

[pierrejean]

Re : Décomposer des lignes de texte en colonne

Re

Merci Laurent pour cette appreciation
Malheureusement non , je n'ai pas cette astuce mais je t'engage à creer une question (il y a ici pas mal de faiseurs de miracle )