XL 2013 Trie alphabetique une zone de liste

[lestoiles1]

Bonjour à tous,

J'aimerais que les noms dans la zone de liste se trie automatiquement sans avoir à touche les noms dans la colonnes A.

Merci d'avance

Lestoiles

 

[Compte Supprimé 979]

Bonjour lestoiles1

Il serait bien d'indiquer votre version d'Excel SVP
Car dans Excel 365, vous avez la fonction TRIER()

A+

 

[job75]

Bonjour lestoiles1, Bruno,

La Zone de liste (contrôle de formulaire) se réfère à la plage A1:A4.

Pour faire ce que vous souhaitez utilisez une ListBox (contrôle ActiveX).

Nombreux exemples sur XLD.

A+

 

[job75]

Bon voici le code pour une ListBox :

Option Compare Text 'la casse est ignorée

Private Sub Worksheet_Change(ByVal Target As Range)
Dim a
a = Application.Transpose([A1].CurrentRegion.Columns(1)) 'vecteur ligne
tri a, 1, UBound(a)
ListBox1.List = a
End Sub

Sub tri(a, gauc, droi) ' Quick sort
Dim ref, g, d, temp
ref = a((gauc + droi) \ 2)
g = gauc: d = droi
Do
    Do While a(g) < ref: g = g + 1: Loop
    Do While ref < a(d): d = d - 1: Loop
    If g <= d Then
      temp = a(g): a(g) = a(d): a(d) = temp
      g = g + 1: d = d - 1
    End If
Loop While g <= d
If g < droi Then Call tri(a, g, droi)
If gauc < d Then Call tri(a, gauc, d)
End Sub

 

[riton00]

Bonsoir,

Autre essai avec colonne caché + formule

Slts

 

[lestoiles1]

Merci beaucoup tout le monde

Lestoiles1

 

[job75]

Bonjour à tous,

Si l'on tient à la Zone de liste (contrôle de formulaire) il faut en effet utiliser une colonne auxiliaire.

Mais là encore il vaut mieux une macro :

Private Sub Worksheet_Change(ByVal Target As Range)
Application.ScreenUpdating = False
Application.EnableEvents = False 'désactive les évènements
Columns(1).Copy Columns(2) 'copier-coller
Columns(2).Hidden = True 'masque
Columns(2).Sort Columns(2), xlAscending, Header:=xlNo 'tri
Application.EnableEvents = True 'réactive les évènements
Shapes("Zone de liste 1").ControlFormat.ListFillRange = "$B$1:$B$" & Range("B" & Rows.Count).End(xlUp).Row
End Sub

A+

 

[lestoiles1]

Bonjour à tous,

Si l'on tient à la Zone de liste (contrôle de formulaire) il faut en effet utiliser une colonne auxiliaire.

Mais là encore il vaut mieux une macro :

Private Sub Worksheet_Change(ByVal Target As Range)
Application.ScreenUpdating = False
Application.EnableEvents = False 'désactive les évènements
Columns(1).Copy Columns(2) 'copier-coller
Columns(2).Hidden = True 'masque
Columns(2).Sort Columns(2), xlAscending, Header:=xlNo 'tri
Application.EnableEvents = True 'réactive les évènements
Shapes("Zone de liste 1").ControlFormat.ListFillRange = "$B$1:$B$" & Range("B" & Rows.Count).End(xlUp).Row
End Sub

A+

Merci bcp