XL 2010 Afficher les résultats en ligne

[Michel68000]

Bonjour à tous,

Deux problèmes qui une fois résolus me faciliteront la tâche pour le contrôle de factures.
Le premier serait d'afficher en ligne tous les fournisseurs appartenant à une même famille.
le second serait d'afficher toujours en ligne toutes les factures (3 ou 4 en moyenne) en ligne en face de la date de ladite facture.
j'ai joints un petit fichier pour mieux vous faire comprendre ce que je voudrais faire.
Merci d'avance pour vos idées et pour le temps que vous consacrer à ce problème.

 

[vgendron]

Re : Afficher les résultats en ligne

Hello

En B3 de ta feuille Récap
=INDEX(ListeFournisseur;PETITE.VALEUR(SI(ListeFamilles="Viandes";LIGNE(ListeFamilles)-2);ENT((COLONNE()-2)/5)+1))
formule matricielle à valider par Ctrl + Maj + Entrée

par contre, il faut enlever les cellules fusionnées... je ne comprend d'ailleurs toujours pas pourquoi excel offre la possibilité de fusionner des cellules alors qu'il a horreur de ca pour les formules..

ListeFournisseur et ListeFamilles sont les zones nommées en feuille facture: F3:F13 et G3:G13

pour l'autre formule. je suppose que tu peux utiliser la meme idée à adapter.
par contre.. il faudra d'abord mettre le meme format de date, mettre les meme intitulés. B pour Benoit... etc etc..

Sinon. tu as la solution VBA

 

[vgendron]

Re : Afficher les résultats en ligne

En B4
=SIERREUR(INDEX(TabMontants;PETITE.VALEUR(SI((JOUR(TabDates)=JOUR($A4)*(Tabfournisseur=$B$3));LIGNE(TabDates)-1);COLONNE()-1));"")

idem. formule matricielle

 

[djidji59430]

Re : Afficher les résultats en ligne

Bonjour a tous,
en plus, il ya a des erreurs dans tes dates de saisie de factures, a partir du 19, elle sont en texte.
Je te mets quand meme mon fichier, avec forcement des formules ressemblant beaucoup a celles de Vgendron.

Crdmt

 

[Michel68000]

Re : Afficher les résultats en ligne

Merci Messieurs je vais tester tout ça cette nuit je reviendrais si j'ai un souci

 

[Michel68000]

Re : Afficher les résultats en ligne

Bonjour
Apres une bonne nuit de recherches j'ai opté pour la solution dedjidji59430, par contre deux problèmes sont encore là
Le premier c'est qu'une fois le nom des fournisseurs en entier je n'arrive pas à enlever Gauche dans la formule matricielle
et mon deuxième est la référence au nombre de lignes dans la formule, il se peut qu"il augmente et là ca ne fonctionne plus

Merci pour vos idées

 

[vgendron]

Re : Afficher les résultats en ligne

Hello

pour ajuster automatiquement au nombre de lignes, utilise des zones nommées dynamiquement avec la fonction Décaler
ouvrir gestionnaire de noms et modifier les zones comme suit:

exemple pour la zone date
=DECALER(Factures!$A$2;;;NBVAL(Factures!$A:$A)-1)

 

[vgendron]

Re : Afficher les résultats en ligne

et la formule à remettre
=SIERREUR(INDEX(Montants;PETITE.VALEUR(SI((date=$A4)*(fournisseurs=$B$3);LIGNE(Montants));COLONNES($A:A)));"")

 

[Michel68000]

Re : Afficher les résultats en ligne

en utilisant la formule decaler pour mes zones les résultats ne sont pas justes ça affiche le montant du dessous pour une date donnée

 

[Michel68000]

Re : Afficher les résultats en ligne

J'ai trouvé il suffisait de mettre =DECALER(Factures!$A$1;;;NBVAL(Factures!$A:$A)-1) et c'est juste. Grosse frayeur au niveau des chiffres. J'ai oublié de te remercier pour ta forte implication sur ce forum Vgendron.
Donc il ne me reste plus qu'un problème que je vais poster tout à l'heure après avoir tester qq trucs

 

[Michel68000]

Re : Afficher les résultats en ligne

Lorsque je regroupais les fournisseurs par initiale A pour André j'utilisais

=SIERREUR(INDEX(Montants;PETITE.VALEUR(SI((date=$A4)*(fournisseurs=GAUCHE(Récap_Fact!$B$3;1))<>0;LIGNE(Montants));COLONNES($A:A)));"")

Maintenant si le prénom était marqué en entier il me faut enlever la notion de GAUCHE dans la formule et là ça ne veux plus rien savoir.
Vous auriez une solution j'y perd mon latin

 

[vgendron]

Re : Afficher les résultats en ligne

Je ne comprend pas l'utilisation du <>0 dans la formule initiale..
mais c'est lui qui pose problème dans la nouvelle

=SIERREUR(INDEX(Montants;PETITE.VALEUR(SI((date=$A4)*(fournisseurs=Récap_Fact!$B$3);LIGNE(Montants));COLONNES($A:A)));"")

 

[Michel68000]

Re : Afficher les résultats en ligne

C'est pas possible comment fais tu, j'y est passé toute la nuit à chercher et toi en 2 secondes . Chapeau bas et un grand merci à vous deux

 

[djidji59430]

Re : Afficher les résultats en ligne

re a vous 2

=SIERREUR(INDEX(Montants;PETITE.VALEUR(SI(((date=$A4)*(fournisseurs=$B$3))<>0;LIGNE(Montants)-1);COLONNES($A:A)));"")

montants=Factures!$C$2:$C$42

Pas de probleme avec mon <>0, mais c'est vrai qu'il ne sert a rien