Copier colonne et coller dans un autre onglet avec espace à la fin

[st007]

Bonjour et encore bonne année à toutes et à tous,

Le but est qu'en activant l'onglet "Feuil2"
La colonne A de cette feuil2 se remplisse des données de la colonne A de l'onglet "Feuil1"
auquel on ajoute un espace à la fin de chaque cellule

J'essaie dans le code de la feuille 2

Private Sub Worksheet_Activate()
  Sheets("Feuil2").Range("A1").Value = Sheets("Feuil1").Range("A1", Range("A1").End(xlDown)).Value & " "
End Sub

Il doit certainement manquer un petit quelque chose ...
Merci d'avance

 

[camarchepas]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

Bonjour ,


Je verrai bien quelque chose comme cela :

Private Sub Worksheet_Activate()
Dim zone As String
   zone = "A1:" & Sheets("Données").Range("A" & Rows.Count).End(xlUp).Address
   Sheets("Feuil2").Range(zone) = Sheets("Données").Range(zone).Value
 End Sub

 

[Modeste]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

Salut st007,

Pas certain que tu puisses ajouter une espace à toutes les cellules en "un bloc" !?
Je passerais plutôt par une boucle (et un tableau, si tu as un gros volume à traiter), comme ce qui suit:

Private Sub Worksheet_Activate()
tablo = Sheets("Feuil1").[A1].Resize(Application.CountA(Sheets("Feuil1").[A:A]), 1)
For x = LBound(tablo) To UBound(tablo)
    tablo(x, 1) = tablo(x, 1) & " "
Next x
Sheets("Feuil2").[A1].Resize(UBound(tablo), 1) = tablo
End Sub

[Edit:] Bonjour Nono ... pas compris la même chose, on dirait

 

[camarchepas]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

bonjour Modeste ,

Merci de ton éclairage .

Tu as raison , par ces temps neigeux , j'ai un peu glissé .

Et pan du coup le trottoir .

Et oui , je crois que ta solution est celle qu'il faut employer , avec peut être un blocage des évenements , des fois que l'utilisateur fasse du flip flop avec les onglets ......

 

[st007]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

Bonjour et merci de vous interesser à mon soucis,

camarchepas : on n'est pas sur la même longueur d'onde je crois ....
Modeste : nous sommes sur la même longueur d'onde

Ton code fonctionne parfaitement pour mes besoins, j'ai environs 200 lignes à traiter par fichier, les tablo ne sont toujours pas assimilés, mais j'aurai du faire une boucle ....
encore merci ...

 

[Pierrot93]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

Bonjour à tous,

une autre approche :

Option Explicit
Private Sub Worksheet_Activate()
With Feuil1
    Range(.Range("A1").Resize(.Cells(Rows.Count, 1).End(xlUp).Row).Address).FormulaR1C1 = "=Feuil1!RC" & " "
End With
With Range("A1").Resize(Cells(Rows.Count, 1).End(xlUp).Row)
    .Copy
    .PasteSpecial xlPasteValues
End With
End Sub

bon après midi
@+

 

[Modeste]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

... j'ai un peu glissé .
Et pan du coup le trottoir .

Attention au cou(p) du lapin (... quand il sort du chapeau)!

[Edit:] Salut Pierrot

 

[Modeste]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

Re²,

@Pierrot: ne faudrait-il pas écrire FormulaR1C1 = "=Feuil1!RC & "" """
... J'ai peut-être encore loupé quelque chose, mais avec ta proposition, il me semble que l'espace manque

 

[Pierrot93]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

Re,

Aarf Modeste bien vu, tu as tout à fait raison :

Option Explicit
Private Sub Worksheet_Activate()
With Feuil1
    Range(.Range("A1").Resize(.Cells(Rows.Count, 1).End(xlUp).Row).Address).FormulaR1C1 = "=Feuil1!RC & "" """
End With
With Range("A1").Resize(Cells(Rows.Count, 1).End(xlUp).Row)
    .Copy
    .PasteSpecial xlPasteValues
End With
End Sub

 

[st007]

Re : Copier colonne et coller dans un autre onglet avec espace à la fin

Re²

Pierrot93 : Belle approche très fonctionnelle aussi ....

re merci pour votre réactivité .