transfer d'un tableau word vers excel

[progaide]

bjr comment faire pour transferer des données d'un tableau word vers excel avec un programme en vba en excel ss toucher le document word ??? merci d'vance .

 

[PMO2]

Re : transfer d'un tableau word vers excel

Bonjour,

Voici un code qui transfère les tableaux Word dans une nouvelle feuille Excel.
Adaptez la Constante
Const MON_DOC As String = "c:\essai.doc"
au chemin de votre document Word (.doc)

Tous les tableaux seront copiés. Si vous n'en voulez qu'un seul modifiez la ligne
For i& = 1 To DOC.Tables.Count
par (si par exemple il s'agit du tableau 7)
For i& = 7 To 7

****************
'### Constante à adapter (chemin du .doc ###
Const MON_DOC As String = "c:\essai.doc"
'###########################################

Sub Word2Excel()
Dim S As Worksheet
Dim i&
Dim Lig&
Dim DOC As Word.Document
On Error GoTo Erreur
Application.ScreenUpdating = False
Set DOC = GetObject(MON_DOC)
Set S = ActiveWorkbook.Worksheets.Add
Lig& = 1
For i& = 1 To DOC.Tables.Count
DOC.Tables(i&).Range.Copy
S.Paste Destination:=S.Range("a" & Lig& & "")
Lig& = S.UsedRange.Rows.Count + 2
Next i&
DOC.Close
Set DOC = Nothing
S.Columns.AutoFit
S.Rows.AutoFit
Application.ScreenUpdating = True
Exit Sub
Erreur:
If Not DOC Is Nothing Then DOC.Close
Set DOC = Nothing
Application.ScreenUpdating = True
MsgBox "Erreur " & Err.Number & vbCrLf & Err.Description
End Sub
****************

Cordialement.

PMO
Patrick Morange

 

[progaide]

Re : transfer d'un tableau word vers excel

Salut Patrick Merci pour votre reponse


hanaâ

 

[JNP]

Re : transfer d'un tableau word vers excel

Bonjour le forum ,
Progaide, j'avais cru que tu tiendrais compte de la remarque de Pascal, mais là, 7 fils sur le même, chapeau !
http://www.excel-downloads.com/forum/110078-programme-en-vba-qui-permet-le-transfer-des-donn-es-de-word-vers-excel.html
http://www.excel-downloads.com/forum/110046-changement-les-colonnes-d-un-tableau.html
http://www.excel-downloads.com/forum/110065-inverser-les-colonnes-dun-tableau-excel.html
http://www.excel-downloads.com/forum/109938-transfer-dun-tableau-word-vers-excel.html
http://www.excel-downloads.com/forum/109981-transfer-dun-tableau-word-vers-excel.html
http://www.excel-downloads.com/forum/109759-comment-faire-pour-transfer-des-donn-e-de-word-vers-excel.html
http://www.excel-downloads.com/forum/110081-cr-ation-d-une-copie-d-un-document-word-depuis-excel.html
Ne peux-tu conserver le même ? Ce serait l'idéal pour toi comme pour tous. Si tu as l'impression que ton fil s'enfonce dans le lointain, un petit post dans le même fil le fera remonter...
Bonne soirée quand même