Compter des valeurs séparées par un point virgule

[pierre974]

Bonjour à Tous !

voila je voudrai compter les valeurs présentes dans une colonne dans les valeurs de cellules sont séparée par un point virgule.

exp :

ligne 1 : 4;3
ligne 2 : 4;2
ligne 3 : 3;2

Quelle formule pourrai je utiliser pour compter le nombre de 4, de 3 et de 2 présentes dans la colonne ?

je vous remercie pour l'attention que vous porterez à mon message et je vous souhaite une bonne journée !

Pierre

 

[R@chid]

Re : Compter des valeurs séparées par un point virgule

Bonjour,
Si tes valeurs sont en A1:A3 :

=SOMMEPROD(NBCAR(A1:A3)-NBCAR(SUBSTITUE(A1:A3;";";))+1)

@ + +

 

[pierre974]

Re : Compter des valeurs séparées par un point virgule

Bonjour Rachid,

je te remercie de ta réponse mais je n'arrive pas à faire fonctionner ta formule.

je te joint un fichier exemple qui pourra me permettre de mieux comprendre.

Merci bien !

Pierre

 

[R@chid]

Re : Compter des valeurs séparées par un point virgule

Bonjour,
Si j'ai bien compris, en D3,

=NB(1/N(NBCAR(A$3:A$9)-NBCAR(SUBSTITUE(A$3:A$9;";";))+1=LIGNES($3:3)))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

@ + +

 

[Efgé]

Re : Compter des valeurs séparées par un point virgule

Bonjour pierre974 Salut Rachid

Je crois que pierre974 cherche ceci:

=SOMMEPROD(NBCAR($A$3:$A$9)-NBCAR(SUBSTITUE($A$3:$A$9;C2;"")))

Avec fioritures pour le tableau

Cordialement

 

[job75]

Re : Compter des valeurs séparées par un point virgule

Bonjour pierre974, salut R@chid, Edit : Efgé aussi,

Formule en D3 à tirer vers le bas :

=SOMMEPROD((NBCAR(";"&A$3:A$11&";")-NBCAR(SUBSTITUE(";"&A$3:A$11&";";";"&C3&";";)))/(2+NBCAR(C3)))

Fichier joint, noter en colonne C le format personalisé "nbre de fois "0

A+

 

[R@chid]

Re : Compter des valeurs séparées par un point virgule

Re,
Salut Efgé
Oui peut-être, 2 interprétations différentes..

@ + +

 

[R@chid]

Re : Compter des valeurs séparées par un point virgule

Re,
Salut Job75,
Peut-être que vous avez raison, mais on peut faire plus courte, en D3,

=NB.SI(A$3:A$9;"*"&LIGNES($3:3)&"*")

@ + +

 

[R@chid]

Re : Compter des valeurs séparées par un point virgule

Re,
Problème de valeurs numériques, en D3,

=NB(1/CHERCHE(C2;A$3:A$9))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

@ + +

 

[job75]

Re : Compter des valeurs séparées par un point virgule

Re,

La formule de mon post #6 fonctionne bien s'il n'y a pas de doublons dans une cellule.

S'il y a des doublons :

=SOMMEPROD((NBCAR(";"&SUBSTITUE(A$3:A$11;";";";;")&";")-NBCAR(SUBSTITUE(";"&SUBSTITUE(A$3:A$11;";";";;")&";";";"&C3&";";)))/(2+NBCAR(C3)))

Fichier (2).

A+

 

[job75]

Re : Compter des valeurs séparées par un point virgule

Re,

Avant de dîner, une formule matricielle :

=SOMME(N(STXT(";"&A$3:A$11&";";TRANSPOSE(LIGNE($1:$99));NBCAR(C3)+2)=";"&C3&";"))

A valider par Ctrl+Maj+Entrée.

S'il y a plus de 99 caractères dans une cellule augmenter ce nombre.

Cette formule est plus courte mais en général les calculs seront moins rapides.

Fichier (3).

A+

 

[job75]

Re : Compter des valeurs séparées par un point virgule

Bonjour le fil, le forum,

Fichier (3 bis) qui évite TRANSPOSE et la validation matricielle :

=SOMMEPROD(N(STXT(";"&A$3:A$11&";";COLONNE(A:CZ);NBCAR(C3)+2)=";"&C3&";"))

Les chaînes sont étudiées sur au plus COLONNES(A:CZ) = 104 caractères.

A+