Association de fonctions à RechercheV

[Dams92]

Bonjour,

Je voulais avoir un petit coup de pouce pour savoir où est mon erreur dans ma formule rechechev dans le fichier excel joint.

Je ne comprends pourquoi la formule ne marche qu'une fois sur 2.

le fichier que j'ai joint ne comporte que 5 colonnes. Le fichier que j'utilise en comporte plutot une cinquantaine.

Au lieu de remplir pour chaque colonne une fonction spécifique, existe il une fonction que l'on pourrait associer à recherchev pour pouvoir remplir plusieurs colonnes d'un coup?

Je me m'explique. Si comme dans mon exemple je tape le numéro de contrat 1. Il y a t-il un moyen de remplir automatiquement les 5 caractéristiques dans leur cellule respective?

Merci beaucoup pour votre aide

Damien

 

[Tibo]

Re : Association de fonctions à RechercheV

Bonjour,

Rajoute un ;0 comme dernier paramètre à tes formules RECHERCHEV

EN D5, ça donne :

=RECHERCHEV($C5;Données!$C$4:$H$10;2[COLOR=red][B];0[/B][/COLOR])

Je te laisse adapter sur les autres formules


@+

 

[JCGL]

Re : Association de fonctions à RechercheV

Bonjour à tous,

Peux-tu essayer D5 et tirer à droite et vers le bas :

=RECHERCHEV($C5;Données!$C$4:$H$10;COLONNE(A1)+1;0)

A+ à tous

Edition : Ah ben y a du monde pour un 0 manquant Arf
Salut à Tibo, Toto et Kjin ;-)

 

[tototiti2008]

Re : Association de fonctions à RechercheV

Bonjour Dams92,

la fonction RECHERCHEV a 4 arguments, et si le 4ème est facultatif il est pourtant trés important.

en écrivant

=RECHERCHEV($C6;Données!$C$4:$H$10;2)

tu omets le 4ème argument ce qui signifie que tu recherche une valeur "approximative" et que la liste dans laquelle tu recherche doit être triée sur la 1ère colonne (ce qui n'est pas le cas ici.

essaye

=RECHERCHEV($C6;Données!$C$4:$H$10;2;0)

ou

=RECHERCHEV($C6;Données!$C$4:$H$10;2;FAUX)

ce qui signifie une recherche exacte sur une liste qui n'a pas besoin d'être triée.

l'aide sur les fonctions pourra te donner des précisions intéressantes également.

Bing, Bing.. Bonjour Tibo et JCGL

 

[kjin]

Re : Association de fonctions à RechercheV

Bonsoir,
Tu as oublié la valeur proche dans la formule qui si elle est omis =VRAI

=RECHERCHEV($C5;Données!$C$4:$H$10;2;[COLOR="Blue"][B]0[/B][/COLOR])

Edit : j'en profite pour saluer bien bas (aïe) tout ce beau monde et corriger les fotes d'ortograf
A+
kjin

 

[Monique]

Re : Association de fonctions à RechercheV

Bonjour,

En D5 :
=RECHERCHEV($C5;Données!$C$4:$H$10;COLONNES($C5 : D5);0)
à copier puis coller dans toutes les autres cellules du tableau

Le dernier argument : 0 pour avoir la valeur exacte
Avec l'argument 1 (ou rien) il faut que les données soient triées

COLONNES($C5 : D5) à la place de 2, 3, 4, etc
ou bien COLONNE()-2 mais là, si tu insères ou supprimes une colonne à gauche, il faut modifier le 2

Edit
J'ai comme du retard, non ?

 

[Dams92]

Re : Association de fonctions à RechercheV

Vous êtes juste magiques!

Merci, effectivement je ne pensais pas que le dernier argument était important.
Et merci JCGL, vous m'avez fait gagner du temps précieux!

Damien

 

[Dams92]

Re : Association de fonctions à RechercheV

Et est ce qu'il est possible d'utiliser la fonction recherchev à l'envers?
C'est à dire que je voudrais l'utiliser pour insérer le contenu de la colonne antérieure à celle de référence.

Je ne suis peut êter pas très clair, l'idée de la formule serait ccela mais bien sur ca ne marche pas....

RECHERCHEV($C9;'Portefeuille Brut OL Filtre'!$C$6:$O$107;-1;0)

 

[tototiti2008]

Re : Association de fonctions à RechercheV

Re,
Bonjour kjin, Bonjour Monique,

Ah ben y a du monde pour un 0 manquant Arf

ben oui, ça fait tellement plaisir de répondre quand on sait

bon, trèves de plaisanterie, pour rechercher dans la colonne précédente tu vas devoir imbiquer 2 fonctions : INDEX et EQUIV...

 

[Tibo]

Re : Association de fonctions à RechercheV

re,

Il faut dans ce cas passer par l'utilisation des fonctions INDEX et EQUIV

Dans ton cas, ça devrait donner :

=INDEX('Portefeuille Brut OL Filtre'!$B$6:$B$107;
EQUIV($C9;'Portefeuille Brut OL Filtre'!$C$6:$C$107;0))

Bon, formule rédigée sans le fichier, donc pas garantie à 100 %

Le principe : avec EQUIV, on recherche le rang de la valeur cherchée ($C9) dans la plage C6:C107

Une fois trouvé ce rang, on recherche avec INDEX dans B6:B107 la valeur correspondante.

Je te laisse adapter

@+

Edit : un salut amical à tous les amis qui sont passés sur ce fil

@+

 

[Dams92]

Re : Association de fonctions à RechercheV

Merci beaucoup pour toute ces réponses qui m'aident vraiment!

Vous ne me motivez donc à en demander toujours plus...

Cette fois-ci j'aimerais transformer un résultat de calcul "N/A" en chiffre "0" sans ajouter ligne ou colonne. Je comprends tout à fait pourquoi ce résultat est renvoyé mais pour des raisons esthétiques, je voudrais que ce disparaisse.

De plus, ce "N/A" m'empêche de sommer mes colonnes. J'ai essayé la fonction "somme.si" mais je ne sais malheureusement pas dire que j'aimerais n'additionner que les chiffres...

L'exemple est attaché à ce mail.

Je sais que j'en demande beaucoup...

Damien

 

[JCGL]

Re : Association de fonctions à RechercheV

Bonjour à tous,

Peux-tu essayer en D5 et tirer à droite et vers le bas :

=SI(ESTNA(RECHERCHEV($C5;Données!$C$4:$H$10;COLONNE(A2)+1;0));0;RECHERCHEV($C5;Données!$C$4:$H$10;COLONNE(A2)+1;0))

Bien évidemment avec le fichier déposé et donc à adapter.

Je te conseille de sommer en H3...

A+ à tous

 

[Dams92]

Re : Association de fonctions à RechercheV

je ne peux qu'applaudir...
la formule est pourtant simple, il suffisait de savoir qu'elle existait et j'en étais bien loin...
merci beaucoup
ce forum est vriament dingue!

 

[ledzepfred]

Re : Association de fonctions à RechercheV

bonsoir à tous,

amis formulistes : avez-vous vu une difference lors de l'utilisation du 0 ou du faux comme 4ème argument de la fonction recherchev?

Merci de vos réponses

A+

 

[JCGL]

Re : Association de fonctions à RechercheV

Bonjour à tous,
Salut LedZep,

Aucune...
0 = False ou Faux et 1 = True ou Vrai comme dans le VBA
Si l'argument 4 est omis le True ou Vrai ... ou le 1 est implicite

A++
A+ à tous