Compter cellule non vide selon condition

[porcinet82]

Bonjour à tous,

J'ai une petite question pour mes amis spécialistes de la formule.
Je suppose que ce n'est pas compliqué, mais les formules et moi nous n'arrivons pas à nous entendre.

Donc, voici ma question (qui sera plus explicite dans le fichier en PJ) : Dans un onglet recap, je voudrais compter le nombre de cellule non vide présentent dans un autre onglet, mais selon un numéro de centre.
Je vous laisse jeter un oeil et me dire si cela est réalisable par formule. J'ai tenté quelques trucs, mais sans vraiment de succès...

Merci par avance à tous ceux qui m'accorderons un peu de leur temps.

@+

 

[Tibo]

Re : Compter cellule non vide selon condition

Bonjour Porcinet ,

Un essai avec SOMMEPROD en B2 :

=SOMMEPROD((Détail!$A$3:$A$201=$A2)*ESTNUM(Détail!$G$3:$G$201))

Je te laisse tester

@+

 

[porcinet82]

Re : Compter cellule non vide selon condition

Salut Tibo

Et bien 3 minutes pour me trouver la formule, c'est moins que le temps qu'il m'a fallu pour construire l'exemple !!!
En tout cas, merci beaucoup, ça fonctionne nickel !!

Si ce n'est pas trop demandé, tu peux me donner quelques explications que j'essais de retenir ce genre de formule qui est très utile.

Merci beaucoup pour ton aide.

@+

 

[hoerwind]

Re : Compter cellule non vide selon condition

Bonjour,

Cette formule en Récap!B2 :
=SOMMEPROD((Détail!$A$3:$A$201=A2)*(Détail!$G$3:$G$201>0))
à copier vers le bas
est censée te donner les mêmes résultats que ceux souhaités.

Edition : salut Tibo, pas vu !

 

[Sofhy]

Re : Compter cellule non vide selon condition

Bonjour Porcinet82, Tibo et hoerwind

J'arrive après la bataille...
Bon, comme j'ai travaillé dessus, je poste quand même ma formule.

Donc, tu as eu les versions "ligth" de Tibo et hoerwind et bien voici ma version compliquée

=NB.SI(Détail!$A$3:$A$201;$A2)-SOMMEPROD((Détail!$A$3:$A$201=$A2)*ESTVIDE(Détail!$G$3:$G$201))

En B2.

 

[Tibo]

Re : Compter cellule non vide selon condition

re,

tentative d'explication :

(Détail!$A$3:$A$201=$A2)

cette sous-formule va retourner une matrice de VRAI et de FAUX selon le résultat du test

ESTNUM(Détail!$G$3:$G$201)

idem, là on teste si les valeurs sont numériques (une date est une valeur numérique pour Excel). On obtient également une matrice de VRAI et de FAUX

Pour Excel, VRAI vaut 1 et FAUX vaut 0

La multiplication des deux matrices va nous retourner une nouvelle matrice de 0 et de 1

reste à faire l'addition avec SOMMEPROD.

Voilou pour cette tentative d'explication.

@+

 

[porcinet82]

Re : Compter cellule non vide selon condition

re,

Merci à tous !!
Tibo, ton explication est parfaitement clair. Reste maintenant à ma petite mémoire de mémoriser cela !!

Encore merci

@+