Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

[Nicolas18]

Bonjour à tous,

Je recherche une fonction pour connaitre dans une série de chiffres (qui varie) selon les mois de l'année, le nombre de fois qu'un chiffre appairait 7 fois.

Exemple dans la série :
1 1 1 2 2 2 2 2 2 2 3 3 3 3 3 3 3 4 4 4 4 4 4 4 5 5 5
Les termes 2 3 et 4 sont répété 7 fois je cherche donc une formule dont la réponse serait 3

Merci beaucoup d'avance,
Bonne journée
Nico

 

[mth]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

Bonjour,

Un idée parmi d'autres en passant par un petit TCD intermédiaire,

Bonne journée,

mth

 

[poulie]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

Bonjour Nicolas18, mth,

Eventuellement cette proposition avec une colonne intermédiaire en A (les 12 mois de l'année).

Bonne réception

 

[Celeda]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

Bonjour,

la réponse serait 3

Les données de B2 à B28
Frequence+sp =SOMMEPROD(0+(FREQUENCE(B2:B28;B2:B28)>6))

 

[david84]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

Bonjour,
à tester :
A+

=SOMMEPROD(N(FREQUENCE(A2:A28;A2:A28)=7))

 

[Nicolas18]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

Super ça marche

Merci beaucoup!

 

[Nicolas18]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

Bonsoir,
Petit question subsidiaire !
Est-il possible de faire une formule qui me diras dans une première cellule : c'est le chiffre X le premier qui est répété 7 fois
puis dans une autre, c'est le second chiffre répété 7 fois et ainsi de suite...

Merci beaucoup d'avance

 

[Nicolas18]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

tout le monde sèche?!

 

[david84]

Re : Calculer le nombre de fois ou des chiffres apparaîssent 7 fois

Re
à placer en B2, à valider en matriciel et à tirer vers le bas :
pour avoir la fréquence d'apparition de l'ensemble des données,

=MODE(SI(NB.SI(B$1:B1;A$2:A$28)=0;A$2:A$28))

avec test logique :

=SI(LIGNES($1:1)<=SOMME(1/NB.SI(A$2:A$28;A$2:A$28));MODE(SI(NB.SI(B$1:B1;A$2:A$28)=0;A$2:A$28));"")

Pour avoir uniquement la fréquence d'apparition des données apparaissant 7 fois.

=MODE(SI((NB.SI(B$1:B1;A$2:A$28)=0)*(NB.SI(A$2:A$28;A$2:A$28)=7);A$2:A$28))

avec test logique :

=SI(LIGNES($1:1)<=SOMME(N(FREQUENCE(A$2:A$28;A$2:A$28)=7));MODE(SI((NB.SI(B$1:B1;A$2:A$28)=0)*(NB.SI(A$2:A$28;A$2:A$28)=7);A$2:A$28));"")

A+