Comparer plusieurs cellules d'une feuil à une autre

[koak]

Bonjour à tous, (attention aux cheveux)

Alors voilà la pirouette que j'essaye de faire dans Excel et sans succès pour le moment

J'ai une feuil1 avec des informations exporté et une Feuil2 avec les élements d'origine
Je cherche à effectuer une recherche à partir du nom de la Feuil2 sur la Feuil1 et contrôler que les valeurs situées en Feuil1 sont correct en Feuil2
Dans la Feuil1 j'ai l'information des IP et VLAN et je veux controler dans la Feuil2 à partir du nom du serveur avoir les mêmes informations

Je joints un exemple

Merci d'avance

 

[Modeste]

Re : Comparer plusieurs cellules d'une feuil à une autre

Bonjour koak,

Tu connais bien ton fichier et ce que tu veux en faire ... ce qui te semble évident l'est nettement moins pour ceux qui "débarquent" dans ton projet!
Dans ton exemple (si j'ai bien compris), il n'y a guère de points communs entre les données des 2 feuilles ... Est-ce normal (par exemple des VLAN avec un caractère d'espacement avant le nombre qui suit, en Feuil2, alors qu'il n'y en a pas en Feuil1 )

Si c'est en Feuil2 que tu veux faire ressortir les différences (et toujours à condition que j'aie compris!?) pourquoi pas ceci:

• sélectionner, en Feuil2, B2 à Bxxx
• Mise en Forme Conditionnelle > Nouvelle règle > Utiliser une formule pour ...
• coller la formule suivante dans la zone prévue à cet effet:

  =$B2<>RECHERCHEV($A2;Feuil1!$A$2:$G$20;4;FAUX)

• choisir un format et appliquer

 

[koak]

Re : Comparer plusieurs cellules d'une feuil à une autre

Merci Modeste

Oui effectivement il y a un espace que je viens de supprimer car dans la Feuil2, c'est la base de mes informations qui ne bouge pas.
Par contre en appliquant ta formule je me retrouve avec des lignes OK alors que l'information est fausse dans l'IP par exemple mais correct dans le VLAN

Sinon la valeur commune au 2 Feuilles est le nom de serveur, après je voudrais contrôler que les colonnes corresponde entre elle :

VLAN Cible(feuil2)=Nic0NetName (Feuil1)
IP Cible=Nic0IPInfo
VLAN Admin=Nic1NetName
IP Admin=Nic1IPInfo

Je remet mon exemple sans l'espace

 

[Modeste]

Re : Comparer plusieurs cellules d'une feuil à une autre

Re-bonjour,

Par contre en appliquant ta formule je me retrouve avec des lignes OK alors que l'information est fausse dans l'IP par exemple mais correct dans le VLAN

Oui, le premier essai n'avait pas d'autre ambition que de vérifier la cohérence des VLAN en colonne B de la Feuil2 avec ceux de la 4e colonne de la Feuil1 (pour le même nom de serveur)

Sur base de cette proposition, tu as donc 2 solutions:

• refaire la même manip (en adaptant un chouïa la formule) pour les 3 autres colonnes
• créer une MFC vérifiant si une différence au moins existe pour n'importe laquelle des 4 colonnes, en combinant en une seule les 4 formules.

Dis-nous vers quelle option ton choix se porterait et si tu as besoin d'aide pour y arriver (précise aussi, alors, si tu veux que la MFC s'applique au seul nom du serveur, en colonne A, ou à la ligne entière)

 

[koak]

Re : Comparer plusieurs cellules d'une feuil à une autre

Merci beaucoup pour ton aide.
Je te cache pas que rien que la solution que tu m'as apportée dépasse mes compétences.
Si il est possible avec cette même formule avec grand plaisir si tu peux m'aider sur le "chouïa" je suis preneur.


Merci encore

PS: d'ailleurs à quoi correspond =$B2<> avant le recherchev ?

 

[Modeste]

Re : Comparer plusieurs cellules d'une feuil à une autre

Re²,

à quoi correspond =$B2<> avant le recherchev ?

En v'là une question qu'elle est bonne (pour la prochaine question, essaie de formuler une hypothèse ... si ça tombe, la proposition dépassait moins tes compétences que tu ne le pensais!)
Tu connais sans doute la RECHERCHEV: celle-ci permet de chercher une valeur dans la colonne de gauche d'un tableau et de renvoyer la donnée figurant à la même hauteur, dans une autre colonne. La partie suivante de la formule:

RECHERCHEV($A2;Feuil1!$A$2:$G$20;4;FAUX)

permettra donc de chercher "Serveur1" (figurant en A2) dans la première colonne du tableau s'étalant, en Feuil1, de A2 à G20 et, une fois cette valeur trouvée, de renvoyer l'info figurant en colonne 4 du même tableau (dans le cas présent, "VLAN003").

Pour qu'une Mise en Forme Conditionnelle s'applique, il suffit, comme son nom l'indique, de vérifier qu'une condition se réalise (si le résultat est VRAI, le format est appliqué). Dans la plage B2:Bxxx, si on écrit

=$B2<>RECHERCHEV($A2;Feuil1!$A$2:$G$20;4;FAUX)

On a vu que la RECHERCHEV donnait "VLAN003" comme résultat; avec la formule ci-dessus, c'est donc comme si on écrivait: "Est-ce que B2 est différent de (ce sont les signes '<>') "VLAN003"?"
B2 (au début de la formule) doit donc correspondre à l'adresse de la première cellule à laquelle on applique la MFC.

Pour faire la même chose, en comparant IP Cible à Nic0IPInfo, il faudra donc sélectionner la plage C2:Cxxx de la Feuil2 et appliquer la formule suivante dans la MFC:

=$C2<>RECHERCHEV($A2;Feuil1!$A$2:$G$20;7;FAUX)

(seuls changent le C2 du début de la formule et le n° d'index de colonne de la RECHERCHEV, puisque cette fois on comparera C2 avec le contenu de la 7[SUP]e[/SUP] colonne du tableau Feuil1!A2:G20)

Je te laisse essayer les 2 autres formules?

 

[koak]

Re : Comparer plusieurs cellules d'une feuil à une autre

Merci pour l'explication
Oui le recherchev je connais j'essaye de concaténer ($) la formule pour les 4 cellules mais est ce possible ? ou dois je créer une mise en Forme Conditionnelle pour chaque cellule ?


En rajoutant une régle pour chaque Cellule s'est pas mal aussi

Un grand merci

 

[Modeste]

Re : Comparer plusieurs cellules d'une feuil à une autre

Re³,

L'avantage de 4 MFC distinctes est que tu pourras repérer la colonne où figure la différence.

Pour le "tout en un" il ne faut pas CONCATENER mais imbriquer les 4 formules dans un OU, de manière que si le résultat d'un seul des 4 tests est VRAI, la formule retourne VRAI ... quelque chose comme

=OU($B2<>RECHERCHEV($A2;Feuil1!$A$2:$G$20;4;FAUX);$C2<>RECHERCHEV($A2;Feuil1!$A$2:$G$20;7;FAUX);$H2<>RECHERCHEV($A2;Feuil1!$A$2:$G$20;6;FAUX);$I2<>RECHERCHEV($A2;Feuil1!$A$2:$G$20;3;FAUX))

mais là je te donne la solution des 4 formules c'est de la triche! Ne regarde pas la formule, si tu n'avais pas trouvé le "chouïa" de différence

Je ne comprends pas, par contre le ($) que tu mentionnes après Concaténer