Utilisation des noms des feuilles dans des formules

[hankyn]

Bonjour à tous,

Petit problème qui doit pas etre bien méchant pour vous .

J ai un classeur avec en noms de feuilles "Janvier 2011, Fevrier 2011, Mars 2011" etc ....
Je créé une Feuille "récap 2011" sur laquelle je viens chercher les valeurs de toutes le feuilles de 2011

Ma formule de base (qui fonctionne)

=SOMME.SI('JANVIER 2011'!$A$39:$C$49;A5;'JANVIER 2011'!$C$39:$C$49)

Comment faire pour rentrer mon "janvier 2011" dans une cellule et pouvoir incrémenter ma formule sans tout se palucher à la main.

J ai essayé de la facon suivante mais ca ne fonctionne pas :

En metant en B1 : 'Janvier 2011'! (en format texte)
et ma formule devient

=SOMME.SI(B1 & "$A$39:$C$49";A5;B1 & "$C$39:$C$49")

un peu de vos lumière svp je bloque

 

[tdenfert]

Re : Utilisation des noms des feuilles dans des formules

Bonjour,

Regarde du coté de indirect()

 

[BOISGONTIER]

Re : Utilisation des noms des feuilles dans des formules

Bonjour,

Il faut utiliser la fonction Indirect()

En B1, frapper 'Janvier 2011 (le format ne change pas le contenu mais seulement l'aspect)

=SOMME.SI(INDIRECT("'"&B1&"'!$A$39:$C$49");A5;INDIRECT("'"&B1&"'!$C$39:$C$49"))

Si B1 contient une date 01/01/2011 e.g.

=SOMME.SI(INDIRECT("'"&TEXTE(B1;"mmmm aaaa")&"'!$A$39:$C$49");A5;INDIRECT("'"&TEXTE(B1;"mmmm aaaa")&"'!$C$39:$C$49"))

Si B1 contient l'année (2011)

=SOMME.SI(INDIRECT("'"&TEXTE(DATE($B$1;LIGNES($1:1);1);"mmmm aaaa")&"'!$A$39:$C$49");A5;INDIRECT("'"&TEXTE(DATE($B$1;LIGNES($1:1);1);"mmmm aaaa")&"'!$C$39:$C$49"))

La fonction Indirect()

JB

 

[hankyn]

Merci les gars , ca fonctionne nickel

Edit :
Question pour satisfaire ma curiosité

Comment se fait il que ca ne fonctionne pas avec CONCATENER
j' avais essayer ca aussi, mais je vois pas la différence avec la fonction indirect

 

[BOISGONTIER]

Re : Utilisation des noms des feuilles dans des formules

La fonction Indirect() évalue une chaîne en adresse de champ

JB