trier et éffacer cellule

[yvon07]

Bonjour a tous
en espérant qu'une âme charitable pourras m'aider.
feuille 1 une liste que j'utilise pour autre chose
feuille 2 un export,2 fois par jour
se que je veux faire repérer ,les réf. de ma liste qui se trouve dans mon export
et effacer les autres ,sur la feuille 1.pour pouvoir les utilisé pour la suite de mon fichier
je sait les repérer avec une MFC, mais comment supprimer.
Encore merci d'avance pour votre aide

 

[yvon07]

Re : trier et éffacer cellule

bonsoir JOB75
oui ceci n'a rien a voir avec le premier post, mais s'est pour le même fichier
qui j'espère vas me faire gagner du temp dans mon job.
je teste ceci demain ,sur le fichier original, mais la sa marche parfaitement, il n'y a pas de raison ,pour que ceci ne soit pas ok.
je vous tient au courant,
est merci beaucoup pour votre aide.
Mes Salutations
A+

 

[job75]

Re : trier et éffacer cellule

Re,

Ceci est sans doute un peu mieux :

Sub Enregistrer()
Dim chemin$, c As Range, fichier$
chemin = ThisWorkbook.Path & "\"
Set c = Sheets("export").Range("A" & Rows.Count).End(xlUp)
fichier = Format(Date, "dd-mm-yyyy ") & c & " " & c(, 2) '???
Application.ScreenUpdating = False
Application.DisplayAlerts = False 'si le fichier a déjà été créé
On Error Resume Next
Workbooks(fichier).Close 'si le fichier est ouvert on le ferme
On Error GoTo 0
Sheets("armoire").Copy 'nouveau document
ActiveSheet.UsedRange = ActiveSheet.UsedRange.Value 'facultatif, supprime les formules
ActiveWorkbook.SaveAs chemin & fichier
ThisWorkbook.Sheets("base").Range("A" & Rows.Count).End(xlUp)(2) = ActiveWorkbook.Name
ActiveWorkbook.Close
End Sub

A+

 

[yvon07]

Re : trier et éffacer cellule

juste un point, si je veux enregistrer deux feuilles en même temp " comme armoire et export"
A+

 

[job75]

Re : trier et éffacer cellule

Re,

juste un point, si je veux enregistrer deux feuilles en même temp " comme armoire et export"

Sub Enregistrer()
Dim chemin$, c As Range, fichier$
chemin = ThisWorkbook.Path & "\"
Set c = Sheets("export").Range("A" & Rows.Count).End(xlUp)
fichier = Format(Date, "dd-mm-yyyy ") & c & " " & c(, 2) '???
Application.ScreenUpdating = False
Application.DisplayAlerts = False 'si le fichier a déjà été créé
On Error Resume Next
Workbooks(fichier).Close 'si le fichier est ouvert on le ferme
On Error GoTo 0
Sheets("armoire").Copy 'nouveau document
ActiveSheet.UsedRange = ActiveSheet.UsedRange.Value 'facultatif, supprime les formules
ThisWorkbook.Sheets("export").Copy After:=ActiveWorkbook.Sheets(1) '2ème feuille
ActiveWorkbook.Sheets(1).Activate
ActiveWorkbook.SaveAs chemin & fichier
ThisWorkbook.Sheets("base").Range("A" & Rows.Count).End(xlUp)(2) = ActiveWorkbook.Name
ActiveWorkbook.Close
End Sub

Bonne nuit et A+

 

[yvon07]

Re : trier et éffacer cellule

encore merci JOB75
je teste tous ceci demain matin, sur mon model d'essais cela marche
bonne nuit A+

 

[yvon07]

Re : trier et éffacer cellule

bonjour
tous marche, je vient de remettre une macro, que j'avais dans mon ancien document,
pour faire une recherche dans le fichier base.
en inscrivant le N° ou le nom, ceci m'ouvrais le fichier, de même que en cliquant sur le N° dans la feuille bases.
Or la ca ne marche pas.
ma feuille base été dans un classeur a part.
pensez vous qu'il soit possible de faire la même chose.
Merci
Slts
A +

 

[job75]

Re : trier et éffacer cellule

Bonsoir yvon07,

C'est pourtant très simple et il doit y avoir pas mal d'exemples sur le forum :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Column > 1 Or Target = "" Then Exit Sub
Dim wb As Workbook
Cancel = True
On Error Resume Next
Set wb = Workbooks.Open(ThisWorkbook.Path & "\" & Target)
If wb Is Nothing Then MsgBox Target & " introuvable.."
End Sub

Fichier joint.

Bonne nuit.

 

[yvon07]

Re : trier et éffacer cellule

bonsoir
pour le double clic ok, mais lorsque j'aurai 100 voir plus de fichier, comment faire la recherche.
avant j'avais une macro qui m'ouvrer un userforme,de recherche. Ou si j'inscris le N0 ou le nom, mon fichier s'ouvre.
de même si je clic dessus.
Slts
A plus

 

[job75]

Re : trier et éffacer cellule

Re,

Votre UserForm ne va pas car il peut y avoir plusieurs noms de fichiers qui répondent au critère de recherche.

Il faut les lister dans une ListBox.

Faites une recherche sur le forum, là encore c'est un sujet maintes fois traité.

A+

 

[job75]

Re : trier et éffacer cellule

Re,

Je vous mets quand même ma solution :

Private Sub TextBox1_Change()
Dim x$, t, d As Object, i&
x = "*" & LCase(TextBox1) & "*"
t = Sheets("base").[A1].CurrentRegion.Resize(, 2) 'au moins 2 éléments
Set d = CreateObject("Scripting.Dictionary")
For i = 1 To UBound(t)
  If LCase(t(i, 1)) Like x Then d(LCase(t(i, 1))) = "" 'élimine les doublons
Next
If d.Count Then ListBox1.List = d.keys Else ListBox1.Clear
TextBox1.SetFocus: TextBox1.SelStart = Len(TextBox1)
End Sub

Private Sub ListBox1_Click()
Dim wb As Workbook
On Error Resume Next
Set wb = Workbooks.Open(ThisWorkbook.Path & "\" & ListBox1)
If wb Is Nothing Then MsgBox "'" & ListBox1 & "' introuvable..."
End Sub

Fichier (2).

A+

 

[yvon07]

Re : trier et éffacer cellule

Bonsoir JOB75
ceci est vraiment pas mal. Peu être mieux que ce que je voulais.
Je vous remercie, pour votre aide et votre patience.
je vais pouvoir terminer mon fichier, est me faciliter un peu la vie avant la retraite.
Mes salutations les meilleurs.
et bonne nuit

 

[job75]

Re : trier et éffacer cellule

Re,

Peu être mieux que ce que je voulais.

C'est le minimum que l'on puisse dire.

Bonne fin de soirée.

 

[yvon07]

Re : trier et éffacer cellule

un grand merci pour tout
Bonne soirée a vous aussi

 

[yvon07]

Re : trier et éffacer cellule

bonsoir
j'ai terminé mon usine a gaz, tout fonctionne correctement ,cela me permet de gagner pas mal de temps.
et profiter de ma pause trop souvent négligé, avant de prendre ma retraite.
Encore merci a vous JOB75