XL 2016 Classeur rassembleur( 18 .xls=> 1 .xls)

[Claudy]

Bonjour à tous,
j'ai un dossier (nommé Extra) avec plusieurs classeurs .xls qui commencent par 330-....(voir capture d'écran)

Comment créer un seul classeur reprenant tous les onglets renommés du nom du classeur(330-74...)

Merci d'avance,

Claudy

 

[Staple1600]

Bonjour Claudy

Tu as regardé dans les archives?
Parce qu'il y a moult discussions relatives à ce sujet
(combiner classeurs... fusionner classeurs etc...)

 

[Hasco]

Bonjour,
Hello staple

Sinon et avec 2016 par PowerQuery : combiner les données de fichiers d'un dossier

Cordialement

 

[Staple1600]

Re, Bonjour Roblochon

Avec le confinement , je suis en train de tâter à donf la Requête Omnipotente (aka PQ pour les saxons)


NB: Ça marche aussi avec Excel 2013
(mais il faut télécharger un addon)

 

[job75]

Bonjour Claudy, JM, Roblochon,

Pour créer les onglets :

Sub Onglets()
Dim i%, chemin$, fichier$
Application.ScreenUpdating = False
Application.DisplayAlerts = False
With ThisWorkbook
    '---supprime les onglets existants sauf le 1er---
    For i = .Sheets.Count To 2 Step -1
        .Sheets(i).Delete
    Next
    .Sheets(1).Name = Chr(1)
    '---crée les onglets---
    chemin = .Path & "\" 'à adapter
    fichier = Dir(chemin & "*.xls*")
    While fichier <> ""
        If fichier <> .Name Then
            .Sheets.Add After:=.Sheets(.Sheets.Count)
            .Sheets(.Sheets.Count).Name = fichier
        End If
        fichier = Dir
    Wend
    .Sheets(1).Delete
End With
End Sub

Et ensuite qu'est-ce qu'on en fait de ces onglets ?

A+

 

[Claudy]

Bonsoir à tous...
Mais comment avoir PowerQuery ??
Merci,
Claudy

 

[Hasco]

Re,

Une simple recherche google donne : https://support.microsoft.com/fr-fr/help/4027739/excel-power-query-in-excel

Bon week-end

 

[job75]

Et ensuite qu'est-ce qu'on en fait de ces onglets ?

On peut les remplir en copiant les données et formats de la 1ère feuille de chaque fichier source :

Sub Onglets()
Dim i%, chemin$, fichier$, F As Worksheet
Application.ScreenUpdating = False
Application.DisplayAlerts = False
With ThisWorkbook
    '---supprime les onglets existants sauf le 1er---
    For i = .Sheets.Count To 2 Step -1
        .Sheets(i).Delete
    Next
    .Sheets(1).Name = Chr(1)
    '---crée les onglets---
    chemin = .Path & "\" 'à adapter
    fichier = Dir(chemin & "*.xls*")
    While fichier <> ""
        If fichier <> .Name Then
            .Sheets.Add After:=.Sheets(.Sheets.Count)
            Set F = .Sheets(.Sheets.Count)
            F.Name = fichier
            With Workbooks.Open(chemin & fichier).Worksheets(1) 'ouvre le fichier
                With .Range("A1", .UsedRange)
                    .EntireRow.Copy F.Cells(1) 'pour les formats
                    F.Cells(1).Resize(.Rows.Count, .Columns.Count) = .Value 'copie les valeurs
                End With
                .Parent.Close 'ferme le fichier
            End With
            F.Columns.AutoFit 'ajustement largeurs
        End If
        fichier = Dir
    Wend
    .Sheets(1).Delete
    .Sheets(1).Activate
End With
End Sub