Date moins un an -> jour semaine équivalent.

[neal]

Bonjour,

dans un tableau excel, j'ai des dates au format 17/09/2013.

Grâce à la formule suivante, j'obtiens le nom du jour.
=CHOISIR(EQUIV(JOURSEM(I19;2);{1;2;3;4;5;6;7});"Lundi";"Mardi";"Mercredi";"Jeudi";"Vendredi";"Samedi";"Dimanche")

Donc pour le 17/09/2013, j'obtiens Mardi.

Je cherche à avoir cette date moins un an, et tomber sur le jour équivalent dans la semaine.

Donc pour le Mardi 17/09/2013, j'obtiendrais le Mardi 18/09/2012 (et non pas le 17/09/2012, qui correspond à un lundi).

Je sèche ... comment faire ?

Merci d'avance

 

[phlaurent55]

Re : Date moins un an -> jour semaine équivalent.

Bonjour BClement,

essaie ceci:
=CHOISIR(EQUIV(JOURSEM(I19-364;2);{1;2;3;4;5;6;7});"Lu ndi";"Mardi";"Mercredi";"Jeudi";"Vendredi";"Samedi ";"Dimanche")

à+
Philippe

 

[neal]

Re : Date moins un an -> jour semaine équivalent.

Pardon, je me suis mal exprimé.
Le résultat que j'essaie d'obtenir est en format date, soit pour reprendre mon exemple : 18/09/2012.

 

[phlaurent55]

Re : Date moins un an -> jour semaine équivalent.

Re,

il suffit d'appliquer un format perso à la cellule concernée

voir fichier joint

à+
Philippe

 

[neal]

Re : Date moins un an -> jour semaine équivalent.

Merci, tout marche!
Entre temps, je me suis amusé à chercher une autre formule, qui semble marcher :
Avec la date en B2

=7*(ENT(MOD(ENT((B2-2)/7)+0,6;52+5/28))+1)+DATE(ANNEE(AUJOURDHUI())-1;1;3)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;3))-(CHOISIR(EQUIV(JOURSEM(B2;2);{1;2;3;4;5;6;7});"3";"2";"1";"0";"-1";"-2";"-3"))

 

[Modeste geedee]

Re : Date moins un an -> jour semaine équivalent.

Bonsour®


=I19-(52*7)

format de cellule :
jjjj
ou bien :
jjjj j mmm


et pourquoi pas 53 semaines ???

parce que une année ne comporte jamais plus 52,28 semaines

 

[neal]

Re : Date moins un an -> jour semaine équivalent.

Je reviens sur ma formule que j'ai modifié : elle fonctionne maintenant ! J'ai fais des checks sur des dates prises au hasard, tout marche

La date en B2

=7*(ENT(MOD(ENT((B2-2)/7)+0,6;52+5/28))+1)+DATE((ANNEE(B2)-1);1;1)-JOURSEM(DATE((ANNEE(B2)-1);1;1))-(CHOISIR(EQUIV(JOURSEM(B2;2);{1;2;3;4;5;6;7});"5";"4";"3";"2";"1";"0";"-1"))

 

[Modeste geedee]

Re : Date moins un an -> jour semaine équivalent.

Bonsour®

Bonjour,

dans un tableau excel, j'ai des dates au format 17/09/2013.

Grâce à la formule suivante, j'obtiens le nom du jour.
=CHOISIR(EQUIV(JOURSEM(I19;2);{1;2;3;4;5;6;7});"Lundi";"Mardi";"Mercredi";"Jeudi";"Vendredi";"Samedi";"Dimanche")

Donc pour le 17/09/2013, j'obtiens Mardi.

=NOMPROPRE(TEXTE(I19;"jjjj"))

=NOMPROPRE(TEXTE(I19-(52*7));"jjjj"))

 

[JBOBO]

Re : Date moins un an -> jour semaine équivalent.

Bonjour,

A tester :

=SI(JOURSEM(I19;2)<JOURSEM(FIN.MOIS(I19;-13)+JOUR(I19);2);FIN.MOIS(I19;-13)+JOUR(I19)+JOURSEM(I19;2)-JOURSEM(FIN.MOIS(I19;-13)+JOUR(I19);2)+7;FIN.MOIS(I19;-13)+JOUR(I19)+JOURSEM(I19;2)-JOURSEM(FIN.MOIS(I19;-13)+JOUR(I19);2))

ps : Oulà je n'ai pasrafraichi avant de poster, je suis plus qu'en retard. Dslé

ps2 : ou un peu plus court :

=ENT(I19-(52+1/7)*7)+1

 

[Modeste geedee]

Re : Date moins un an -> jour semaine équivalent.

Bonsour®

Bonjour,


ps : Oulà je n'ai pasrafraichi avant de poster, je suis plus qu'en retard. Dslé

ps2 : ou un peu plus court :

plus court ????

=I19-(52*7)
https://www.excel-downloads.com/threads/date-moins-un-an-jour-semaine-equivalent.211002/

 

[R@chid]

Re : Date moins un an -> jour semaine équivalent.

Bonjour @ tous ,

Bonsour®


plus court ????

=I19-(52*7)
https://www.excel-downloads.com/threads/date-moins-un-an-jour-semaine-equivalent.211002/

Il faut pas oublier que la plus courte est là déjà donnée par l'ami Philippe..
@ + +

 

[Modeste geedee]

Re : Date moins un an -> jour semaine équivalent.

Bonsour®

Oupsss....!
Mes excuses à Philippe...

bien vu R@chid j'en étais resté là :

=CHOISIR(EQUIV(JOURSEM(I19-364;2);{1;2;3;4;5;6;7});"Lundi";"Mardi";"Mercredi";"Jeudi";"Vendredi";"Samedi ";"Dimanche")

il suffit d'appliquer un format perso à la cellule concernée

edit :

pas facile de simultanément surveiller le frichti, proposer une soluce, rafraichir les post, ouvrir les fichiers joints.