Vba-recuperer valeur dans une autre feuille

[Celeda]

Bonjour,

J'aurai besoin de votre aide pour automatiser une action, svp.

Dans le fichier ci-joint, j'ai deux feuilles :

la feuille master_list : dans la colonne B, l'intitulé SN avec dans la colonne une liste de sn et dans la colonne L , Avis.

la feuille statut : En D14, on retrouve l'intitulé sn avec dans cette colonne une liste de sn et en AE14, l'intitulé Avis avec dans la colonne des valeurs.
Ces valeurs sont ajoutées à la main en fonction d'une extraction SAP et en fonction du SN.

Il s'agit de récupèrer ces valeurs de la feuille Statut en colonne AE14 pour les transférer
dans la colonne AVIS de la feuille master_list en fonction du SN. Il faudrait mieux que cela se fasse simultanément : dès qu'une valeur est entrée dans la colonne Avis, elle se répércute dans la master_list;
Opération que je fais à la mimine actuellement...

Puis-je avoir été assez claire, sinon n'hésitez pas à me le dire.
A l'avance, un grand merci.

 

[Fo_rum]

Re : Vba-recuperer valeur dans une autre feuille

Salut

à essayer dans le module de la feuille "Status"

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Cl As Range
  If Intersect(Target, Range("AE15:AE" & Cells(Rows.Count, "AE").End(xlUp).Row)) Is Nothing Then Exit Sub
  With Sheets("master_list")
    Set Cl = .[B:B].Find(Target.Offset(, -27))
    If Not Cl Is Nothing Then .Cells(Cl.Row, 12) = Target
  End With
End Sub

 

[Modeste]

Re : Vba-recuperer valeur dans une autre feuille

Bonjour Celeda , salut Fo_rum ,

Comme j'étais "dessus", la même que Fo_rum (avec juste un message si le s/n n'est pas trouvé en feuille "Master_list" et une sortie de la macro, si on efface un avis)

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("AE15:AE1000")) Is Nothing Then
    If Not Target.Value = "" Then
        With Sheets("master_list")
        Set c = .Range("B2:B" & .Range("B65000").End(xlUp).Row).Find(what:=Target.Offset(0, -27).Value, _
            LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            c.Offset(0, 10) = Target.Value
        Else
            MsgBox "Pas trouvé de " & Target.Offset(0, -27).Value
        End If
        End With
    End If
End If
End Sub

 

[Celeda]

Re : Vba-recuperer valeur dans une autre feuille

Bonsoir,

Désolée d'arriver aussi tard mais urgence oblige : je n'ai pas pu tester
mais vous connaissant cela doit fonctionner.

Je vous en remercie et je vous reviens demain.

Merci à tous les deux.

 

[Celeda]

Re : Vba-recuperer valeur dans une autre feuille

Bonjour,

Tout d'abord, sachez que tout fonctionne correctement (mais je n'en ai jamais douté!!)
sur mon fichier de travail mais qu'en plus, et vous allez être fière de moi!!lol!, j'ai
compris quelques lignes de codes qui m'ont permis d'ajouter une fonctionnalité complémentaire (le même process mais avec une autre colonne _ grâce au -27, j'ai réussi à appliquer pour une autre colonne).

Je tiens doublement à vous remercier sincèrement.