XL pour MAC 2 graphiques qui descendent quand on scrolle la page

[38manu74]

Bonjour,
J'ai un tableau qui comporte de nombreuse ligne.
A coté 2 graphique pour un suivi graphique de certaines données
Quand je descends dans le tableau, comment faire pour que mes graphiques reste toujours visible quand je scrolle... (je vous ai mis mon fichier en PJ)
Précision j'utilise Excel pour MAC version 16.69.1
Merci de votre aide

 

[Dranreb]

Bonjour.
Ces instructions rectifient la position des graphiques :

   ChartObjects(1).Top = Rows(ActiveWindow.ScrollRow).Top
   ChartObjects(2).Top = ChartObjects(1).Top + ChartObjects(1).Height

Le plus simple c'est de les mettre dans une Private Sub Worksheet_SelectionChange(ByVal Target As Range)
mais ça oblige à sélectionner une cellule. Sinon je ne vois que l'exécution toutes les secondes d'une procédure planifiée au moyen d'un Application.OnTime Now + TimeSerial(0, 0, 1), …

 

[job75]

Bonjour 38manu74, Bernard,

Voyez ce code dans ThisWorkbook :

Private Sub Workbook_Open()
Application.OnTime 1, "ThisWorkbook.Deplacer" 'lance la macro
End Sub

Sub Deplacer()
With Sheets("Feuille 1")
    Do
        DoEvents
        .ChartObjects(1).Top = .Rows(ActiveWindow.ScrollRow + 7).Top
        .ChartObjects(2).Top = .ChartObjects(1).Top + .ChartObjects(1).Height + 10
    Loop
End With
End Sub

Nota : dans VBA, pour arrêter la macro, menu Exécution => Réinitialiser.

A+

 

[38manu74]

Oulala merci à vous deux, mais là vous me parlez chinois je susi désolé je suis nul
voici ce que j'ai fait, et qui ne marche pas :
- clique droit sur le nom de la feuille
- afficher le code
- j'ai collé :
Private Sub Workbook_Open()
Application.OnTime 1, "ThisWorkbook.Deplacer" 'lance la macro
End Sub

Sub Deplacer()
With Sheets("Feuille 1")
Do
DoEvents
.ChartObjects(1).Top = .Rows(ActiveWindow.ScrollRow + 7).Top
.ChartObjects(2).Top = .ChartObjects(1).Top + .ChartObjects(1).Height + 10
Loop
End With
End Sub

- enregistrer le fichier en .xlsm

Mais quand je scrolle, il ne se passe rien.
J'ai un peu honte je suis vraiment nul

 

[job75]

- clique droit sur le nom de la feuille
- afficher le code
- j'ai collé :

Oulala pas du tout, j'ai bien dit que le code est dans ThisWorkbook !!!

Suffit de regarder le VBA.

 

[38manu74]

Oulala pas du tout, j'ai bien dit que le code est dans ThisWorkbook !!!

Suffit de regarder le VBA.

ok merci j'ai fais ca (copie écran) et enregistrer masi je ce message à l'ouverture (copie écran)

 

[38manu74]

aussi comment peut-on faire pour que une fois que les graphiques s'affiche, le scroll soit encore possible ??

 

[38manu74]

J'ai réussi avec Chatgpt (et oui j'ai essayé ) il m'a donné ce code :
Option Explicit



Private Sub Workbook_Open()

Application.OnTime 1, "ThisWorkbook.Deplacer" 'lance la macro

End Sub



Sub Deplacer()

With Sheets("PS Campus Coach Tokyo")

If .Range("A1").Top <= 100 Then

.ChartObjects(1).Top = .Rows(ActiveWindow.ScrollRow).Top

.ChartObjects(2).Top = .ChartObjects(1).Top + .ChartObjects(1).Height + 10

Application.OnTime Now + TimeValue("00:00:01"), "ThisWorkbook.Deplacer"

End If

End With

End Sub

ca marche nickel... SAUF que Excel me demande maintenant de réouvrrir le fichier dès que je le ferme.... et c'est sans fin... Une idée vous les humains ?

 

[Dranreb]

Oui, essayez comme ça :

Option Explicit
Private HOT As Date
Private Sub Workbook_Open()
   Deplacer
   End Sub
Sub Deplacer()
   With Sheets("PS Campus Coach Tokyo")
      .ChartObjects(1).Top = .Rows(ActiveWindow.ScrollRow).Top
      .ChartObjects(2).Top = .ChartObjects(1).Top + .ChartObjects(1).Height + 10
      End With
   HOT = Now + TimeSerial(0, 0, 1)
   Application.OnTime HOT, "ThisWorkbook.Deplacer"
   End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
   If HOT = 0 Then Exit Sub
   Application.OnTime HOT, "ThisWorkbook.Deplacer", Schedule:=False
   HOT = 0
   End Sub

 

[38manu74]

Oui, essayez comme ça :

Option Explicit
Private HOT As Date
Private Sub Workbook_Open()
   Deplacer
   End Sub
Sub Deplacer()
   With Sheets("PS Campus Coach Tokyo")
      .ChartObjects(1).Top = .Rows(ActiveWindow.ScrollRow).Top
      .ChartObjects(2).Top = .ChartObjects(1).Top + .ChartObjects(1).Height + 10
      End With
   HOT = Now + TimeSerial(0, 0, 1)
   Application.OnTime HOT, "ThisWorkbook.Deplacer"
   End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
   If HOT = 0 Then Exit Sub
   Application.OnTime HOT, "ThisWorkbook.Deplacer", Schedule:=False
   HOT = 0
   End Sub

Merveilleux.... Merci bcp