Comparaison

[Moreno076]

Bonsoir. Voilà ma demande d'aide. J'ai un fichier excel avec 3 onglets. Le premier onglet regroupe un fichier clients de plusieurs colonnes (numéro client, nom, adresse...). Le second et troisieme onglet regroupent egalement des clients qui appartiennent peut etre au 1er onglet.
Comment faire ressortir dans le 1er onglet les clients qui appartiennent à l'onglet 2 d'une part et l'onglet 3 d'autre part? Par exemple j'aimerais rajouter une colonne dans l'onglet 1 qui me disent si le client fait parti de l'onglet 2 ou de l'onglet 3.

Le point commun de ces fichiers la colonne A qui regroupe le numéro des clients. Je ne sais pas si c'est très clair mais merci d'avance pour votre aide.

 

[CBernardT]

Re : Comparaison

Bonsoir Moreno076 et le forum,

Où il est le classeur exemple de ton projet ?

 

[Moreno076]

Re : Comparaison

Le voici ! En fait ce que je veux c'est en rouge dans le 1er onglet. Merci

 

[Dranreb]

Re : Comparaison

Bonsoir.
Formule pour la ligne 2

=CHOISIR((NB.SI('Zone 1'!$A:$A;$A2)>0)+2*(NB.SI('Zone 2'!$A:$A;$A2)>0)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")

Cordialement.

 

[Moreno076]

Re : Comparaison

Bonsoir.
Formule pour la ligne 2

=CHOISIR((NB.SI('Zone 1'!$A:$A;$A2)>0)+2*(NB.SI('Zone 2'!$A:$A;$A2)>0)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")

Cordialement.

Alors là chapeau ! un grand merci Dranreb, c'est exactement ce qu'il me fallait. Je vais aller plus loin en ayant une zone 3 et une zone 4. Nota qu'il est impossible d'avoir un même client dans plusieurs zones différentes. Quelle serait la formule? J'essaie de comprendre mais pas évident du tout.

 

[Dranreb]

Re : Comparaison

Si c'est à coup sûr impossible multipliez les NB.SI par 1, 2, 3, 4: il ne pourra y avoir de confusion entre 3 et 1 + 2 par exemple.
Si une erreur peut malgré tout les rendre présents en plusieurs feuilles, les poids 1, 2, 4, 8 feraient l'affaire, mais il faudrait prévoir une liste de 16 textes possibles, un pour chaque combinaison.

 

[Moreno076]

Re : Comparaison

Je ne comprend pas désolé la solution pour 4.

 

[Dranreb]

Re : Comparaison

Imaginons que ce soit en zone 2
=CHOISIR((NB.SI('Zone 1'!$A:$A;$A2)>0)+2*(NB.SI('Zone 2'!$A:$A;$A2)>0)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR((0>0)+2*(NB.SI('Zone 2'!$A:$A;$A2)>0)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR((FAUX)+2*(NB.SI('Zone 2'!$A:$A;$A2)>0)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR(0+2*(NB.SI('Zone 2'!$A:$A;$A2)>0)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR(0+2*(1>0)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR(0+2*(VRAI)+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR(0+2*1+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR(0+2+1;"Aucun";"Zone 1";"Zone 2";"Les deux")
=CHOISIR(3;"Aucun";"Zone 1";"Zone 2";"Les deux")
="Zone 2"

Ce qui vous a peut être échappé c'est qu'une expression booléenne entre parenthèses soumise à des opérations arithmétiques est transformée en numérique, à savoir 1 pour VRAI et 0 pour FAUX
Pour que plusieurs d'entre elles puissent déboucher sur un choix il suffit de les multiplier par un poids approprié. 1 pour la première, 2 pour la deuxième etc. Celle qui est vraie fait donc valoir son poids, donc le rang dans CHOISIR du texte à restituer après ajout de 1 à l'ensemble pour restituer le 1er texte si aucune n'est vraie.
À +

 

[Moreno076]

Re : Comparaison

Merci bien !