Comment savoir si au moins une colonne est masqué sur ma feuille ?

chasseur44

XLDnaute Occasionnel
Bonjour à tous
J'ai une question qui parait simple mais je but :confused::
"Comment savoir si au moins une colonne est masqué sur ma feuille ? "
Je ne veux même pas savoir laquelle ... je veux tout simplement savoir s'il existe dans ma feuille une colonne masquée !
Merci pour votre aide
 

chasseur44

XLDnaute Occasionnel
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Merci DoubleZero

J'avais lu cette discussion mais ... en fait je ne sais pas comment récupérer l'info qui me dirais que si j'ai au moins une colonne masquée je fais telle action sinon j'en fais une autre.
 

Efgé

XLDnaute Barbatruc
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Bonjour chasseur44, Bonjour 00 :)
Une méthode simple à adapter:
VB:
Sub Col()
Dim i&, Flag As Boolean
For i = 1 To Application.Columns.Count
    If Sheets("Toto").Columns(i).Hidden = True Then
        Flag = True
        Exit For
    End If
Next i
If Flag Then
    MsgBox "Au moins une colonne est masquée ", 64, "Traitement avec"
Else
    MsgBox "Aucune colonne n'est masquée", 64, "Traitement sans"
End If
End Sub
Cordialement
 

chris

XLDnaute Barbatruc
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Bonjour
Coucou 00 :D, Efgé ;)

Plus direct (on peut distinguer ligne et colonne si on préfère ou ne traiter que l'un des 2)
Code:
If Cells.Columns.Count <> ActiveSheet.Rows("1:1").SpecialCells(xlCellTypeVisible).Count Or _
 Cells.Rows.Count <> ActiveSheet.Columns("A:A").SpecialCells(xlCellTypeVisible).Count Then MsgBox "Cache cache"
 

DoubleZero

XLDnaute Barbatruc
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Re-bonjour, bonjour, Efgé :D, chris :D,

Une autre suggestion :

VB:
Option Explicit
Sub Colonne_masquée_totaliser()
    Dim Compteur As Integer, i As Integer
    Application.ScreenUpdating = False
    Compteur = 0
    For i = 1 To Columns.Count
        If Columns(i).Hidden = True Then
            Compteur = Compteur + 1
        End If
    Next i
    MsgBox "Total colonnes : " & Columns.Count
    MsgBox "Total colonnes visibles : " & Columns.Count - Compteur    ' & " colonnes visibles"
    MsgBox "Total colonne(s) masquée(s) : " & Compteur
End Sub
A bientôt :)
 

chris

XLDnaute Barbatruc
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Re

Pas testé mais à mon avis la boucle est plus longue que calculer l'écart entre nombre de colonnes et nombre de colonnes visibles... même si c'est infime.
 

DoubleZero

XLDnaute Barbatruc
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Re-bonjour,

...Pas testé mais à mon avis la boucle est plus longue...
Tu as raison, chris :D, mais je ne sais pas trouver mieux :eek: et je sais encore moins comment lister les colonnes / lignes masquées :confused:.

A bientôt :D:D
 

Pierrot93

XLDnaute Barbatruc
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Bonjour Chasseur, 00:), Chris:), fg:)
une variante pour le fun :
Code:
MsgBox Columns.Count - Rows(1).SpecialCells(12).Count & " colonne(s) masquée(s)"
bonne soirée
@+
 

Staple1600

XLDnaute Barbatruc
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Bonsoir à tous

Comme dirait le Schtroumph grognon:
"Moi j'aime pas qu'on me cache des choses!
"Et j'aime pas compter ce qui est masqué!"


Et en passant un petit hommage à Mireille D. "Bas les masques!"

Code:
Sub VoyonsToutIciEtMaintenant()
Cells.Columns.Hidden = False
Cells.Rows.Hidden = False
End Sub
PS: Je suppute que si on cherche ce qui est masqué c'est pour ensuite mieux le démasquer.
Donc allons à l'essentiel et montrons tout et n'en déplaise à Jean-François: "A poil Excel !"
 

chasseur44

XLDnaute Occasionnel
Re : Comment savoir si au moins une colonne est masqué sur ma feuille ?

Merci à Tous
La solution de Efgé me convient parfaitement pour ce que je souhaite faire
 
Haut Bas