Supprimer ligne avec doublons même colonne

[matrix]

Bonjour à tous,

J'ai un probléme avec un script.

Dans mon fichier Excel, dans la colonne E, à partir de la ligne 3 en descendant, se trouve des noms.

Je voudrais faire en sorte que si le nom apparait plus qu’une fois dans cette même colonne, qui garde la ligne du premier nom en doublons, et qu’il supprime les autres lignes qui suivent toujours du même nom.

Comment faire s.v.p?

Merci pour votre aide.

Voici mon code jusqu'à present

Private Sub CommandButton2_Click()
Dim Cell As Range
    Dim i As Integer
    Dim Un As New Collection
    
    On Error Resume Next
       
        For Each Cell In Sheets("Export file format").Range("e3:e3000")
            Un.Add Cell, CStr(Cell)
        Next Cell
    On Error GoTo 0
    
    For i = 1 To Un.Count
       
        Sheets("Export file format").Cells(i, 5) = Un.Item(i)
    Next i
End Sub

 

[pierrejean]

Re : Supprimer ligne avec doublons même colonne

bonjour matrix

Une proposition:

Sub test()
For n = Range("E65536").End(xlUp).Row To 4 Step -1
  If Range("E" & n - 1) = Range("E" & n) Then Rows(n).Delete
Next n
End Sub

NB: Tient compte du fait que le classement sur la colonne E est fait

 

[matrix]

Re : Supprimer ligne avec doublons même colonne

Super merci.

Ça fonctionne a merveille.

 

[matrix]

Re : Supprimer ligne avec doublons même colonne

Bonjour,

Je dois faire une modification au script de pierrejean.

Sub test()
For n = Range("E65536").End(xlUp).Row To 4 Step -1
  If Range("E" & n - 1) = Range("E" & n) Then Rows(n).Delete
Next n
End Sub

Dans le script, il cherche les doublons dans la colonne E. Je voudrais modifier pour qu'il cherche les doublons sur 2 colonnes.

Donc, si dans la colonne E il y a des doublons, il va regarder dans la colonne R de la même ligne.

Si la valeur de la colonne E et la valeur de la colonne R se retrouve sur plusieurs lignes, il va garder la première ligne et supprimer les suivantes avec la même valeur.

Comment faire s.v.p?

Merci pour votre aide.

 

[Cousinhub]

Re : Supprimer ligne avec doublons même colonne

Bonjour,

essaie avec ce code :

Private Sub CommandButton1_Click()
Dim Cel As Range
Dim MesDonnees As Object, MesDonnees2 As Object
Dim Donnee As String
Dim I As Integer
Dim tmp As Variant
Set MesDonnees = CreateObject("Scripting.Dictionary")
Set MesDonnees2 = CreateObject("Scripting.Dictionary")
For Each Cel In Range("E3:E" & [E65000].End(xlUp).Row)
    Donnee = Cel.Value & Cel.Offset(0, 13).Value
        If Not MesDonnees.Exists(Donnee) Then
            MesDonnees.Add Donnee, Donnee
        Else
            MesDonnees2.Add Cel.Row, Cel.Row
        End If
Next Cel
If MesDonnees2.Count > 0 Then
    tmp = Application.Transpose(MesDonnees2.Items)
    Application.ScreenUpdating = False
    For I = UBound(tmp) To LBound(tmp) Step -1
        Rows(tmp(I, 1)).Delete
    Next I
End If
End Sub

Bon Week-End

 

[matrix]

Re : Supprimer ligne avec doublons même colonne

Super merci.

ça fonctionne très bien.

Merci encore