Calculer un écart sur une plage

[Spip]

Bonjour à tous et à toutes,

Je souhaiterai savoir quelle formule entrer dans Excel pour calculer l'écart d'une valeur sur une plage de recherche.
Par exemple, la valeur recherchée est en B79 et la plage de recherche entre B29 et F78 (donc sur 50 lignes et 5 colonnes).

Je pense qu'il faut combiner la fonction RECHERCHEV à une autre, mais je ne sais pas laquelle (ECART TYPE ou ECART MOYEN ne convenant pas car je veux savoir depuis combien de temps une valeur recherchée n'est pas apparue dans une plage).

Est-ce que quelqu'un pourrait m'aider SVP ?

D'avance merci pour vos réponses.

 

[Vilain]

Re : Calculer un écart sur une plage

Bonjour et bienvenue,

Pas bien compris la demande. Un fichier aiderait pas mal...

A plus

 

[job75]

Re : Calculer un écart sur une plage

Bonjour Spip, salut Gillus69

Chez moi un "écart" est une différence, et alors on a le choix :

=B79-MAX(B29:F78)

=B79-MIN(B29:F78)

=B79-MOYENNE(B29:F78)

=B79-NBVAL(B29:F78)

=B79-NB(B29:F78)

Après ces gros efforts ma boule de cristal est épuisée

A+

 

[Spip]

Re : Calculer un écart sur une plage

Bonsoir Job75 et Gillus69,

Job75 : Merci pour votre réponse et vos pistes, mais aucune des formules ne donnent le bon résultat, désolé. Avec ça, elles ne donnent pas toutes le même résultat.

Gillus69 : Vous demandiez un fichier; vous en trouverez un joint à ce post. J'ai mis en couleur des exemple de valeurs recherchées ainsi que l'écart que je souhaiterais trouver "automatiquement" par le biais d'une formule.

Merci encore pour vos réponses.

 

[job75]

Re : Calculer un écart sur une plage

Re,

Formule matricielle en I52 :

=INDEX(G$1:G$51;MIN(SI(ESTNUM(G$1:G$51)*(B$1:F$51=B52);LIGNE(G$1:G$51))))

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

Pour la 2ème valeur (10) ce n'est pas le résultat que vous souhaitiez : la formule travaille par lignes.

Fichier joint.

A+

 

[job75]

Re : Calculer un écart sur une plage

Re,

Si maintenant on veut travailler par colonne, il faut sortir l'artillerie lourde.

Formule en I52, à tirer vers le bas :

=SI(ESTNUM(EQUIV(B52;INDEX(T;;1);0));INDEX(G$1:G$52;EQUIV(B52;INDEX(T;;1);0));SI(ESTNUM(EQUIV(B52;INDEX(T;;2);0));INDEX(G$1:G$52;EQUIV(B52;INDEX(T;;2);0));SI(ESTNUM(EQUIV(B52;INDEX(T;;3);0));INDEX(G$1:G$52;EQUIV(B52;INDEX(T;;3);0));SI(ESTNUM(EQUIV(B52;INDEX(T;;4);0));INDEX(G$1:G$52;EQUIV(B52;INDEX(T;;4);0));SI(ESTNUM(EQUIV(B52;INDEX(T;;5);0));INDEX(G$1:G$52;EQUIV(B52;INDEX(T;;5);0));"Pas trouvé")))))

Pas besoin ici de validation matricielle.

Voyez le nom défini T, c'est une matrice.

Fichier (2).

Edit : salut Roger j'en profite pour ajouter "Pas trouvé" dans la formule.

A+

 

[ROGER2327]

Re : Calculer un écart sur une plage

Bonsoir à tous

Un autre essai dans le classeur joint. (Artillerie légère)​

Bonne nuit.


ROGER2327
#6196

Samedi 14 Tatane 139 (Sainte Anne, Pèlerine, énergumène - fête Suprême Quarte)
9 Thermidor An CCXX, 9,0115h - mûre
2012-W30-5T21:37:40Z

 

[job75]

Re : Calculer un écart sur une plage

Bonjour le fil, le forum,

Voilà maintenant un exocet.

Il suffit de stocker les données adéquates dans la matrice T :

=SI(ESTNUM(Feuil1!$G$1:$G$51)*(Feuil1!$B$1:$F$51=Feuil1!$B52);COLONNE(Feuil1!$B$1:$F$51)+LIGNE(Feuil1!$B$1:$F$51)/100000000)

et de les récupérer dans la formule en I52 :

=SI(MIN(T);INDEX(G$1:G$51;100000000*(MIN(T)-ENT(MIN(T))));"Pas trouvé")

Fichier (3).

A+

 

[job75]

Re : Calculer un écart sur une plage

Re,

Bon Spip nous le dira, mais je me suis peut-être cassé la tête pour rien.

Si l'on recherche en fait l'écart minimum pour chaque valeur, il suffit de modifier la formule du post #5 avec MAX :

=INDEX(G$1:G$51;MAX(SI(ESTNUM(G$1:G$51)*(B$1:F$51=B52);LIGNE(G$1:G$51))))

Edit : en introduisant "Pas trouvé" :

=SI(MAX(ESTNUM(G$1:G$51)*(B$1:F$51=B52));INDEX(G$1:G$51;MAX(SI(ESTNUM(G$1:G$51)*(B$1:F$51=B52);LIGNE(G$1:G$51))));"Pas trouvé")

Formules matricielles bien sûr.

Fichier (1 bis).

A+

 

[david84]

Re : Calculer un écart sur une plage

Bonjour à tous,
sous réserve d'avoir compris la demande :

=MAX(LIGNE(C$2:G$51))-MAX(SI(C$2:G$51=J52;LIGNE(C$2:G$51)))

Formule à tirer vers le bas (validation matricielle).
A+

 

[JJ1]

Re : Calculer un écart sur une plage

Bonjour à tous,

Une formule donnée par Monique pour calculer les écarts successifs de 5 numéros (saisis) dans une plage de Loto et non dans une seule colonne (en remontant la plage).
Je joins un bout du fichier pour explication.
Bon WE à tous.

 

[Spip]

Re : Calculer un écart sur une plage

Merci beaucoup à tous et à toutes pour toutes ces réponses et explications (j'en attendais pas autant )
Sinon Job75, non vous ne vous êtes pas cassé la tête pour rien; je ne cherche pas l'écart minimum.

Ceci dit, je ne comprends pas qu'il n'y ait pas une fonction "toute faite" pour ce que je demandais. Il y a ECART.TYPE ou ECART.MOYEN, mais pas ECART tout court (en tout cas pas sous ce nom là) ?!!